📄 reply.asp

📁 淘客网上商店网站程序淘客网上商店网站程序淘客网上商店网站程序
💻 ASP
字号:
<!--#include file="Setting.asp"-->
<%
Dim GuestID,ReplyID
GuestID = Cl.GetCLng(Request("GuestID"))
ReplyID = Cl.GetCLng(Request("ReplyID"))
Cl.Path		= Cl.Path & " &gt;&gt; 回复留言"

Select Case LCase(Action)
Case "edit"
	Call Page_ReplyEdit()
Case "save"
	Call Page_ReplySave()
Case "replyadminsave"
	Call Page_ReplyAdminSave()
Case Else
	Call Page_ReplyWrite()
End Select

'TempStr=Template.Html
If InStr(TempStr,"{$nopassnum}")>0 Then TempStr = Replace(TempStr,"{$nopassnum}",GetGuestNoPassNum)
Call Template.LoadCss()
TempStr = Template.CacheReplace(TempStr)
Response.write Template.ReplaceAllFlag(TempStr)

Sub Page_ReplyWrite()
	If GuestID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
	set rsGuest = Cl.Execute("select * from Cl_Guest where GuestID=" & GuestID)
	If rsGuest.Eof Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
	End If
	If rsGuest("Status")=0 And Cl.UserGroupID<>1 Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestNoFind").text)
	End If
	if Not Cl.ChkUserGroupID(Cl.Web_Setting(35),Cl.UserGroupID) Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestNoPurview").text)
	end if
	TempStr = Template.Read(TemplateReply)
	Rem 2008-2-16
	If InStr(TempStr,"{$guestmode}")>0 Then
		if Cl.ChkUserGroupID(Cl.Web_Setting(35),5) Then
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/Guest").text)
		Else
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/User").text)
		End if
	End If
	If InStr(TempStr,"{$appearmode}")>0 Then
		if Cl.Web_Setting(6)="Yes" Then
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Check").text)
		Else
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Show").text)
		End if
	End If
	Rem 2008-2-16 End
	If Cl.UserID>0 Then
	TempStr = Replace(TempStr,"{$username}",Cl.MemberName)
	TempStr = Replace(TempStr,"{$useremail}",Cl.User_Info(7))
	TempStr = Replace(TempStr,"{$isdisabled}"," disabled")
	Else
	TempStr = Replace(TempStr,"{$username}",Cl.GetUserGroupName(Cl.UserGroupID))
	TempStr = Replace(TempStr,"{$useremail}",Cl.Web_Info(8))
	TempStr = Replace(TempStr,"{$isdisabled}","")
	End If
	TempStr = Replace(TempStr,"{$guestid}",GuestID)
	TempStr = Replace(TempStr,"{$replyid}",0)
	TempStr = Replace(TempStr,"{$guesttitle}","Re:"&rsGuest("GuestTitle"))

	TempStr = Replace(TempStr,"{$userface}","01")
	TempStr = Replace(TempStr,"{$guestemote}","1")
	TempStr = Replace(TempStr,"{$showubb}",ShowUbb)
	If Action="replyadmin" then
	TempStr = Replace(TempStr,"value=""Save""","value=""ReplyAdminSave""")
	TempStr = Replace(TempStr,"{$guestcontent}",rsGuest("ReplyContent") & "")
	Else
	TempStr = Replace(TempStr,"{$guestcontent}","")
	End If
	TempStr = Replace(TempStr,"{$action}",Action)
	TempStr = Replace(TempStr,"{$isshowcode}",LCase(Cl.Web_Setting(41)))
	rsGuest.Close : Set rsGuest = Nothing
End Sub

