glllstringutil.as

flex开发的音乐播放程序程序。带歌词功能

package com.ll19.util {

	/**
	 * - GL'LL. - 
	 * 
	 * @author <a href="http://www.LL19.com/">LL19.com</a>
	 * 
	 */
	public class GlllStringUtil {

		/**
		 *
		 *对照字符串put是否包含在putString中
		 *
		 * 
		 */
		public static function indexString(putString:String,put:String):Boolean {
			if (putString.indexOf(put) > -1) {
				return true;
			} else {
				return false;
			}
		}

		/**
		 * 
		 * 两位补0注意将int转为String
		 * 
		 * 
		 */
		public static function checkDigits(toCheck:String):String {
			return  int(toCheck) < 10 ? toCheck = "0" + toCheck : toCheck;
		}

		/**
		 * 
		 * 去除char中的字符串remove
		 * 
		 * 
		 */
		public static function remove(char:String,remove:String):String {
			return replaceAll(char, remove, "");
		}

		/**
		 * 
		 * 将字符串char中的replace替换为replaceWith
		 * 
		 */
		public static function replaceAll(char:String,replace:String,replaceWith:String):String {
			return char.split(replace).join(replaceWith);
		}

		/**
		 * 
		 * 返回min和max（包含）之间的随机整数
		 * 
		 * 
		 */
		public static function randRange(min:Number, max:Number):Number {
			var randomNum:Number = Math.floor(Math.random() * (max - min + 1)) + min;
			return randomNum;
		}

		/**
		 * 
		 * 单位转换 将Bytes单位转换为KB或者MB 传入数字返回带单位的String
		 * 
		 * 
		 */
		public static function getUnitTransform(num:Number):String {
			if (num < 1000) {
				return num + "Bytes";
			} else if (num < 1024 * 1000) {
				return Math.round(num / 1024) + "KB";
			} else {
				return Math.round(num / 1024 / 1024 * 100) / 100 + "MB";
			}
		}

		/**
		 * 
		 * 将时间(类型[02:02.08])转换成秒 用在LRC中
		 * String返回Number
		 * 
		 * 
		 */
		public static function convertToTime(str:String):Number {
			var times:Array = str.split(":");
			return parseInt(times[0]) * 60 + parseFloat(times[1]);
		}

		/**
		 * 
		 * 将返回Str split后子字符串数组的最后一组字符串
		 * 
		 */
		public static function splitLast(Str:String,split:String):String {
			var temp:Array = Str.split(split);
			return (temp[temp.length - 1]);
		}

		/**
		 * 
		 * 将返回Str split后子字符串数组的第一组字符串
		 * 
		 */
		public static function splitBegin(Str:String,split:String):String {
			var temp:Array = Str.split(split);
			return (temp[0]);
		}

		/**
		 * 
		 * 将毫秒转换为 00 m 00 s 
		 * 
		 */
		public static function convertMillToTime(mill:Number):String {
			mill = mill / 1000;
			var timem:Number = Math.floor(mill / 60);
			var times:Number = Math.round(mill % 60);
			var time:String = timem + " m " + times + " s ";
			return time;
		}
	}
}