edit.asp

功能齐全的oa系统

<%option explicit%>
<!-- #include virtual="include/DataEnvi.asp" -->
<!-- #include virtual="include/String.asp" -->
<!-- #include virtual="include/SelectValue.asp" -->
<!-- #include virtual="include/GetTrueNames.asp" -->
<!-- #include file="Function.asp" -->
<%
Dim intFlowID
intFlowID = Request.QueryString("ID")
%>
<script language=javaScript>
function doEdit(){
  var re = parent.doAlert(2,"确定要修改？")
  if (!re) return
  thisForm.Action.value   = "Edit"
  if(CheckForm(document.forms[0])) thisForm.submit() 
}

function doReset(){
  var re = parent.doAlert(2,"注意：重置后工作流节点全部被删除，是否继续？")
  if (!re) return
  thisForm.Action.value = "Reset"
  thisForm.submit()
}

function doAccountList()
{
  window.location = "AccountList.asp?ID=" + <%=intFlowID%>;
}
</script>
<%
Dim ObjDB,FlowObjRS,FlowNodeObjRS,StrSQL
Dim C
Dim ArrList,i,j,IntRows,IntCols
Dim StrOption
Dim Action,FlowNodIDS,FlowName,NodeName,ExecuteID,PassType,IsNeed,objRS,k
Dim FlowIsValid

FlowIsValid = False

Set ObjDB = Server.CreateObject("Adodb.Connection")
OpenDB ObjDB

Action  = Request.Form("Action")

IF Action <> "" THEN
  FlowNodIDS  = Request.Form("FlowNodIDS")
  FlowName  = FixSQL(Request.Form("FlowName"))
  NodeName  = FixSQL(Request.Form("NodeName"))
  ExecuteID = Request.Form("ExecuteID")
  PassType  = Request.Form("PassType")
  IsNeed    = Request.Form("IsNeed")
  
  Set objRS = Server.CreateObject("ADODB.Recordset")
  If Action =  "Edit" Then
    FlowNodIDS  = Split(FlowNodIDS,",")
    NodeName  = Split(NodeName,",")
    ExecuteID = Split(ExecuteID,", ")
    PassType  = Split(PassType,",")
    IsNeed    = Split(IsNeed,",")
  
    strSQL = "select * from t_OA_Work_Flow Where ID = " & intFlowID
    objRS.Open strSQL,objDB,1,3
    objRS.Fields("FlowName")  = FlowName
    objRS.Update()
    objRS.Close()
  
    For k = LBound(FlowNodIDS) To UBound(FlowNodIDS)
      strSQL    = "select * from t_OA_Work_Flow_Node Where ID = " & FlowNodIDS(k)
      objRS.Open strSQL,objDB,1,3 
      objRS.Fields("NodeName")  = Trim(NodeName(k))
      objRS.Fields("ExecuteID") = ExecuteID(k)
      objRS.Fields("PassType")  = PassType(k)
      objRS.Fields("IsNeed")    = IsNeed(k)
      objRS.Update()
      objRS.Close()
    Next
  ElseIf Action =  "Reset" Then
    strSQL    = "select IsValid from t_OA_Work_Flow Where ID = " & intFlowID
    objRS.Open strSQL,objDB,1,3
    objRS.Fields("IsValid") = 0
    objRS.Update()
    objRS.Close()

    strSQL  = "Delete From t_OA_Work_Flow_Node Where ID In (" & FlowNodIDS  &")"
    ObjDB.Execute(strSQL)
  End If
  Set objRS = Nothing
  Response.Redirect "List.asp"
END IF

Set C = Server.CreateObject("CMS2003.DBHandle")
C.Init(ObjDB)
Set FlowObjRS = C.View("Select * From t_OA_Work_Flow Where ID = " & FixSQL(intFlowID) )

if FlowObjRS("IsValid") then
  FlowIsValid = true
end if

StrSQL = "Select ID,NodeName,ExecuteID,PassType,IsNeed,IsAllPass From t_OA_Work_Flow_Node Where FlowID = " & FixSQL(intFlowID) 
StrSQL = StrSQL & "order by parentid"

ArrList = C.List(1,0,StrSQL)      '使用List()函数获得列表数组
IntRows = C.GetRows()             '使用GetRows()获得总返回的行数
IntCols = C.GetCols()             '使用GetCols()获得总返回的列数

Sub Main%>
  <form action="" method="post" name=thisForm onsubmit=return(CheckForm(this))>
  <table class=Ltable cellspacing=1 cellpadding=3>
  <tr class=LHtr>
    <td width="15%">工作流修改</td>
    <td width="85%"></td>
  </tr>
  <tr class=Ltr>
    <td>工作流名称</td>
    <td><input type="text" name="FlowName" Check=1 Show="工作流名称" class=Input value="<%=FlowObjRS("FlowName")%>"></td>
  </tr>
  <tr class=Ltr>
    <td>创建时间</td>
    <td><input type="text" readonly value="<%=FlowObjRS("CreateTime")%>"  class=Input></td>
  </tr>
  </table>
  
  <table>
  <tr>
  <td><%Call DrawNode("起始节点","创建人",1,0,2)%></td>
  <td><img src="<%=Application("RootPath")%>Images/OA/Work/Flow/Next.gif"></td>
