show.asp

淘客网上商店网站程序 淘客网上商店网站程序 淘客网上商店网站程序

<!--#include file="Setting.asp"-->
<%
PageSize	= 5
Call Page_GuestShow()
If InStr(TempStr,"{$nopassnum}")>0 Then TempStr = Replace(TempStr,"{$nopassnum}",GetGuestNoPassNum)
Call Template.LoadCss()
TempStr = Template.CacheReplace(TempStr)
Response.write Template.ReplaceAllFlag(TempStr)

Public Sub Page_GuestShow()
	Dim GuestID,WhereStr,rsGuest,rsReply,SQLGuest,GuestButton,ReplyButton,TopicContent,TopicReplaceStr
	Dim regEx,sTemp,ContentStr,ReplaceStr,LoopStr
	Dim Matches,Match,TempValue,ArrayStr,DataStr
	Dim ReplyButtonPass,ReplyButtonNoPass,ReplyButtonDel
	GuestID = Cl.GetCLng(Request("GuestID"))
	SQLGuest = "select * from Cl_Guest where GuestID="&GuestID
	Set rsGuest = Cl.Execute(SQLGuest)
	if rsGuest.bof and rsGuest.eof Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestNoFind").text)
	End If
	If rsGuest("Status")=0 And Cl.UserGroupID<>1 Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestNoFind").text)
	End If
	Cl.Path		= Cl.Path & " &gt;&gt; 查看留言"
	Cl.Title	= rsGuest("GuestTitle")
	'Response.write SQLGuest
	TempStr		= Template.Read(TemplateShow)
	Rem 2008-2-16
	If InStr(TempStr,"{$guestmode}")>0 Then
		if Cl.ChkUserGroupID(Cl.Web_Setting(35),5) Then
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/Guest").text)
		Else
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/User").text)
		End if
	End If
	If InStr(TempStr,"{$appearmode}")>0 Then
		if Cl.Web_Setting(6)="Yes" Then
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Check").text)
		Else
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Show").text)
		End if
	End If
	Rem 2008-2-16 End
	GuestButton = Cl.Language.SelectSingleNode("//GuestButton/Info").text
	GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Email").text
	GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Reply").text
	GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Edit").text
	Rem ReplyButton
	ReplyButton = Cl.Language.SelectSingleNode("//GuestButton/Info").text
	ReplyButton = ReplyButton & Cl.Language.SelectSingleNode("//GuestButton/Email").text
	ReplyButton = ReplyButton & Cl.Language.SelectSingleNode("//GuestButton/EditReply").text
	If Cl.UserGroupID=1 Then
		If rsGuest("Status")=0 Then
		GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Pass").text
		else
		GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/NoPass").text
		End if
		GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/AdminReply").text
		GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Delete").text
		Rem ReplyButton
		ReplyButtonPass = Cl.Language.SelectSingleNode("//GuestButton/Pass").text
		ReplyButtonNoPass = Cl.Language.SelectSingleNode("//GuestButton/NoPass").text
		ReplyButtonDel = Cl.Language.SelectSingleNode("//GuestButton/Delete").text
		'ReplyButton = ReplyButton & Cl.Language.SelectSingleNode("//GuestButton/NoPass").text
		'ReplyButton = ReplyButton & Cl.Language.SelectSingleNode("//GuestButton/Delete").text
	End If
	'TempStr = Replace(TempStr,"{$replybutton}",ReplyButton)
	TempStr = Replace(TempStr,"{$guestbutton}",GuestButton)
	TempStr = Replace(TempStr,"{$guestid}",GuestID)
	TempStr = Replace(TempStr,"{$guesttitle}",rsGuest("guesttitle"))
	TempStr = Replace(TempStr,"{$webdir}",InstallDir)
	LoopStr = Template.GetPartContent(TempStr,"[Cl_Loop]","[/Cl_Loop]")
	ReplaceStr = "[Cl_Loop]" & LoopStr & "[/Cl_Loop]"
	Set regEx	= New RegExp
	regEx.IgnoreCase= True
	regEx.Global	= True
	WhereStr = " Where GuestID="&GuestID&" "
	If Cl.UserGroupID<>1 Then
		WhereStr = WhereStr & " and Status=1 "
	End if
	SQLGuest = "select * From Cl_GuestReply " & WhereStr & " Order by ReplyID Asc"
	set rsReply = server.createobject("adodb.recordset")
	OpenConn : rsReply.open SQLGuest,Conn,1,1
	if rsReply.bof and rsReply.eof then
		TotalPut = 1 : CurrentPage=1
		ContentStr = ""
		rsReply.close : Set rsReply=Nothing
	else
		Dim rsTotalPut,tPageSize
		Dim Node,XMLData,FloorNum
		tPageSize = PageSize
		Set rsTotalPut= Cl.Execute("Select count(ReplyID) from Cl_GuestReply " & WhereStr)
		TotalPut = rsTotalPut(0) + 1
		rsTotalPut.Close : Set rsTotalPut=Nothing
		if (TotalPut mod PageSize)=0 then
			TotalPages = TotalPut \ PageSize
		else
			TotalPages = TotalPut \ PageSize + 1
		end if
		if CurrentPage > TotalPages then CurrentPage=TotalPages
		if CurrentPage < 2 Then
			CurrentPage = 1
			tPageSize = PageSize -1
			FloorNum = 1
		Else
			FloorNum = (CurrentPage-1) * PageSize
			rsReply.move FloorNum - 1
		End If
		Set XMLData = Cl.ArrayToxml(rsReply.GetRows(tPageSize),rsReply,"guest","guestlist")
		'XMLData.Save(Server.MapPath("/guestlist.xml"))
		rsReply.close : Set rsReply=Nothing
		regEx.Pattern	= "{\$.[^{\$}]*}"
		For Each Node In XMLData.DocumentElement.SelectNodes("guest")
			sTemp = LoopStr : FloorNum = FloorNum + 1
			If Node.SelectSingleNode("@status").text="0" Then
				sTemp = Replace(sTemp,"{$replybutton}",ReplyButton & ReplyButtonPass & ReplyButtonDel)
			Else
				sTemp = Replace(sTemp,"{$replybutton}",ReplyButton & ReplyButtonNoPass & ReplyButtonDel)
			End if
			Set Matches		= regEx.Execute(sTemp)
			For Each Match in Matches
				ArrayStr	= Match.Value
				ArrayStr	= Replace(ArrayStr,"{$","")
				ArrayStr	= Replace(ArrayStr,"}","")
				ArrayStr	= Replace(ArrayStr,"(",",")
				ArrayStr	= Replace(ArrayStr,")","")
				ArrayStr	= Split(ArrayStr,",")
				ArrayStr(0) = LCase(ArrayStr(0))
				Select Case ArrayStr(0)
				Case "userface"
					DataStr = "<img src='" & InstallDir & "images/guestbook/" & Node.SelectSingleNode("@"&ArrayStr(0)).text & ".gif' width='"&ArrayStr(1)&"' height='"&ArrayStr(2)&"' />"
				Case "usergroupname"
					DataStr = Cl.GetUserGroupName(Node.SelectSingleNode("@usergroupid").text)
				Case "guestcontent","replycontent"
					DataStr = Cl.UbbCode(Node.SelectSingleNode("@"&ArrayStr(0)).text)
				Case "floornum"
					DataStr = FloorNum
				Case "csspicurl","webdir","installdir"
					DataStr = Match.Value
				Case Else
					DataStr = Node.SelectSingleNode("@"&ArrayStr(0)).text
				End Select
				sTemp = Replace(sTemp,Match.Value,DataStr)
				ArrayStr = Empty
			Next
			Set Matches		= Nothing
			ContentStr = ContentStr & sTemp
		Next
		Set XMLData = Nothing
	end If
	TempStr = Replace(TempStr,ReplaceStr,ContentStr)
	TempStr = Replace(TempStr,"{$showpage}",Cl.ShowPage("Show.asp?GuestID=" & GuestID,TotalPut,PageSize,GuestItemUnit,GuestItemName))

	Rem 主题处理
	'Response.write TopicContent
	'Response.end
	TopicContent = Template.GetPartContent(TempStr,"[Cl_Topic]","[/Cl_Topic]")
	TopicReplaceStr = "[Cl_Topic]" & TopicContent & "[/Cl_Topic]"
	If CurrentPage = 1 Then
		TopicContent = Replace(TopicContent,"{$replyid}",0)
		If rsGuest("IsReply")=1 Then
			TopicContent = Replace(TopicContent,"{$replycontent}",Cl.Language.SelectSingleNode("//ShowReply").text)
		Else
			TopicContent = Replace(TopicContent,"{$replycontent}","&nbsp;")
		End if
		regEx.Pattern	= "{\$.[^{\$}]*}"
		Set Matches		= regEx.Execute(TopicContent)
		For Each Match in Matches
			ArrayStr	= Match.Value
			ArrayStr	= Replace(ArrayStr,"{$","")
			ArrayStr	= Replace(ArrayStr,"}","")
			ArrayStr	= Replace(ArrayStr,"(",",")
			ArrayStr	= Replace(ArrayStr,")","")
			ArrayStr	= Split(ArrayStr,",")
			ArrayStr(0) = LCase(ArrayStr(0))
			Select Case ArrayStr(0)
			Case "userface"
				DataStr = "<img src='" & InstallDir & "images/guestbook/" & rsGuest("UserFace") & ".gif' width='"&ArrayStr(1)&"' height='"&ArrayStr(2)&"' />"
			Case "usergroupname"
				DataStr = Cl.GetUserGroupName(rsGuest("usergroupid"))
			Case "guestcontent"
				DataStr = Cl.UbbCode(rsGuest("guestcontent"))
			Case "replycontent"
				DataStr = Cl.UbbCode(rsGuest("replycontent"))
			Case Else
				'Response.write ArrayStr(0)
				DataStr =rsGuest(ArrayStr(0))
			End Select
			TopicContent = Replace(TopicContent,Match.Value,DataStr&"")
			ArrayStr = Empty
		Next
		Set Matches		= Nothing
	Else
		TopicContent = ""
	End If
	TempStr = Replace(TempStr,TopicReplaceStr,TopicContent)
	Rem End
	Set regEx	= Nothing
	rsGuest.Close : Set rsGuest = Nothing
	If Cl.UserID>0 Then
	TempStr = Replace(TempStr,"{$username}",Cl.MemberName)
	TempStr = Replace(TempStr,"{$useremail}",Cl.User_Info(7))
	TempStr = Replace(TempStr,"{$isdisabled}"," disabled")
	Else
	TempStr = Replace(TempStr,"{$username}",Cl.GetUserGroupName(Cl.UserGroupID))
	TempStr = Replace(TempStr,"{$useremail}",Cl.Web_Info(8))
	TempStr = Replace(TempStr,"{$isdisabled}","")
	End If
	TempStr = Replace(TempStr,"{$guestid}",GuestID)
	TempStr = Replace(TempStr,"{$isshowcode}",LCase(Cl.Web_Setting(41)))
End Sub
%>