meet_detail.asp

jsp 同学录源码

<%
'===================================================================
'= ASP FILENAME	: /meet/meet_detail.asp
'= CREATED TIME : 2006-5-7
'= LAST MODIFIED: 2006-5-7
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 活动详细信息
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./meet_inc.asp" -->
<!-- #include file = "../inc/logic/logic_meet.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "meet/meet_detail.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "活动详细信息"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowMeetDetailCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_objDicUnit		'== 单列记录
Dim TAG_strVerifyCode	'== 表单校验
Dim TAG_strPageNav		'== 翻页导航
Dim TAG_intLastId,TAG_intNextId,TAG_intMeetId
Dim TAG_objRS

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)
 

'== 页面析构
Call ActionOver()
%>

<%
''===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-7
'= Description : 加载页面模块
'==================================================================='
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_meet_detail.html.asp" --> 
<%
End Function


''===================================================================
'= Function	   : ShowMeetDetailCtl()
'= Time		   : Created At 2006-5-7
'= Input       : None
'= Description : show meet list
'==================================================================='
Function ShowMeetDetailCtl()
	Dim intMeetId,strSql,intLastId,intNextId

	'== 获取ID参数
	If Not GetPostIdValue("intMeetId","活动",intMeetId) Then Exit Function

	'== 取本活动记录
	strSql = " AND MEET_ID=" & intMeetId
	If Not GetMeetLogic(strSql) Then Exit Function

	Set TAG_objDicUnit = GBL_objPubDB.GetRsOneRow() 

	If TAG_objDicUnit.Exists("Exist") Then

		'== 取活动总结 
		If TAG_objDicUnit.Item("MEET_STATUS") = CONST_MEET_RUN Then
			TAG_objDicUnit.Item("MEET_SUM") = "活动进行中,尚无总结.."
		End If

		'== 取上一张和下一张的ID
		Call GetLastNextMeetIdLogic(intMeetId,intLastId,intNextId)
		If intLastId = 0 Then
			TAG_intLastId = intMeetId
		Else
			TAG_intLastId = intLastId
		End If

		If intNextId = 0 Then
			TAG_intNextId = intMeetId
		Else
			TAG_intNextId = intNextId
		End If

		'== 赋ID
		TAG_intMeetId = intMeetId

		Dim strFileName 
		Dim intMaxPerPage
		Dim intCurPage,intTotalPut

		intMaxPerPage = GBL_intMaxPerPage
		TAG_intPerPage = intMaxPerPage

		strFileName = "meet_detail.asp?intMeetId=" & intMeetId

		'== 取本活动评论记录
		strSql = " AND MEET_BBS_MEET_ID=" & intMeetId
		If Not GetMeetBBSsLogic(strSql) Then Exit Function


		Set TAG_objRS = GBL_objPubDB.objPubRS

		intTotalPut = GBL_objPubDB.intRSNum

		intCurPage = GetCurPage(intMaxPerPage,intTotalPut)

		If intCurPage > 1 Then		
			If (intCurPage - 1) * intMaxPerPage < intTotalPut Then
				GBL_objPubDB.objPubRS.Move  (intCurPage - 1) * intMaxPerPage
				Dim BookMark
				BookMark = GBL_objPubDB.objPubRS.BookMark	
			End If
		End If
		
		TAG_strPageNav = ShowPageNav(intTotalPut,intMaxPerPage,intCurPage,strFileName)

		'== 发相片评论客户段表单校验生成
		Dim objClientChk
		Set objClientChk = New classClientChk
		TAG_strVerifyCode = objClientChk.ClientDataCheck("theform",arrMeetBBSDataChk)
		Set objClientChk = Nothing
	End If

End Function

