dir.nc

nesC写的heed算法

// $Id: Dir.nc,v 1.1.4.2 2003/08/18 22:09:47 cssharp Exp $

/*									tab:4
 * "Copyright (c) 2000-2003 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement is
 * hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
 * CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 *
 * Copyright (c) 2002-2003 Intel Corporation
 * All rights reserved.
 *
 * This file is distributed under the terms in the attached INTEL-LICENSE     
 * file. If you do not find these files, copies can be found by writing to
 * Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA, 
 * 94704.  Attention:  Intel License Inquiry.
 */
includes IFS;
module Dir {
  provides interface FileDir;
  uses {
    interface IFileMetaRead;
    interface IFileCoord;
    interface IFileFree;
  }
#include "massert.h"
}
implementation {
  bool busy;

  /**
   * List names of all files in filing system
   * @return 
   *   SUCCESS: attempt proceeds, <code>nextFile</code> will be signaled<br>
   *   FAIL: filesystem is busy
   */
  command result_t FileDir.start() {
    if (!call IFileCoord.lock())
      return FAIL;
    busy = TRUE;

    call IFileMetaRead.read();

    return SUCCESS;
  }

  command result_t FileDir.readNext() {
    if (!busy)
      return FAIL;
    call IFileMetaRead.readNext();
    return SUCCESS;
  }

  default event result_t FileDir.nextFile(const char *filename, fileresult_t result) {
    return FAIL;
  }

  event void IFileMetaRead.nextFile(struct fileEntry *file, fileresult_t result) {
    if (signal FileDir.nextFile(file->name, result) != SUCCESS ||
	result != FS_OK)
      {
	call IFileCoord.unlock();
	busy = FALSE;
      }
  }

  /**
   * @return Number of bytes available in filing system.
   */
  command uint32_t FileDir.freeBytes() {
    return (uint32_t)call IFileFree.nFreeBlocks() << IFS_LOG2_PAGE_SIZE;
  }
}