Sub Page_ReplyEdit()
	If Cl.UserID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//NoLoginErr").text)
	If ReplyID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
	set rsGuest = Cl.Execute("select * from Cl_GuestReply where ReplyID=" & ReplyID)
	If rsGuest.Eof Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
	End If
	If rsGuest("UserID")<>Cl.UserID And Cl.UserGroupID<>1 Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Edit").text)
	End if
	TempStr = Template.Read(TemplateReply)
	Rem 2008-2-16
	If InStr(TempStr,"{$guestmode}")>0 Then
		if Cl.ChkUserGroupID(Cl.Web_Setting(35),5) Then
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/Guest").text)
		Else
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/User").text)
		End if
	End If
	If InStr(TempStr,"{$appearmode}")>0 Then
		if Cl.Web_Setting(6)="Yes" Then
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Check").text)
		Else
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Show").text)
		End if
	End If
	Rem 2008-2-16 End
	TempStr = Replace(TempStr,"{$username}",rsGuest("UserName") & "")
	TempStr = Replace(TempStr,"{$useremail}",rsGuest("UserEmail") & "")
	If rsGuest("UserID")>0 then
	TempStr = Replace(TempStr,"{$isdisabled}"," disabled")
	Else
	TempStr = Replace(TempStr,"{$isdisabled}","")
	End If
	TempStr = Replace(TempStr,"{$guestid}",0)
	TempStr = Replace(TempStr,"{$replyid}",ReplyID)
	TempStr = Replace(TempStr,"{$guesttitle}",rsGuest("ReplyTitle") & "")
	TempStr = Replace(TempStr,"{$guestcontent}",rsGuest("ReplyContent") & "")
	TempStr = Replace(TempStr,"{$userface}",rsGuest("UserFace") & "")
	TempStr = Replace(TempStr,"{$guestemote}",rsGuest("ReplyEmote") & "")
	TempStr = Replace(TempStr,"{$showubb}",ShowUbb)
	TempStr = Replace(TempStr,"{$isshowcode}",LCase(Cl.Web_Setting(41)))
	rsGuest.Close : Set rsGuest = Nothing
End Sub

