lib.asp

新魔界最新帐号注册源码 精简了文件

<%
'过滤特殊字符
Function FilterHtml(str)
		str = Replace(str, "&", "&amp;")
		str = Replace(str, ">", "&gt;")
		str = Replace(str, "<", "&lt;")
		str = Replace(str, """", "&quot;")
		str = Replace(str, "'", "&#39;")
		str = Replace(str, Chr(9), "　　　　")
		str = Replace(str, "　", "　　")
		str = Replace(str, " ", "　")
		str = Replace(str, Chr(10) & Chr(13), "<br />")
		FilterHtml = str
	End Function
	
'获取QueryString传过来的数字参数
	Function GetQueryInt(name)
		If Request.QueryString(name) = "" Or Not IsNumeric(Request.QueryString(name)) Then
			GetQueryInt = 0
		Else
			GetQueryInt = CLng(Request.QueryString(name))
		End If
	End Function
	
'获取Post过来的数字参数
	Function GetPostInt(name)
		If Request.Form(name) = "" Or Not IsNumeric(Request.Form(name)) Then
			GetPostInt = 0
		Else
			GetPostInt = CLng(Request.Form(name))
		End If
	End Function
	
'获取QueryString传过来的项值，并将其过滤特殊字符
	Function GetQueryField(name)
		GetQueryField = FilterHtml(Request.QueryString(name))
	End Function
	
'获取Post传过来的项值，并将其过滤特殊字符
	 Function GetPostField(name)
		GetPostField = FilterHtml(Request.Form(name))
	End Function

	Public Sub msg(content)
		response.write("<script>alert('"& content &"');history.go(-1)</script>")
		Response.End()
	End Sub
	Public Sub msg1(content)
		response.write "<script language='javascript'>" & chr(13)
		response.write "alert('"& content &"');" & Chr(13)
		response.write "window.document.location.href='"& Request.ServerVariables("HTTP_REFERER") &"';"&Chr(13)
		response.write "</script>" & Chr(13)
		Response.End 
	End Sub
	Public Sub msg2(content,url) 
		response.write "<script language='javascript'>" & chr(13)
		response.write "alert('"& content &"');" & Chr(13)
		response.write "window.document.location.href='"& url &"';"&Chr(13)
		response.write "</script>" & Chr(13)
		Response.End 
	End Sub
	Public Sub msg3(content)
		response.write "<script language='javascript'>" & chr(13)
		response.write "alert('"& content &"');" & Chr(13)
		response.write "window.close();"&Chr(13)
		response.write "</script>" & Chr(13)
		Response.End 
	End Sub
	'读取ip地址
	Function getip()
		if Request.ServerVariables("HTTP_X_FORWARDED_FOR")=empty then 
			getip=Request.ServerVariables("REMOTE_ADDR") 
		else 
			getip=Request.ServerVariables("HTTP_X_FORWARDED_FOR") 
		end if 
	End Function
	
	'过滤非法词组
	Function ChkInvaildWord(Words) 
	Const InvaildWords="select|update|delete|insert|union|--|,|'" '需要过滤得字符以“|”隔开，最后结束的字符必须是| 

	ChkInvaildWord=True 
	InvaildWord=Split(InvaildWords,"|") 
	inWords=LCase(Trim(Words)) 

	For i=LBound(InvaildWord) To UBound(InvaildWord) 
	If Instr(inWords,InvaildWord(i))>0 Then 
	ChkInvaildWord=True 
	Exit Function 
	End If 
	Next 
	ChkInvaildWord=False 
	End Function 
	
%>