meet_list.asp

jsp 同学录源码

<%
'===================================================================
'= ASP FILENAME	: /meet/meet_list.asp
'= CREATED TIME : 2006-5-7
'= LAST MODIFIED: 2006-5-7
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 活动列表
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./meet_inc.asp" -->
<!-- #include file = "../inc/logic/logic_meet.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "meet/meet_list.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "活动列表"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowMeetListCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_objDicUnit		'== 单列记录
Dim TAG_strVerifyCode	'== 表单校验
Dim TAG_strPageNav		'== 翻页导航

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)
 

'== 页面析构
Call ActionOver()
%>

<%
''===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-7
'= Description : 加载页面模块
'==================================================================='
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_meet_list.html.asp" --> 
<%
End Function


''===================================================================
'= Function	   : ShowMeetListCtl()
'= Time		   : Created At 2006-5-7
'= Input       : None
'= Description : show meet list
'==================================================================='
Function ShowMeetListCtl()
	Dim strFileName 
	Dim intMaxPerPage
	Dim intCurPage,intTotalPut
	Dim strSql,strMethod

	intMaxPerPage = GBL_intMaxPerPage

	'== 取查询方式
	strMethod = FmtFormData(Request.QueryString("method"))

	strFileName = "meet_list.asp?method=" & strMethod

	'== 取记录集
	Select Case strMethod
		Case "over" : strSql = " AND MEET_STATUS=" & CONST_MEET_OVER
		Case "run"  : strSql = " AND MEET_STATUS=" & CONST_MEET_RUN
	End Select 
	If Not GetMeetsLogic(strSql) Then Exit Function

	If GBL_objPubDB.intRSNum > 0 Then

		intTotalPut = GBL_objPubDB.intRSNum

		intCurPage = GetCurPage(intMaxPerPage,intTotalPut)

		If intCurPage = 1 Then
			Call ShowContentMeet(GBL_objPubDB.objPubRS,intMaxPerPage)
		Else
			If (intCurPage - 1) * intMaxPerPage < intTotalPut Then
				GBL_objPubDB.objPubRS.Move  (intCurPage - 1) * intMaxPerPage
				Dim BookMark
				BookMark = GBL_objPubDB.objPubRS.BookMark
				Call ShowContentMeet(GBL_objPubDB.objPubRS,intMaxPerPage)
			Else
				intCurPage = 1
				Call ShowContentMeet(GBL_objPubDB.objPubRS,intMaxPerPage)
			End If

		End If
		
		TAG_strPageNav = ShowPageNav(intTotalPut,intMaxPerPage,intCurPage,strFileName)

	Else
		Response.Write "<p align=center>目前没有任何校友活动<br><a href='" & GBL_strHomeURL & "meet/meet_add_form.asp'>发起新的校友活动</a></p>"
	End If

	GBL_objPubDB.Clear()

End Function

'===================================================================
'= Function    : ShowContentMeet(objRSCont,intMaxPerPage)
'= Time		   : Created At Feb,08,2004
'= Input       : objRSCont	   : rs 
'=				 intMaxPerPage : 
'= Description : Show per meet
'===================================================================
Function ShowContentMeet(objRSCont,intMaxPerPage)

	Dim i
	i = 0
	'== Set table header
%>
	<table border="0" cellpadding="0" cellspacing="0" align="center" valign="middle" width="98%"  style="word-break:break-all">
	<tr  class="nav_title_tr">
	 <td  class="nav_title_td" colspan="2">
		<div id="meet_nav_list"><span class="alt">[ meet_nav_list ]</span></div></td>
	</tr>
</table>
<table class="list_table" width="98%" border="0" cellpadding="2" cellspacing="1" align="center" valign="middle">
		<tr class="list_title_tr">
			<td   class="list_title_td" width=55%  align="center">活动主题</td>
			<td   class="list_title_td" width=12%  align="center">发起人</td>
			<td   class="list_title_td" width=25%  align="center">发起时间</td>
			<td   class="list_title_td" width="*"  align="center">状态</td>
		</tr>
</table>
 <TABLE  cellSpacing=0 cellPadding=0 width="98%"  border=0>
        <TBODY>
<%
	Dim GBL_strImgIco,strIco,strStatus,strHtmlCode
	Do While Not objRSCont.Eof

		i = i + 1

		Select Case objRSCont("MEET_STATUS") 
			Case	 0	:	strIco = MakeImg(GBL_strImgIco & "forum_comm.gif","编号" & objRSCont("MEET_ID"))
							strStatus = "(活动报名中...)"
			Case else	:	strStatus = "(活动已结束.)"
							strIco = MakeImg(GBL_strImgIco & "forum_comm.gif","编号" & objRSCont("MEET_ID"))
		End Select
%>
        <TR>
          <TD height=27 width=55% align="left"><li>
					  <%
		  		strHtmlCode = ""
		If objRSCont("USER_ID") = GBL_intUserId  Then
			
			strHtmlCode = MakeLink("meet/meet_mdy_form.asp?intMeetId=" & objRSCont("MEET_ID"),"[修改/关闭/开启]","修改/关闭/开启本活动")
		End If
		
		  %>
			<A 
            href="<%=GBL_strHomeURL%>meet/meet_detail.asp?intMeetId=<%=objRSCont("MEET_ID")%>" 
            ><%=objRSCont("MEET_TITLE")%><br><%=strHtmlCode%></A></li> </TD>
          <TD width=12% height=27>
		  <span onclick=window.open("<%=GBL_strHomeURL%>address/address_userinfo_pop.asp?intUserId=<%=objRSCont("USER_ID")%>",'','left=5,top=5,width=450,height=410,scrollbars=yes,status=yes') style='cursor:hand'><%=objRSCont("USER_REALNAME")%></span> 
            </TD>
          <TD width=25% height=27><%=FormatDateTime(objRSCont("MEET_ADD_TIME"))%></TD>
          <TD width=* height=27>
		  <%
			If objRSCont("MEET_STATUS") = 0 Then
				Response.Write "<font color=red>报名中</font>"
			Else
				Response.Write "结束"
			End If
		  %></TD>

	 <TR  >
          <TD background=<%=GBL_strHomeURL%>images/meet/line2.gif colSpan=5> </TD></TR>

<%

		If i >= intMaxPerPage Then Exit Do
			objRSCont.MoveNext
		
	Loop
%>
</TABLE>
<%
End Function


%>