Sub Page_ReplySave()
	if Not Cl.ChkUserGroupID(Cl.Web_Setting(35),Cl.UserGroupID) then
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestNoPurview").text)
	end if
	if Cl.Web_Setting(41)="Yes" Then
		If Not Cl.CodeIsTrue(Trim(request("Guest_ChkCode")),"Guest_ChkCode") then
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Code").text)
		End if
	end if
	Dim UserName,UserEmail,UserFace,GuestEmote
	Dim GuestTitle,GuestContent,Hidden,Passed
	Dim Saveinfo

	UserFace	= Trim(request("UserFace"))
	GuestEmote	= Trim(request("GuestEmote"))
	GuestTitle	= Trim(request("GuestTitle"))
	GuestContent= Trim(request("GuestContent"))
	if GuestContent="" then
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Content").text)
	end if
	if Cl.UserID=0 then
		UserName	= Trim(request("UserName"))
		UserEmail	= Trim(request("UserEmail"))
		if UserName="" then
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Name").text)
		end if
	else
		UserName	= Cl.MemberName'Cl.MemberName
		UserEmail	= Cl.User_Info(7)
	end If
	Rem 默认值
	If UserFace="" Then UserFace="01"
	If GuestEmote="" Then GuestEmote="1"
	'Hidden	= Cl.GetClng(request("Hidden"))
	'if Cl.Web_Setting(6)="Yes" And Cl.UserGroupID<>1 then
	'	Passed = 0
	'else
		Passed = 1
	'end if
	GuestContent= Left(GuestContent,1000)
	GuestTitle	= Left(GuestTitle,100)
	if Cl.Web_Setting(5)="Yes" then  '脏话过滤
		GuestContent= Cl.ChkBadWords(GuestContent)
		GuestTitle	= Cl.ChkBadWords(GuestTitle)
	end if
	if ReplyID=0 then
		if IsDate(Session("GuestTime")) And Cl.UserGroupID<>1 Then
			If DateDiff("S",Session("GuestTime"),Now())<30 Then
				Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Time").text)
			End if
		End If
		If GuestID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
		set rsGuest = Cl.Execute("select GuestID,GuestTitle from Cl_Guest where GuestID=" & GuestID)
		If rsGuest.Eof Then
			rsGuest.Close : Set rsGuest = Nothing
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
		End If
		GuestTitle = "Re:" & rsGuest("GuestTitle")
		rsGuest.Close : Set rsGuest = Nothing
		set rsGuest=server.createobject("adodb.recordset")
		SQLGuest = "Select Top 1 * from Cl_GuestReply"
		OpenConn : rsGuest.open SQLGuest,Conn,1,3
		rsGuest.addnew
		rsGuest("GuestID")		= GuestID
		rsGuest("UserID")		= Cl.UserID
		rsGuest("UserName")		= UserName
		rsGuest("UserEmail")	= UserEmail
		rsGuest("UserGroupID")	= Cl.UserGroupID
		rsGuest("UserFace")		= UserFace
		rsGuest("UserIP")		= Cl.UserTrueIP
		rsGuest("ReplyEmote")	= GuestEmote
		rsGuest("ReplyTitle")	= GuestTitle
		rsGuest("ReplyContent")	= GuestContent
		rsGuest("ReplyTime")	= now()
		'rsGuest("Hidden")		= Hidden
		rsGuest("Status")		= Passed
		rsGuest.update
		rsGuest.Close : Set rsGuest = Nothing
		Session("GuestTime") = Now()
		Cl.Execute("update Cl_Guest Set ReplyCount=ReplyCount+1 Where GuestID="&GuestID&"")
		Saveinfo = Cl.Language.SelectSingleNode("//GuestSuc/Reply").text
	Else
		If Cl.UserID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//NoLoginErr").text)
		set rsGuest=server.createobject("adodb.recordset")
		SQLGuest = "select * from Cl_GuestReply where ReplyID=" & ReplyID
		OpenConn : rsGuest.open SQLGuest,Conn,1,3
		If rsGuest.Eof Then
			rsGuest.Close : Set rsGuest = Nothing
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
		End If
		If rsGuest("UserID")<>Cl.UserID And Cl.UserGroupID<>1 Then
			rsGuest.Close : Set rsGuest = Nothing
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Edit").text)
		End If
		'If rsGuest("UserID")=0 Then
		'rsGuest("UserName")		= UserName
		'rsGuest("UserEmail")	= UserEmail
		'End if
		If UserName=rsGuest("UserName") then
		rsGuest("UserGroupID")	= Cl.UserGroupID
		rsGuest("UserIP")		= Cl.UserTrueIP
		End if
		rsGuest("UserFace")		= UserFace
		rsGuest("ReplyEmote")	= GuestEmote
		'rsGuest("ReplyTitle")	= GuestTitle
		rsGuest("ReplyContent")	= GuestContent
		'rsGuest("Hidden")		= Hidden
		rsGuest("Status")		= Passed
		rsGuest.update
		GuestID = rsGuest("GuestID")
		rsGuest.Close : Set rsGuest = Nothing
		Saveinfo = Cl.Language.SelectSingleNode("//GuestSuc/Edit").text
	end If
	if Passed = 0 then
		Saveinfo = Saveinfo & Cl.Language.SelectSingleNode("//GuestSuc/NoPass").text
	end If
	Call Cl.OutMsg(0,Saveinfo,"Show.asp?GuestID=" & GuestID)
End Sub

'保存管理员回复留言
Sub Page_ReplyAdminSave()
	Dim GuestReply
	GuestReply = request("GuestContent")
	if GuestID=0 or Cl.UserGroupID<>1 then
		Call Cl.OutErr(0,"<li>未指定要回复的留言ID，或者你不是管理员！</li>")
		Exit Sub
	End If 
	set rsGuest=server.createobject("adodb.recordset")
	sql="select IsReply,ReplyContent,ReplyUser,ReplyTime from Cl_Guest where GuestId=" & GuestID
	OpenConn : rsGuest.open sql,Conn,3,3
	if rsGuest.bof and rsGuest.eof Then
		rsGuest.close : Set rsGuest=Nothing
		Call Cl.OutErr(0,"<br /><li>找不到您指定的留言！</li>")
		Exit Sub
	Else
		rsGuest("IsReply")		= 1
		rsGuest("ReplyContent")	= GuestReply
		rsGuest("ReplyUser")	= Cl.MemberName
		rsGuest("ReplyTime")	= now()
		rsGuest.update
	end if
	rsGuest.close : Set rsGuest=Nothing
	Call Cl.OutMsg(0,Cl.Language.SelectSingleNode("//GuestSuc/Reply").text,"Show.asp?GuestID=" & GuestID)
End Sub
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -