main.pas

Java实例入门

unit Main;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TMainForm = class(TForm)
    Button1: TButton;
    ListBox1: TListBox;
    procedure Button1Click(Sender: TObject);
  private
    procedure ThreadsDone(Sender: TObject);
  end;

  TFooThread = class(TThread)
  protected
    procedure Execute; override;
  end;

var
  MainForm: TMainForm;

implementation

{$R *.DFM}

const
  MaxSize = 128;

var
  NextNumber: Integer = 0;
  DoneFlags: Integer = 0;
  GlobalArray: array[1..MaxSize] of Integer;
  hMutex: THandle = 0;

function GetNextNumber: Integer;
begin
  Result := NextNumber;
  Inc(NextNumber);
end;

procedure TFooThread.Execute;
var
  i: Integer;
begin
  FreeOnTerminate := True;
  OnTerminate := MainForm.ThreadsDone;
  if WaitForSingleObject(hMutex, INFINITE) = WAIT_OBJECT_0 then
  {如果指定的线程对象处于发信号状态}
  begin
    //下面为需要保护的资源
    for i := 1 to MaxSize do
    begin
      GlobalArray[i] := GetNextNumber;  // 为每个数组元素赋值
      Sleep(5);                         // 让线程睡眠一会
    end;
  end;
  ReleaseMutex(hMutex);     //释放互斥量
end;

procedure TMainForm.ThreadsDone(Sender: TObject);
var
  i: Integer;
begin
  Inc(DoneFlags);
  if DoneFlags = 2 then    // 确保两个线程已执行完毕
  begin
    for i := 1 to MaxSize do
      // 将每个数组元素值添加到列表框
    Listbox1.Items.Add(IntToStr(GlobalArray[i]));
    CloseHandle(hMutex);  //关闭互斥量
  end;
end;

procedure TMainForm.Button1Click(Sender: TObject);
begin
  hMutex := CreateMutex(nil, False, nil);  //创建互斥量
  {创建两个线程}
  TFooThread.Create(False);
  TFooThread.Create(False);
end;

end.