fet440_ta05.s43

msp430f440的头程序

#include  "msp430x44x.h"
;******************************************************************************
;   MSP-FET430F440 Demo - Timer_A Toggle P5.1, CCR0 upmode ISR, 32kHz ACLK 
;
;   Description; Toggle P5.1 using software and the TA_0 ISR. Timer_A is 
;   configured in an upmode, thus the timer will overflow when TAR counts 
;   to CCR0. In this example, CCR0 is loaded with 1000.
;   ACLK = TACLK = LFXT1 = 32768, MCLK = SMCLK = DCO = 32xACLK = 1.048576MHz
;   //*An external watch crystal on XIN XOUT is required for ACLK*//	  
;
;                 MSP430F449
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32kHz
;          --|RST          XOUT|-
;            |                 |
;            |             P5.1|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0E000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize '449 stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupFLL    bis.b   #XCAP14PF,&FLL_CTL0     ; Configure load caps
SetupTA     mov.w   #TASSEL0+MC0,&TACTL     ; ACLK, up mode
SetupC0     mov.w   #CCIE,&CCTL0            ; CCR0 interrupt enabled
            mov.w   #1000-1,&CCR0           ; CCR0 counts to 1000
SetupP5     bis.b   #002h,&P5DIR            ; P5.1 output 
            eint                            ; Enable interrupts
                                            ;													  
Mainloop    bis.w   #LPM3,SR                ; Enter LPM3
            nop                             ; Required only for C-spy
                                            ;
;------------------------------------------------------------------------------ 
TA0_ISR;    Toggle P5.1
;------------------------------------------------------------------------------ 
            xor.b   #002h,&P5OUT            ; Toggle P5.1
            reti                            ;		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x44x          
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFECh                  ; Timer_A0 Vector
            DW      TA0_ISR                 ; 
            END