meet_join.asp

jsp 同学录源码

<%
''===================================================================
'= ASP FILENAME	: /meet/meet_join.asp
'= CREATED TIME : 2006-5-7
'= LAST MODIFIED: 2006-5-7
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 活动报名参与或退出报名
'= Change Log:
'==================================================================='
%>
<!-- #include file = "../inc/customer/include_customer_action_execute.asp" -->
<!-- #include file = "./meet_inc.asp" -->
<!-- #include file = "../inc/logic/logic_meet.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "meet/meet_join.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "活动报名参与或退出报名"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "MeetJoinCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()

%>


<%
''===================================================================
'= Function    : MeetJoinCtl() 
'= Time	       : Created At 2006-5-7
'= Input       : None
'= Description : 活动报名参与或退出报名
'==================================================================='
Function MeetJoinCtl() 
	Dim intMeetId,strActFlag,strSql

	strActFlag = FmtFormData(Request.QueryString("pstActFlag"))
	intMeetId = FmtFormData(Request("intMeetId"))

	'== 退出活动
	If strActFlag = "MEET_EXIT_MODE" Then
		strSql = " AND MEET_JOIN_OWNER_ID=" & GBL_intUserId & " AND MEET_JOIN_MEET_ID=" & intMeetId
		If Not RemoveMeetJoinsLogic(strSql) Then Exit Function
	ElseIf strActFlag = "MEET_JOIN_MODE" Then '== 加入活动

		'== 服务器端数据校验
		If Not ServerDataCheck(arrMeetJoinDataChk) Then Exit Function

		'== 数据获取
		Call CnvFormData(strMeetJoinFormName,GBL_objFormData)

		'== 逻辑处理
		If Not SaveMeetJoinLogic(GBL_intUserId,intMeetId,GBL_objFormData) Then Exit Function

	Else
		Call GBL_objException.catchErr(E_USER_PUB,"校友活动表态模式不正确")
		Exit Function
	End If

	'== 成功处理
	Dim strHtmlCode,strSuccUrl
	strHtmlCode = "操作成功"
	strSuccUrl = "meet/meet_detail.asp?intMeetId=" & intMeetId
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function
%>