fet110_wdt02.s43

msp430p1110

#include  "msp430x11x1.h"
;******************************************************************************
;   MSP-FET430x110 Demo - WDT Toggle P1.0 Interval overflow ISR, 32kHz ACLK 
;
;   Description; Toggle P1.0 using software timed by WDT ISR. Toggle rate is 
;   exatly 250ms based on 32kHz ACLK WDT clock source.  In this example the 
;   WDT is configured to divide 32768 watch-crystal(2^15) by 2^13 with an ISR 
;   triggered @ 4Hz.  
;   //*External watch crystal installed on XIN XOUT is required for ACLK*//	  
;
;                MSP430F1121
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32k
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0F000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #300h,SP                ; Initialize stackpointer
StopWDT     mov.w   #WDT_ADLY_250,&WDTCTL   ; WDT 250ms, ACLK, interval timer 
            bis.b   #WDTIE,&IE1             ; Enable WDT interrupt 
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output
            eint                            ; Enable interrupts
                                            ;					  
Mainloop    bis.w   #LPM3,SR                ; Remain in LPM3
            nop                             ; Required only for C-spy
                                            ;
;------------------------------------------------------------------------------ 
WDT_ISR;    Toggle P1.0
;------------------------------------------------------------------------------ 
            xor.b   #001h,&P1OUT            ; Toggle P1.0
            reti                            ;		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x11x1         
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF4h                  ; WDT Vector
            DW      WDT_ISR                 ; 
            END