write.asp

淘客网上商店网站程序 淘客网上商店网站程序 淘客网上商店网站程序

<!--#include file="Setting.asp"-->
<%
Dim GuestID
GuestID = Cl.GetCLng(Request("GuestID"))
Cl.Path		= Cl.Path & " &gt;&gt; 签写留言"
Select Case LCase(Action)
Case "edit"
	Call Page_GuestEdit()
Case "save"
	Call Page_GuestSave()
Case Else
	Call Page_GuestWrite()
End Select

'TempStr=Template.Html
If InStr(TempStr,"{$nopassnum}")>0 Then TempStr = Replace(TempStr,"{$nopassnum}",GetGuestNoPassNum)
Call Template.LoadCss()
TempStr = Template.CacheReplace(TempStr)
Response.write Template.ReplaceAllFlag(TempStr)

Sub Page_GuestWrite()
	if Not Cl.ChkUserGroupID(Cl.Web_Setting(35),Cl.UserGroupID) then
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestNoPurview").text)
	end if
	TempStr = Template.Read(TemplateWrite)
	Rem 2008-2-16
	If InStr(TempStr,"{$guestmode}")>0 Then
		if Cl.ChkUserGroupID(Cl.Web_Setting(35),5) Then
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/Guest").text)
		Else
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/User").text)
		End if
	End If
	If InStr(TempStr,"{$appearmode}")>0 Then
		if Cl.Web_Setting(6)="Yes" Then
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Check").text)
		Else
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Show").text)
		End if
	End If
	Rem 2008-2-16 End
	If Cl.UserID>0 Then
	TempStr = Replace(TempStr,"{$username}",Cl.MemberName)
	TempStr = Replace(TempStr,"{$useremail}",Cl.User_Info(7))
	TempStr = Replace(TempStr,"{$isdisabled}"," disabled")
	Else
	TempStr = Replace(TempStr,"{$username}",Cl.GetUserGroupName(Cl.UserGroupID))
	TempStr = Replace(TempStr,"{$useremail}",Cl.Web_Info(8))
	TempStr = Replace(TempStr,"{$isdisabled}","")
	End If
	TempStr = Replace(TempStr,"{$guestid}",0)
	TempStr = Replace(TempStr,"{$guesttitle}","")
	TempStr = Replace(TempStr,"{$guestcontent}","")
	TempStr = Replace(TempStr,"{$userface}","01")
	TempStr = Replace(TempStr,"{$guestemote}","1")
	TempStr = Replace(TempStr,"{$showubb}",ShowUbb)
	TempStr = Replace(TempStr,"{$isshowcode}",LCase(Cl.Web_Setting(41)))
End Sub

Sub Page_GuestEdit()
	If Cl.UserID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//NoLoginErr").text)
	If GuestID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
	set rsGuest = Cl.Execute("select * from Cl_Guest where GuestID=" & GuestID)
	If rsGuest.Eof Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
	End If
	If rsGuest("UserID")<>Cl.UserID And Cl.UserGroupID<>1 Then
		rsGuest.Close : Set rsGuest = Nothing
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Edit").text)
	End If
'	Call Template.LoadCss()
	TempStr = Template.Read(TemplateWrite)
	Rem 2008-2-16
	If InStr(TempStr,"{$guestmode}")>0 Then
		if Cl.ChkUserGroupID(Cl.Web_Setting(35),5) Then
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/Guest").text)
		Else
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/User").text)
		End if
	End If
	If InStr(TempStr,"{$appearmode}")>0 Then
		if Cl.Web_Setting(6)="Yes" Then
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Check").text)
		Else
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Show").text)
		End if
	End If
	Rem 2008-2-16 End
	TempStr = Replace(TempStr,"{$username}",rsGuest("UserName") & "")
	TempStr = Replace(TempStr,"{$useremail}",rsGuest("UserEmail") & "")
	If rsGuest("UserID")>0 then
	TempStr = Replace(TempStr,"{$isdisabled}"," disabled")
	Else
	TempStr = Replace(TempStr,"{$isdisabled}","")
	End If
	TempStr = Replace(TempStr,"{$guestid}",GuestID)
	TempStr = Replace(TempStr,"{$guesttitle}",rsGuest("GuestTitle") & "")
	TempStr = Replace(TempStr,"{$guestcontent}",rsGuest("GuestContent") & "")
	TempStr = Replace(TempStr,"{$userface}",rsGuest("UserFace") & "")
	TempStr = Replace(TempStr,"{$guestemote}",rsGuest("GuestEmote") & "")
	TempStr = Replace(TempStr,"{$showubb}",ShowUbb)
	TempStr = Replace(TempStr,"{$isshowcode}",LCase(Cl.Web_Setting(41)))
	rsGuest.Close : Set rsGuest = Nothing
End Sub

