ok3w_guest.asp

html生成静态页的小程序

<%
Class Ok3w_Guest
    Public Id
    Public UserName
    Public Mail
    Public Homepage
    Public Content
    Public QQ
    Public TypeID
	Public TableID
    Public AddTime
    Public Ip
	Public IsPass
	Public Ad_ask
	
    '类初始化
    Private Sub Class_Initialize()
    End Sub
	
    '类终止
    Private Sub Class_Terminate()
    End Sub
	
    '添加记录
    Public Sub Add()
        Call GetFormData()
        Set clsRs = Server.CreateObject("Adodb.RecordSet")
        Sql = "select * from Ok3w_Guest where 1=2"
        clsRs.Open Sql,Conn,1,3
        clsRs.AddNew()
        Call UpdateRs(clsRs)
        clsRs.Update()
        clsRs.Close()
        Set clsRs = Nothing
    End Sub
	
	 '回复
    Public Sub Ask(Cask,Content,IsPass,ID)
        Set clsRs = Server.CreateObject("Adodb.RecordSet")
        Sql = "select * from Ok3w_Guest where Id=" & ID
        clsRs.Open Sql,Conn,1,3
		clsRs("Ad_ask") = Cask
		clsRs("Content") = Content
		clsRs("IsPass") = IsPass
        clsRs.Update()
        clsRs.Close()
        Set clsRs = Nothing
    End Sub
	
    '开通/关闭新闻
	Public Sub Pass(action,Id)
		If Id <> "" Then
			sql = "update Ok3w_Guest set IsPass=" & action & " where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub
	
	'删除
	Public Sub Del(Id)
		If Id <> "" Then
			sql = "delete from Ok3w_Guest where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub	
	
    '接收表单
    Private Sub GetFormData()
        UserName = Trim(Request.Form("username"))
        Mail = Trim(Request.Form("email"))
        Homepage = Trim(Request.Form("homeurl"))
        Content = Trim(Request.Form("content"))
        QQ = Trim(Request.Form("qq"))
        TypeID = Trim(Request.Form("TypeID"))
		If TypeID="" Then TypeID=1
		TableID = Trim(Request.Form("TableID"))
		If TableID="" Then TableID=0
        AddTime = Now()
        Ip = Request.ServerVariables("REMOTE_ADDR")
		IsPass = 0
		Ad_ask = ""
    End Sub
	
    '更新记录集
    Private Sub UpdateRs(ByRef Rs)
        Rs("UserName") = UserName
        Rs("Mail") = Mail
        Rs("Homepage") = Homepage
        Rs("Content") = Content
        Rs("QQ") = QQ
        Rs("TypeID") = TypeID
		Rs("TableID") = TableID
        Rs("AddTime") = AddTime
        Rs("Ip") = Ip
		Rs("IsPass") = IsPass
		Rs("Ad_ask") = Ad_ask
    End Sub
	
    '从记录集中读数据
    Public Sub GetRs(ByRef Rs)
        Id = Rs("Id")
        UserName = Rs("UserName")
        Mail = Rs("Mail")
        Homepage = Rs("Homepage")
        Content = Rs("Content")
        QQ = Rs("QQ")
        TypeID = Rs("TypeID")
		TableID = Rs("TableID")
        AddTime = Rs("AddTime")
        Ip = Rs("Ip")
		IsPass = Rs("IsPass")
		Ad_ask = Rs("Ad_ask")
    End Sub
End Class
%>