Function ColumnLeftView()
	Dim strHtmlCode,strSql
	Dim intJoin,intMeetId
	Dim	intMemberFlag		'== 0-join 2-not join
	Dim blnMeetStatus : blnMeetStatus = False

	intMeetId = FmtFormData(Request.QueryString("intMeetId"))

	Dim intMeetStatus : intMeetStatus = 0
	intMeetStatus = Cint(Trim(intMeetStatus))
	intMemberFlag = 2

	'== 取得活动状态
	strSql = " AND MEET_ID=" & intMeetId & " AND MEET_STATUS=" & CONST_MEET_RUN
	If Not GetMeetLogic(strSql) Then Exit Function
	If GBL_objPubDB.intRSNum > 0 Then blnMeetStatus = True
	

	'== 取得报名总数
	strSql = " AND MEET_JOIN_MEET_ID=" & intMeetId & " AND  MEET_JOIN_STATUS=0"
	If Not GetMeetJoinsLogic(strSql) Then Exit Function
	intJoin = GBL_objPubDB.intRSNum

	'== 取得用户报名状态
	strSql = " AND MEET_JOIN_MEET_ID=" & intMeetId & " AND  MEET_JOIN_OWNER_ID=" & GBL_intUserId
	If Not GetMeetJoinsLogic(strSql) Then Exit Function
	If GBL_objPubDB.intRSNum = 1 Then
		intMemberFlag =  GBL_objPubDB.objPubRS("MEET_JOIN_STATUS")
	End If

	Dim clsTable,GBL_strImgIco,strTmp,strJoinFlag
	Set clsTable = New classTable

	'== Set table prameters
	clsTable.Border = "0"
	clsTable.CellPadding = "2"
	clsTable.CellSpacing = "1"
	clsTable.Width = "100%"
	clsTable.ClassType = ""
	clsTable.Align = "center"

	clsTable.MakeTable()

	'== Set table header
	clsTable.AddTitleTr ""
	clsTable.AddTitleTd "","","0%"
	clsTable.AddTitleTd "<br><br>目前有" & intJoin & "人表态参加活动","","100%"

	clsTable.AddInfoTr "","BOTTOM"
	strHtmlCode = "<iframe  height=470 width=165 border=0 frameborder=0 src='" & GBL_strHomeURL & "meet/meet_joinlist_pop.asp?pstAddType=0&intMeetId=" & intMeetId & "' class=list_td_change></iframe>"
	clsTable.AddInfoTd strHtmlCode,""

	clsTable.OutPutTable()
	Set clsTable = Nothing

	If intMeetStatus = 1 Then
		Exit Function
	End If

	strHtmlCode = ""
	If intMeetStatus = 0  AND blnMeetStatus = True Then

		If intMemberFlag <> 0 Then
			strTmp = MakeImg(GBL_strImgIco & "meet_join.gif","表态参与本次活动")
			strHtmlCode = MakeLinkClew("meet/meet_join.asp?strPostName=MeetJoinExec&pstActFlag=MEET_JOIN_MODE&MeetId=" & intMeetId,strTmp,""," onclick=""return confirm('您表态参与本次活动?')""") 
			strHtmlCode = ""
			%>
			<table width="164" border="1" cellpadding="0" cellspacing="0" bordercolordark="#FFFFFF" bordercolorlight="#CCCCCC" align=center>
                  <form name="vbform" method="post" action="meet_join.asp?pstActFlag=MEET_JOIN_MODE"><tr> 
					<input type="hidden" name="intMeetId" value="<%=intMeetId%>">
                  </tr>
                  <tr> 
                    <td height="100%" background="<%=GBL_strHomeURL%>images/meet/l_box1_bg.gif"> <table width="100%" border="0" align="center" cellpadding="0" cellspacing="0" >
                        <tr> 
                          <td  height="26" align="center"> 姓名： 
                            <input name="iptUser" type="text"  value="" size="15" maxlength=20>
                          </td>
                        </tr>
                        <tr> 
                          <td  align="center"> 电话： 
                            <input name="iptTel" type="text"  size="15" maxlength=40>
                          </td>
                        </tr>
						<tr> 
                          <td  align="center"> <font color="red">电话号码我们将为您保密,<br>仅管理员和发起者可见</font>
                          </td>
                        </tr>
                        <tr> 
                          <td valign="bottom" align=center> <input name="image" type="submit" value="报名"></td>
                        </tr>
                      </table>
					  </td>
                  </tr>
                </form></table>
			<%
			strJoinFlag = "[您尚未表态]"
		Else
			strTmp = MakeImg(GBL_strImgDir & "ico/meet_refuse.gif","退出参与本次活动")
			strHtmlCode = strHtmlCode & MakeLinkClew("meet/meet_join.asp?pstActFlag=MEET_EXIT_MODE&intMeetId=" & intMeetId,strTmp,""," onclick=""return confirm('您表态将取消参与本次活动?')""")
			strJoinFlag = "[你已表态参与]"
		End If
		Response.Write "&nbsp;&nbsp;" & strHtmlCode & "&nbsp;&nbsp;&nbsp;<font color=red><br>&nbsp;&nbsp;" & strJoinFlag & "</font><br>"
	End If
End Function
%>