fet440_wdt02.s43

来自「msp430f440的头程序」· S43 代码 · 共 51 行

#include  "msp430x44x.h"
;******************************************************************************
;   MSP-FET430P440 Demo - P5.1 Interval overflow ISR, 32kHz ACLK 
;
;   Description; Toggle P5.1 using software timed by WDT ISR. Toggle rate is 
;   exactly 250ms based on 32kHz ACLK WDT clock source.  In this example the 
;   WDT is configured to divide 32768 watch-crystal(2^15) by 2^13 with an ISR 
;   triggered @ 4Hz.  
;   ACLK = LFXT1 = 32768, MCLK = SMCLK = DCO 
;   //*An external watch crystal on XIN XOUT is required for ACLK*//	  
;
;                 MSP430F449
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32kHz
;          --|RST          XOUT|-
;            |                 |
;            |             P5.1|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize '449 stackpointer
SetupFLL    bis.b   #XCAP14PF,&FLL_CTL0     ; Configure load caps
SetupWDT    mov.w   #WDT_ADLY_250,&WDTCTL   ; WDT 250ms, ACLK, interval timer 
            bis.b   #WDTIE,&IE1             ; Enable WDT interrupt 
SetupP5     bis.b   #002h,&P5DIR            ; P5.1 output
            eint                            ; Enable interrupts      
                                            ;					  
Mainloop    bis.w   #LPM3,SR                ; Remain in LPM3
            nop                             ; Required only for C-spy
                                            ;
;------------------------------------------------------------------------------
WDT_ISR;    Toggle P5.1
;------------------------------------------------------------------------------
            xor.b   #002h,&P5OUT            ; Toggle P5.1
            reti                            ;		 
                                            ;   
;----------------------------------------------------------------------------- 
;           Interrupt Vectors Used MSP430F44x          
;----------------------------------------------------------------------------- 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF4h                  ; WDT Vector
            DW      WDT_ISR                 ; 
            END