sms_detail.asp

jsp 同学录源码

<%
'===================================================================
'= ASP FILENAME	: /sms/sms_detail.asp
'= CREATED TIME : 2006-5-8
'= LAST MODIFIED: 2006-5-8
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 站内短信查看 
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./sms_inc.asp" -->
<!-- #include file = "../inc/logic/logic_sms.asp" -->
<!-- #include file = "../inc/inc_ubb.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "sms/sms_detail.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "站内短信查看"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowSmsDetailCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_strVerifyCode	'== 表单校验
Dim TAG_objDicUnit		'== 单列记录

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()
%>

<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_sms_list.html.asp" --> 
<%
End Function

'===================================================================
'= Sub         : ShowSmsDetailCtl() 
'= Time		   : Created At 2006-5-8
'= Input       :
'= Description : 站内短信查看
'===================================================================
Function ShowSmsDetailCtl()
	Dim clsTable
	Dim intSmsId,strHtmlCode

	'== 获取ID参数
	If Not GetPostIdValue("intSmsId","站内短信",intSmsId) Then Exit Function

	'== 取记录逻辑
	If Not GetSmsLogic(GBL_intUserId,intSmsId) Then Exit Function
	If Not ResultExecute(GBL_objPubDB.intRSNum,"该站内短信不存在或已被删除","ES_DB_NO") Then

		Set clsTable = New classTable
		clsTable.Border = "0"
		clsTable.CellPadding = "3"
		clsTable.CellSpacing = "1"
		clsTable.Width = "95%"
		clsTable.ClassType = GBL_cssListTable
		clsTable.Align = "center"
		clsTable.MakeTable()

		clsTable.AddTitleTr GBL_cssListTr
		clsTable.AddTitleTd "接 收 者：",GBL_cssListTdChange,"30%"
		clsTable.AddTitleTd GBL_objPubDB.objPubRS("SMS_INCEPTER") & "&nbsp;&nbsp;<img src=""../images/Ico/User_info.gif"" style=""cursor:hand;"" onclick=""window.open('../address/address_userinfo_pop.asp?intUserId=" & GBL_objPubDB.objPubRS("SMS_INCEPTER_ID") & "','','left=5,top=5,width=450,height=410,scrollbars=yes,status=yes');"" alt=""查看用户信息"" border=""0"" align=""absmiddle"" valign=""middle"">",GBL_cssListTd,"70%"

		clsTable.AddTr GBL_cssListTr
		clsTable.AddTd "发 送 者：",GBL_cssListTdChange
		clsTable.AddTd GBL_objPubDB.objPubRS("SMS_SENDER") & "&nbsp;&nbsp;<img src=""../images/Ico/User_info.gif"" style=""cursor:hand;"" onclick=""window.open('../address/address_userinfo_pop.asp?intUserId=" & GBL_objPubDB.objPubRS("SMS_SENDER_ID") & "','','left=5,top=5,width=450,height=410,scrollbars=yes,status=yes');"" alt=""查看用户信息"" border=""0"" align=""absmiddle"" valign=""middle"">",GBL_cssListTd

		clsTable.AddTr GBL_cssListTr
		clsTable.AddTd "短信主题：",GBL_cssListTdChange
		clsTable.AddTd GBL_objPubDB.objPubRS("SMS_TITLE"),GBL_cssListTd

		clsTable.AddTr GBL_cssListTr
		clsTable.AddTd "时&nbsp;&nbsp;&nbsp;&nbsp;间：",GBL_cssListTdChange
		clsTable.AddTd GBL_objPubDB.objPubRS("SMS_TIME"),GBL_cssListTd

		clsTable.AddTr GBL_cssListTr 
		clsTable.AddTd "短信内容：",GBL_cssListTdChange
		clsTable.AddTd UbbCode(GBL_objPubDB.objPubRS("SMS_CONTENT")),GBL_cssListTd
		
		'== Return the sms of user incept 
		If GBL_objPubDB.objPubRS("SMS_INCEPTER_ID") = GBL_intUserId And GBL_objPubDB.objPubRS("SMS_SEND_FLAG") = "1" And GBL_objPubDB.objPubRS("SMS_DEL_INCEPT") = "0" Then
			clsTable.AddInfoTr GBL_cssListTr,"BOTTOM"
			strHtmlCode = "<br><input type='button'  value='回复短信' name='btnSmsView' onclick=parent.location.href='./sms_add_form.asp?pstReTitle=" & GBL_objPubDB.objPubRS("SMS_TITLE") & "&pstReSender=" &  GBL_objPubDB.objPubRS("SMS_SENDER") & "&pstReSenderId=" &  GBL_objPubDB.objPubRS("SMS_SENDER_ID") & "'><br>&nbsp;"
			clsTable.AddInfoTd strHtmlCode,"form_sub_td"
		End If

		'== Edit the sms of user's has not sended
		If GBL_objPubDB.objPubRS("SMS_SENDER") = GBL_strUserRealName And  GBL_objPubDB.objPubRS("SMS_SEND_FLAG") = "0" And GBL_objPubDB.objPubRS("SMS_DEL_SEND") = "0" And GBL_objPubDB.objPubRS("SMS_DEL_INCEPT") = "0" Then
			clsTable.AddInfoTr GBL_cssListTr,"BOTTOM"
			strHtmlCode = "<br><input type='button' class='" & GBL_cssIptBtn &"' value='编辑短信' name='btnSmsView' onclick=parent.location.href='./sms_add_form.asp?action=FormNewSms&SmsId=" & GBL_objPubDB.objPubRS("SMS_ID") & "'><br>&nbsp;"
			clsTable.AddInfoTd strHtmlCode,GBL_cssListTd
		End If
		
		Response.Write "<br>"
		clsTable.OutPutTable()
		Set clsTable = Nothing

		'== 更新短信阅读状态
		If Not SaveSmsViewFlagLogic(GBL_intUserId,intSmsId) Then Exit Function

	End If

End Function
%>