ok3w_article.asp

html生成静态页的小程序

<%
Class Ok3w_Article
    Public Id
    Public ChannelID
    Public ClassID
	Public SortPath
    Public Title
    Public Content
    Public Author
    Public ComeFrom
    Public AddTime
    Public Inputer
    Public IsPass
    Public IsPic
    Public PicFile
    Public IsTop
    Public IsCommend
	Public IsDelete
	Public IsMove
	Public IsPlay
    Public Hits
	
    '类初始化
    Private Sub Class_Initialize()
		IsPass = 1
		Hits = 0
		AddTime = Now()
		ComeFrom = SysSiteName
		Author = SysSiteName
    End Sub
    '类终止
    Private Sub Class_Terminate()
    End Sub
	
	'读记录
	Public Sub Load(Id)
		Set clsRs = Server.CreateObject("Adodb.RecordSet")
		Sql = "select * from Ok3w_Article where Id=" & Id
        clsRs.Open Sql,Conn,1,1
		If clsRs.Eof And clsRs.Bof Then
			Response.Write("资源不存在")
			Response.End()
		End If
        Call GetRs(clsRs)
        clsRs.Close()
        Set clsRs = Nothing
	End Sub
	
	'点击数加1
	Public Sub HitsAdd(Id)
		Sql = "update Ok3w_Article set Hits = Hits + 1 where Id=" & Id
		Conn.Execute Sql
	End Sub
	
    '添加记录
    Public Sub Add()
        Call GetFormData()
        Set clsRs = Server.CreateObject("Adodb.RecordSet")
        Sql = "select * from Ok3w_Article where 1=2"
        clsRs.Open Sql,Conn,1,3
        clsRs.AddNew()
        Call UpdateRs(clsRs)
        clsRs.Update()
        clsRs.Close()
        Set clsRs = Nothing
    End Sub
    '修改记录
    Public Sub Edit()
        Call GetFormData()
        Set clsRs = Server.CreateObject("Adodb.RecordSet")
        Sql = "select * from Ok3w_Article where Id= " & Id
        clsRs.Open Sql,Conn,1,3
        Call UpdateRs(clsRs)
        clsRs.Update
        clsRs.Close
        Set Rs = Nothing
    End Sub
    
    '接收表单
    Private Sub GetFormData()
        Id = Request.QueryString("Id")
		If Id = "" Then Id=GetMaxArticleID()+1
        ChannelID = Request.QueryString("ChannelID")
        ClassID = Request.Form("ClassID")
		If ClassID="" Then
			ClassID = -1
			SortPath = ""
			Else
				SortPath = Conn.Execute("select SortPath from Ok3w_Class where ID=" & ClassID)(0)
		End If
        Title = Request.Form("Title")
		For i = 1 To Request.Form("Content").Count 
			Content = Content & Request.Form("Content")(i) 
		Next
        Author = Request.Form("Author")
        ComeFrom = Request.Form("ComeFrom")
        AddTime = Request.Form("AddTime")
		Inputer = Request.Form("Inputer")
		If Inputer="" Then Inputer = Admin.AdminName
        IsPass = Request.Form("IsPass")
		If IsPass = "" Then IsPass = 0
        IsPic = Request.Form("IsPic")
		If IsPic = "" Then IsPic = 0
        PicFile = Request.Form("PicFile")
        IsTop = Request.Form("IsTop")
		If IsTop = "" Then IsTop = 0
        IsCommend = Request.Form("IsCommend")
		If IsCommend = "" Then IsCommend = 0
		IsDelete = Request.Form("IsDelete")
		If IsDelete = "" Then IsDelete = 0
		IsMove = Request.Form("IsMove")
		If IsMove = "" Then IsMove = 0
		IsPlay = Request.Form("IsPlay")
		If IsPlay = "" Then IsPlay = 0
        Hits = Request.Form("Hits")
    End Sub
    '更新记录集
    Private Sub UpdateRs(ByRef Rs)
		Rs("ID") = Id
        Rs("ChannelID") = ChannelID
        Rs("ClassID") = ClassID
		Rs("SortPath") = SortPath
        Rs("Title") = Title
        Rs("Content") = Content
        Rs("Author") = Author
        Rs("ComeFrom") = ComeFrom
        Rs("AddTime") = AddTime
        Rs("Inputer") = Inputer
        Rs("IsPass") = IsPass
        Rs("IsPic") = IsPic
        Rs("PicFile") = PicFile
        Rs("IsTop") = IsTop
        Rs("IsCommend") = IsCommend
		Rs("IsDelete") = IsDelete
		Rs("IsMove") = IsMove
		Rs("IsPlay") = IsPlay
        Rs("Hits") = Hits
    End Sub
    '从记录集中读数据
    Private Sub GetRs(ByRef Rs)
        Id = Rs("Id")
        ChannelID = Rs("ChannelID")
        ClassID = Rs("ClassID")
		SortPath = Rs("SortPath")
        Title = Rs("Title")
        Content = Rs("Content")
        Author = Rs("Author")
        ComeFrom = Rs("ComeFrom")
        AddTime = Rs("AddTime")
        Inputer = Rs("Inputer")
        IsPass = Rs("IsPass")
        IsPic = Rs("IsPic")
		PicFile = Rs("PicFile")
        IsTop = Rs("IsTop")
        IsCommend = Rs("IsCommend")
		IsDelete = Rs("IsDelete")
		IsMove = Rs("IsMove")
		IsPlay = Rs("IsPlay")
        Hits = Rs("Hits")
    End Sub
	
	'开通/关闭新闻
	Public Sub Pass(action,Id)
		If Id <> "" Then
			sql = "update Ok3w_Article set IsPass=" & action & " where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub
	
	'置顶/取消置顶
	Public Sub Top(action,Id)
		If Id <> "" Then
			sql = "update Ok3w_Article set IsTop=" & action & " where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub

	'推荐/取消推荐
	Public Sub Commend(action,Id)
		If Id <> "" Then
			sql = "update Ok3w_Article set IsCommend=" & action & " where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub
	
	'图片/取消图片
	Public Sub Pic(action,Id)
		If Id <> "" Then
			sql = "update Ok3w_Article set IsPic=" & action & " where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub
	
	'恢复
	Public Sub Resumption(action,Id)
		If Id <> "" Then
			sql = "update Ok3w_Article set  IsDelete=0 where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub

	'删除
	Public Sub Del(Id)
		If Id <> "" Then	
			Sql="select ID,ChannelID,PicFile from Ok3w_Article where Id  in(" & Id & ")"
			Rs.Open Sql,Conn,0,1
			Do While Not Rs.Eof
				If Rs("PicFile")<>"" Then Call DeleteFile("../" & Rs("PicFile"))
				If Rs("ChannelID")=1 Then
					Call DeleteFile("../article/" & Rs("ID") & ".html")
					Else
						Call DeleteFile("../about/" & Rs("ID") & ".html")
				End If
				Rs.MoveNext
			Loop
			Rs.Close
			
			Sql = "update Ok3w_Article set IsDelete=1 where Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub
	
	'彻底删除
	Public Sub OkDel(Id)
		If Id <> "" Then
			sql = "delete from Ok3w_Article where IsDelete=1 and Id in(" & Id & ")"
			Conn.Execute sql
		End If
	End Sub
	
	'取最大ArticleID
    Public Function GetMaxArticleID()
        Set clsRs = Server.CreateObject("Adodb.RecordSet")
        Sql = "select max(ID) from Ok3w_Article"
        clsRs.Open Sql,Conn,0,1
        If IsNull(clsRs(0)) Then
        GetMaxArticleID = 0
            Else
                GetMaxArticleID = clsRs(0)
        End If
        clsRs.Close
        Set clsRs = Nothing
    End Function
End Class
%>