Sub Page_GuestSave()
	if Not Cl.ChkUserGroupID(Cl.Web_Setting(35),Cl.UserGroupID) then
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestNoPurview").text)
	end if
	if Cl.Web_Setting(41)="Yes" Then
		If Not Cl.CodeIsTrue(Trim(request("Guest_ChkCode")),"Guest_ChkCode") then
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Code").text)
		End if
	end if
	Dim UserName,UserEmail,UserFace,GuestEmote
	Dim GuestTitle,GuestContent,Hidden,Passed
	Dim Saveinfo

	UserFace	= Trim(request("UserFace"))
	GuestEmote	= Trim(request("GuestEmote"))
	GuestTitle	= Trim(request("GuestTitle"))
	GuestContent= Trim(request("GuestContent"))
	if GuestTitle="" or GuestContent="" then
		Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Content").text)
	end if
	if Cl.UserID=0 then
		UserName	= Trim(request("UserName"))
		UserEmail	= Trim(request("UserEmail"))
		if UserName="" then
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Name").text)
		end if
	else
		UserName	= Cl.MemberName'Cl.MemberName
		UserEmail	= Cl.User_Info(7)
	end If
	Rem 默认值
	If UserFace="" Then UserFace="01"
	If GuestEmote="" Then GuestEmote="1"
	'Hidden	= Cl.GetClng(request("Hidden"))
	if Cl.Web_Setting(6)="Yes" And Cl.UserGroupID<>1 then
		Passed = 0
	else
		Passed = 1
	end if
	GuestContent= Left(GuestContent,1000)
	GuestTitle	= Left(GuestTitle,100)
	if Cl.Web_Setting(5)="Yes" then  '脏话过滤
		GuestContent= Cl.ChkBadWords(GuestContent)
		GuestTitle	= Cl.ChkBadWords(GuestTitle)
	end if
	if GuestID=0 then
		if IsDate(Session("GuestTime")) And Cl.UserGroupID<>1 Then
			If DateDiff("S",Session("GuestTime"),Now())<30 Then
				Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Time").text)
			End if
		End if
		set rsGuest=server.createobject("adodb.recordset")
		SQLGuest = "Select Top 1 * from Cl_Guest"
		OpenConn : rsGuest.open SQLGuest,Conn,1,3
		rsGuest.addnew
		rsGuest("UserID")		= Cl.UserID
		rsGuest("UserName")		= UserName
		rsGuest("UserEmail")	= UserEmail
		rsGuest("UserGroupID")	= Cl.UserGroupID
		rsGuest("UserFace")		= UserFace
		rsGuest("UserIP")		= Cl.UserTrueIP
		rsGuest("GuestEmote")	= GuestEmote
		rsGuest("GuestTitle")	= GuestTitle
		rsGuest("GuestContent")	= GuestContent
		rsGuest("GuestTime")	= now()
		'rsGuest("Hidden")		= Hidden
		rsGuest("Status")		= Passed
		rsGuest.update
		rsGuest.Close : Set rsGuest = Nothing
		Session("GuestTime") = Now()
		Saveinfo = Cl.Language.SelectSingleNode("//GuestSuc/Add").text
	Else
		If Cl.UserID=0 Then Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//NoLoginErr").text)
		set rsGuest=server.createobject("adodb.recordset")
		SQLGuest = "select * from Cl_Guest where GuestID=" & GuestID
		OpenConn : rsGuest.open SQLGuest,Conn,1,3
		If rsGuest.Eof Then
			rsGuest.Close : Set rsGuest = Nothing
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/NoFind").text)
		End If
		If rsGuest("UserID")<>Cl.UserID And Cl.UserGroupID<>1 Then
			rsGuest.Close : Set rsGuest = Nothing
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//GuestErr/Edit").text)
		End If
		'If rsGuest("UserID")=0 Then
		'rsGuest("UserName")		= UserName
		'rsGuest("UserEmail")	= UserEmail
		'End if
		If UserName=rsGuest("UserName") then
		rsGuest("UserGroupID")	= Cl.UserGroupID
		rsGuest("UserIP")		= Cl.UserTrueIP
		End if
		rsGuest("UserFace")		= UserFace
		rsGuest("GuestEmote")	= GuestEmote
		rsGuest("GuestTitle")	= GuestTitle
		rsGuest("GuestContent")	= GuestContent
		'rsGuest("Hidden")		= Hidden
		rsGuest("Status")		= Passed
		rsGuest.update
		rsGuest.Close : Set rsGuest = Nothing
		Saveinfo = Cl.Language.SelectSingleNode("//GuestSuc/Edit").text
	end If
	if Passed = 0 then
		Saveinfo = Saveinfo & Cl.Language.SelectSingleNode("//GuestSuc/NoPass").text
	end If
	Call Cl.OutMsg(0,Saveinfo,"Index.asp")
End Sub
%>