frmfull.frm

管理电子相片 可以进行上传 评价 浏览 等操作

Private Sub opFull_Click(Index As Integer)

    Select Case Index
    '-- 播放
        Case 0
            Call frmMain.Commands_ButtonClick(frmMain.Commands.Buttons("Play"))
            frmMain.Commands.Buttons("Play").Value = tbrPressed
            opFull(0).Checked = True
            opFull(1).Checked = False
    
    '-- 暂停
        Case 1
            Call frmMain.Commands_ButtonClick(frmMain.Commands.Buttons("Pause"))
            frmMain.Commands.Buttons("Pause").Value = tbrPressed
            opFull(0).Checked = False
            opFull(1).Checked = True
                
    '-- 上一张
        Case 3
            Call frmMain.Commands_ButtonClick(frmMain.Commands.Buttons("Previous"))
                
    '-- 下一张
        Case 4
            Call frmMain.Commands_ButtonClick(frmMain.Commands.Buttons("Next"))
    
    '-- 第一张
        Case 6
            Call frmMain.Commands_ButtonClick(frmMain.Commands.Buttons("First"))
    
    '-- 最后一张
        Case 7
            Call frmMain.Commands_ButtonClick(frmMain.Commands.Buttons("Last"))
                
    '-- 放大
        Case 11
            Image_Full.ZoomIn
            If (Image_Full.ZoomPercent = 100) Then
                opFull(13).Checked = True
              Else
                opFull(13).Checked = False
            End If
            opFull(14).Checked = False
    
    '-- 缩小
        Case 12
            Image_Full.ZoomOut
            If (Image_Full.ZoomPercent = 100) Then
                opFull(13).Checked = True
            Else
                opFull(13).Checked = False
            End If
            opFull(14).Checked = False
        
    '-- 100%
        Case 13
            Image_Full.ZoomReal
            opFull(13).Checked = True
            opFull(14).Checked = False
                
    '-- 最适合大小
        Case 14
            opFull(14).Checked = Not opFull(14).Checked
            If (opFull(14).Checked = True) Then
                Image_Full.BestFit
                opFull(13).Checked = False
              Else
                Image_Full.ZoomReal
                opFull(13).Checked = True
            End If
        
    '-- 编辑图片
        Case 16
             '-- 调用frmMain窗体OpThumb控件Click事件的第2分支点
            frmMain.OpThumb_Click (2)
                
    '-- 重新装载
        Case 17
            tmpPath = ""
            tmpPathFull = ""
            frmMain.Show_Picture
                
    '-- 说明
        Case 19
            If (opFull(19).Caption = "显示说明") Then
                opFull(19).Caption = "隐藏说明"
                frmComments.Show , Me
                Image_Full.SetFocus
              Else
                opFull(19).Caption = "显示说明"
                frmComments.Hide
            End If
    
    '-- 时间
        Case 20
            If (opFull(20).Caption = "显示时间") Then
                opFull(20).Caption = "隐藏时间"
                Watch = Format(Now, "hh:mm")
                frameWatch.Visible = True
                timerWatch.Enabled = True
              Else
                opFull(20).Caption = "显示时间"
                frameWatch.Visible = False
                timerWatch.Enabled = False
            End If
        
    '-- 退出
        Case 23
            Me.Hide
            '-- TreeView树型控件不可见
            '-- 双击返回frmMain主窗体
            frmMain.TreeView.Visible = False
            frmMain.timerEnableTreeview.Enabled = True
            
            '-- 显示上一张图片
            If (tmpPathPreview <> tmpPath) Then frmMain.Show_Picture
            
            '-- 更新frmComments窗体状态
            If (opFull(19).Caption = "显示说明") Then
                frmMain.chkComments = 0
                 '-- frmComments窗体隐藏
                frmComments.Hide
              Else
                frmMain.chkComments = 1
                '-- 显示frmComments窗体
                frmComments.Show , frmMain
                '-- frmMain窗体获取焦点
                frmMain.SetFocus
            End If
                   
    End Select
    
    '-- 控制放大功能能否使用
    If (Image_Full.ZoomPercent = 200) Then
        opFull(11).Enabled = False
      Else
        opFull(11).Enabled = True
    End If
    
    '-- 控制缩小功能能否使用
    If (Image_Full.ZoomPercent = 5) Then
        opFull(12).Enabled = False
      Else
        opFull(12).Enabled = True
    End If
End Sub

Private Sub opDelay_Click(Index As Integer)
    
    '-- 对所有的都不进行核对
    For i = 0 To opDelay.Count - 1
        opDelay(i).Checked = False
    Next i
    
    '-- 核对目前的选择
    opDelay(Index).Checked = True
    opFull(9).Caption = "Delay: " & Choose(Index + 1, "1 sec.", "2 sec.", "3 sec.", "4 sec.", "5 sec.", "10 sec.", "30 sec.", "1 min.")
    '-- 设置新的延时
    With frmMain.timerShowPictures
        .Enabled = False
        .Interval = Choose(Index + 1, 1000, 2000, 3000, 4000, 5000, 10000, 30000, 60000)
        If (opFull(0).Checked) Then .Enabled = True
    End With
End Sub

Private Sub opColor_Click(Index As Integer)

    '-- 对所有的都不进行核对
    For i = 0 To opColor.Count - 1
        opColor(i).Checked = False
    Next i
    
    '-- 核对目前的选择
    opColor(Index).Checked = True
    
    '--设置新的背景颜色
    Me.BackColor = Choose(Index + 1, vbBlack, vbBlue, vbRed, &HC000&)
    Image_Full.BackColor = Me.BackColor
    frameWatch.BackColor = Me.BackColor
    
    '-- 重新刷新图片
    If (opFull(14).Checked) Then
        Image_Full.BestFit
      Else
        Image_Full.ZoomPrevious
    End If
End Sub

'------------------------------------------------------------------------------
' 设置键盘控制
'------------------------------------------------------------------------------

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    
    Select Case KeyCode
    '-- 弹出菜单 ([Alt])
        Case 18
            PopupMenu Image_Full_Menu
            
    '-- 播放/暂停 ([Space])
        Case 32
            If (opFull(0).Checked = False) Then
                opFull_Click (0) '播放
              Else
                opFull_Click (1) '暂停
            End If
                
    '-- 上一张 ([Page up])
        Case 33
            opFull_Click (3)
                
    '-- 下一张 ([Page down])
        Case 34
            opFull_Click (4)
                
    '-- 第一张 ([Start])
        Case 36
            opFull_Click (6)
                
    '-- 最后一张 ([End])
        Case 35
            opFull_Click (7)
                
    '-- 放大 ([+])
        Case 107
            opFull_Click (11)
                
    '-- 缩小 ([-])
        Case 109
            opFull_Click (12)
                
    '-- 100 % ([R])
        Case 82
            opFull_Click (13)
                
    '-- 最适合大小 ([B])
        Case 66
            opFull_Click (14)
                
    '-- 显示/隐藏说明 ([C])
        Case 67
            opFull_Click (19)
                
    '-- 显示/隐藏时间 ([W])
        Case 87
            opFull_Click (20)
                
    '-- 退出 ([Return])
        Case 13
            opFull_Click (23)
    
    End Select
End Sub

'------------------------------------------------------------------------------
' 时间
'------------------------------------------------------------------------------

Private Sub timerWatch_Timer()
    '-- 显示系统时间，时间格式为hh:mm
    Watch = Format(Now, "hh:mm")
End Sub