<%
  Dim StrColor, RS, ChildID
  For i = 0 To IntRows
    if i = 0 then
      StrSQL = "Select * From t_OA_Work_Flow_Node Where FlowID = " & FixSQL(intFlowID) & " and ParentID = 0 "
      Set RS = ObjDB.Execute(StrSQL)
      ChildID = RS("ChildID")
    else
      if ChildID <> -1 then
        StrSQL = "Select * From t_OA_Work_Flow_Node Where ID = " & ChildID
        Set RS = ObjDB.Execute(StrSQL)
        ChildID = RS("ChildID")
      end if
    end if 
    'ID,NodeName,ExecuteID,PassType,IsNeed,IsAllPass
%>
  <td><%Call DrawNode(FixStr(RS("NodeName")),Replace(GetTrueNames(ObjDB,RS("ExecuteID")),Vbcrlf,"<br>"),RS("IsAllPass"),RS("PassType"),RS("IsNeed"))%></td>
  <td><img src="<%=Application("RootPath")%>Images/OA/Work/Flow/Next.gif"></td>
<%
  Next
%>
  <td><%Call DrawNode("结束节点","归档人",1,0,2)%></td>
  </tr>
  </table>
  <table class=Ltable cellspacing=1 cellpadding=3>
  <tr class=LStr align=center>
  <td width=1%></td>
  <td width=18%>节 点 名 称</td>
  <td width=18%>处  理  人</td>
  <td width=10%>是 否 审 批</td>
  <td width=10%>是 否 等 待</td>
  <td width=10%>是否全体通过</td>
  <td width=10%>是否删除节点</td>
  </tr>
<%  
  For i = 0 To IntRows  
    if i = 0 then
      StrSQL = "Select * From t_OA_Work_Flow_Node Where FlowID = " & FixSQL(intFlowID) & " and ParentID = 0 "
      Set RS = ObjDB.Execute(StrSQL)
      ChildID = RS("ChildID")
    else
      StrSQL = "Select * From t_OA_Work_Flow_Node Where ID = " & ChildID
      Set RS = ObjDB.Execute(StrSQL)
      ChildID = RS("ChildID")
    end if 
    'ID,NodeName,ExecuteID,PassType,IsNeed,IsAllPass
%>
    <input type=hidden name="FlowNodIDS" value="<%=RS("ID")%>">
  <tr class=Ltr>
    <td><img src='../../../images/oa/work/flow/node.gif'></td>
    <td><input name=NodeName Check=1 Show="节点名称" class=Input2 value="<%=RS("NodeName")%>"></td>
    <td>
    <input name=ExecuteID value="<%=Replace(RS("ExecuteID")," ","")%>"></td>
<%
    if RS("PassType") = 1 then
      StrOption = "<option value=1 selected>是</option><option value=0>否</option>"
    else
      StrOption = "<option value=1 >是</option><option value=0 selected>否</option>"
    end if
%>
    <td><select name=PassType><%=StrOption%></select></td>
<% 
    if RS("IsNeed") then
      StrOption = "<option value=1 selected>是</option><option value=0>否</option>"
    else
      StrOption = "<option value=1 >是</option><option value=0 selected>否</option>"
    end if
%>
      <td><select name=IsNeed><%=StrOption%></select></td>
      <td>
      <select name=IsAllPass>
      <option value=1 <%If RS("IsAllPass") Then Response.Write "Selected"%>>是</option>
      <option value=0 <%If Not RS("IsAllPass") Then Response.Write "Selected"%>>否</option>
      </select>
      </td>
      <td align=center>
        <a href="EditDelNode.asp?ID=<%=RS("ID")%>">删除</a>
      </td>
  </tr>
<%
  Next
%>
  </table>
  </td></tr>
  <tr>
    <td></td><td align=right><input type=button  onclick="doEdit()" class=button  value="确定更改"><input class=button type=button value="处理人账号与姓名对应查询" onclick="doAccountList()"><input class=button type=button value="新增节点" onclick="window.location.href='EditAddNode.asp?ID=<%=intFlowID%>'"><input class=button type=button value="取    消" onclick="window.location.href='list.asp'"></td>
  </tr>                                                                                                                                                                                       
  </table>                                                                                                                                                                                    
<input type=hidden name="Action" value="">                                                                                                                                                    
</form>                                                                                                                                                                                       
<%
End Sub
%>
<!-- #include file="Templet.asp" -->