fet110_lpm3.s43

msp430p1110

#include  "msp430x11x.h"
;******************************************************************************
;   MSP-FET430x110 Demo - BasicClcok LPM3 Using WDT ISR, 32kHz ACLK
;
;   Description; This program operates MSP430 normally in LPM3, pulsing P1.0 
;   at 4 second intervals. WDT ISR used to wake-up system. All I/O configured 
;   as low outputs to eliminate floating inputs. Current consumption does 
;   increase when LED is powered on P1.0. Demo for measuring LPM3 current. 
;   ACLK = LFXT1/4 = 32768/4, MCLK = SMCLK = default DCO
;   //*External watch crystal installed on XIN XOUT is required for ACLK*//	  
;
;                MSP430F1121
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32kHz
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0F000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #300h,SP                ; Initialize stackpointer
SetupBC     bis.b   #DIVA1,&BCSCTL1         ; ACLK/4 
SetupWDT    mov.w   #WDT_ADLY_1000,&WDTCTL  ; WDT 1s*4 interval timer 
            bis.b   #WDTIE,&IE1             ; Enable WDT interrupt 
SetupP1     mov.b   #0FFh,&P1DIR            ; All P1.x outputs
            clr.b   &P1OUT                  ; All P1.x reset
SetupP2     mov.b   #0FFh,&P2DIR            ; All P2.x outputs
            clr.b   &P2OUT                  ; All P2.x reset
            eint                            ; Enable interrupts
                                            ;					  
Mainloop    bis.w   #LPM3,SR                ; Enter LPM3
            bis.b   #001h,&P1OUT            ; Set P1.0
            push.w  #5000                   ; Delay to TOS
Delay       dec.w   0(SP)                   ; Decrement TOS
            jnz     Delay                   ; Delay over?
            incd.w  SP                      ; Clean stack
            bic.b   #001h,&P1OUT            ; Reset P1.0
            jmp     Mainloop                ; Again
                                            ;
;------------------------------------------------------------------------------ 
WDT_ISR;    Exit all LPMx modes, reti returns system active with GIE enabled
;------------------------------------------------------------------------------ 
            mov.w   #GIE,0(SP)              ; System active on TOS
            reti                            ;		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x11x1         
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF4h                  ; WDT Vector
            DW      WDT_ISR                 ; 
            END