📄 admin_loadskin.asp
字号:
<!--#include file="Inc/Const.asp"-->
<%
if Not Cl.TrueOtherPurview("Template") then
Cl.ShowErr("<br /><li>您无此操作权限！</li>")
End if
Header
%>
<table border="0" cellspacing="1" cellpadding="5" align="center" width="95%" class="border">
<tr>
<td colspan="3" align="center" class="title">网站风格及模板数据管理</td>
</tr>
<tr>
<td class="tdbg">
注意：<br />
１，确认模板数据库名正确；<br />
２，如模板数据库放在Skins目录下，即填写：../Skins/Cl_Skins.mdb；<br />
３，模板数据库内备份的表名为Cl_TemplateProject、Cl_Template、Cl_Css，请不要更改。
</td>
</tr>
<tr class="title2">
<td><b>
<a href="Admin_LoadSkin.asp">网站模板导出</a> | <a href="Admin_LoadSkin.asp?action=Load">网站模板导入</a></b>
</td>
</tr>
</table>
<br />
<%
Dim Action
Dim sProjectID,mdbname,StyleConn
mdbname = "../Skins/Cl_Skins.mdb"
Action = Request("action")
Select Case Action
Case "DoOut","DoJoin"
Call LoadSkin()
Case "Load"
Call load()
Case Else
Call Main()
End Select
Footer
Sub Main()
Dim tAction,tName
If Action="Join" Then
tName = "导入"
tAction = "DoJoin"
mdbname = Cl.Checkstr(Request("skinmdb"))
If mdbname = "" Then Cl.ShowErr("<li>请填写导出模板保存的表名")
Else
tName = "导出"
tAction = "DoOut"
End If
%>
<script language="JavaScript" type="text/javascript">
function unselectall()
{
if(document.myform.chkAll.checked){
document.myform.chkAll.checked = document.myform.chkAll.checked;
}
}
function CheckAll(form)
{
for (var i=0;i<form.elements.length;i++)
{
var e = form.elements[i];
if (e.name != "chkAll"&&e.disabled==false)
e.checked = form.chkAll.checked;
}
}
</script>
<table border="0" cellspacing="1" cellpadding="4" align="center" width="95%" class="border">
<tr><td width="100%" colspan="5" class="title"><%=tName%>网站模板列表</td></tr>
<tr class="title2">
<td width="5%" align="center">选择</td>
<td width="10%" align="center">序号</td>
<td width="25%" align="center">模板名称</td>
<td width="40%" align="center">模板说明</td>
<td width="20%" align="center">模板设计</td>
</tr>
<form action="?action=<%=tAction%>" method="post" name="even" id="even">
<%
SQL="select * from Cl_TemplateProject order by ProjectID"
If Action="Join" Then
SkinConnection(mdbname)
set Rs=StyleConn.Execute(SQL)
Else
set Rs=Cl.Execute(SQL)
End If
do while not Rs.eof
%>
<tr class="tdbg">
<td align="center"><input type="checkbox" name="ProjectID" value="<%=Rs("ProjectID")%>" /></td>
<td align="center"><%=Rs("ProjectID")%></td>
<td><%=Rs("ProjectName")%></td>
<td ><%=Rs("ProjectIntro")%></td>
<td align="center"><%=Rs("Deviser")%>(<a href="mailto:<%=Rs("DeviserEmail")%>" class="blue">邮箱</a>)(<a href="<%=Rs("DeviserHomePage")%>" target="_blank" class="blue">主页</a>)
</td>
</tr>
<% Rs.movenext
loop
Rs.close:Set Rs=Nothing
%>
<tr class="tdbg">
<td colspan="2" align="left">
<input type="checkbox" name="chkAll" value="on" onClick="CheckAll(this.form)" /> 全选</td>
<td colspan="3" align="left">
<%=tName%>的数据库：
<input type="text" name="skinmdb" size="30" value="<%=mdbname%>" <%If Action="Join" Then Response.write "readonly"%> />
<input type="submit" name="submit" value="<%=tName%>" />
<input type="submit" name="submit" value="删除" onclick="return confirm('注意：所删除的模板将不能恢复！')" />
<%If Action<>"Join" then%>
<input type="checkbox" name="Clear" value="yes" checked /> 先清空目标
<%End if%>
</td>
</tr>
</form>
</table>
<%
End Sub
Sub Load()
%>
<form action="Admin_LoadSkin.asp" method="get">
<table border="0" cellspacing="1" cellpadding="5" height="1" align="center" width="95%" class="border">
<tr><td colspan="2" class="title">导入模板数据</td></tr>
<tr>
<td width="20%" class="tdbg">导入模板数据库名：</td>
<td width="80%" class="tdbg">
<input type="text" name="skinmdb" size="30" value="<%=mdbname%>" />
<input type="hidden" name="Action" value="Join" />
</td>
</tr>
<tr><td colspan="2" class="tdbg"><input type="submit" name="submit" value="下一步" /></td></tr>
</table></form>
<%
End Sub
Sub SkinConnection(mdbname)
On Error Resume Next
Set StyleConn = Server.CreateObject("ADODB.Connection")
StyleConn.open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(mdbname)
If Err.Number ="-2147467259" Then
Cl.ShowErr("<li>"&Server.MapPath(mdbname)&"数据库不存在。")
Response.end
End If
End Sub
Sub LoadSkin()
Dim tName
If Action="DoOut" Then
tName = "导出"
Else
tName = "导入"
End if
sProjectID = Cl.checkstr(Request("ProjectID"))
mdbname = Cl.Checkstr(Trim(Request.form("skinmdb")))
If sProjectID="" or Isnull(sProjectID) or Not IsNumeric(Replace(Replace(sProjectID,",","")," ","")) Then
Cl.ShowErr("<li>您还未选取要"&tName&"的模板，或参数有错误！")
End If
If mdbname="" Then Cl.ShowErr("<li>请请填写"&tName&"模板数据库名")
SkinConnection(mdbname)
Dim OutConn,JoinConn
OpenConn
If Action="DoOut" Then
If Request("Clear")="yes" Then
StyleConn.Execute("Delete from Cl_TemplateProject")
StyleConn.Execute("Delete from Cl_Template")
StyleConn.Execute("Delete from Cl_Css")
End if
Set OutConn = Conn
Set JoinConn= StyleConn
Else
If Request("submit")="删除" Then
StyleConn.Execute("Delete from Cl_TemplateProject where ProjectID in ("&sProjectID&")")
StyleConn.Execute("Delete from Cl_Template where ProjectID in ("&sProjectID&")")
StyleConn.Execute("Delete from Cl_Css where ProjectID in ("&sProjectID&")")
Call Cl.ShowSuc("恭喜您，模板删除成功。")
Exit Sub
End if
Set OutConn = StyleConn
Set JoinConn= Conn
End if
set Rs = OutConn.Execute("select * from Cl_TemplateProject where ProjectID in ("&sProjectID&") order by ProjectID ")
If Rs.EOF Or Rs.BOF Then
Cl.ShowErr("<br /><li>无法取出源模板数据")
End If
Dim tProjectID,tProjectName
Dim nProjectID,nCssID
Dim tRs,cRs,nRs
nProjectID = JoinConn.Execute("select max(ProjectID) from Cl_TemplateProject")(0)
If IsNull(nProjectID) Or Not IsNumeric(nProjectID) Then nProjectID=0
nProjectID = nProjectID + 1
nCssID = JoinConn.Execute("select max(CssID) from Cl_Css")(0)
If IsNull(nCssID) Or Not IsNumeric(nCssID) Then nCssID=0
nCssID = nCssID + 1
Set tRs = Server.CreateObject("Adodb.RecordSet")
Set cRs = Server.CreateObject("Adodb.RecordSet")
Set nRs = Server.CreateObject("Adodb.RecordSet")
Do while not Rs.eof
tProjectID = Rs("ProjectID")
tProjectName = Rs("ProjectName")
Rem 导出Project
nRs.Open "select top 1 * from Cl_TemplateProject",JoinConn,1,3
nRs.AddNew
nRs("ProjectID") = nProjectID
nRs("ProjectName") = tProjectName
nRs("ProjectIntro") = Rs("ProjectIntro")
nRs("Deviser") = Rs("Deviser")
nRs("DeviserEmail") = Rs("DeviserEmail")
nRs("DeviserHomePage") = Rs("DeviserHomePage")
nRs.Update
nRs.Close
Rem End
Rem 导出Template
Set tRs=OutConn.Execute("select * from Cl_Template Where ProjectID="&tProjectID&" and Deleted="&FalseType&" order by ModuleID Asc,TypeID Asc")
Do while not tRs.eof
nRs.Open "select top 1 * from Cl_Template",JoinConn,1,3
nRs.AddNew
nRs("ModuleID") = tRs("ModuleID")
nRs("ChannelID") = 0
nRs("TemplateName") = tRs("TemplateName")
nRs("TemplateIntro")= tRs("TemplateIntro")
nRs("TemplateContent")= tRs("TemplateContent")
nRs("IsDefault") = tRs("IsDefault")
nRs("TypeID") = tRs("TypeID")
nRs("ProjectID") = nProjectID
nRs("ProjectName") = tProjectName
nRs.Update
nRs.Close
tRs.movenext
Loop
tRs.Close
Rem End
Rem 导出Css
Set cRs=OutConn.Execute("select * from Cl_Css Where ProjectID="&tProjectID)
Do while not cRs.eof
nRs.Open "select top 1 * from Cl_Css",JoinConn,1,3
nRs.AddNew
nRs("CssID") = nCssID
nRs("CssName") = cRs("CssName")
nRs("CssPicUrl") = cRs("CssPicUrl")
nRs("CssIntro") = cRs("CssIntro")
nRs("CssContent") = cRs("CssContent")
nRs("IsDefault") = cRs("IsDefault")
nRs("ProjectID") = nProjectID
nRs("ProjectName") = tProjectName
nRs.Update
nRs.Close
nCssID = nCssID + 1
cRs.movenext
Loop
cRs.Close
Rem End
nProjectID = nProjectID + 1
Rs.movenext
Loop
Rs.close : set Rs=Nothing
Set tRs = Nothing
Set cRs = Nothing
Set nRs = Nothing
Cl.SaveAdminLog
Call Cl.ShowSuc("<li>恭喜您，模板数据"&tName&"成功！")
End Sub
'<!--
'┌───────────────────────────────────────────────────────┐
'│ │
'│ CreateLive CMS Version 4.0 │
'│ Powered by Aspoo.CN │
'│ │
'│ 邮箱: support@aspoo.cn Info@aspoo.cn │
'│ ＱＱ: 3315263 596197794 │
'│ 网站: www.aspoo.cn www.aspoo.com │
'│ 论坛: bbs.aspoo.cn bbs.aspoo.com │
'│ │
'│ Copyright (C) 2005-2007 Aspoo.CN All Rights Reserved. │
'└───────────────────────────────────────────────────────┘
'-->
%>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -