index.asp

淘客网上商店网站程序 淘客网上商店网站程序 淘客网上商店网站程序

<!--#include file="Setting.asp"-->
<%
Cl.Path		= Cl.Path & " &gt;&gt; " & PageTitle
PageSize	= 5
Call Page_GuestIndex()
If InStr(TempStr,"{$nopassnum}")>0 Then TempStr = Replace(TempStr,"{$nopassnum}",GetGuestNoPassNum)
Call Template.LoadCss()
TempStr = Template.CacheReplace(TempStr)
Response.write Template.ReplaceAllFlag(TempStr)

Public Sub Page_GuestIndex()
	Dim WhereStr,rsGuest,SQLGuest
	Dim regEx,sTemp,ContentStr,ReplaceStr,LoopStr
	Dim Matches,Match,TempValue,ArrayStr,DataStr
	Set regEx	= New RegExp
	regEx.IgnoreCase= True
	regEx.Global	= True
	Select Case Action
	Case "myguest"
		if Cl.UserID=0 Then
			Call Cl.OutErr(0,Cl.Language.SelectSingleNode("//NoLoginErr").text)
		end if
		WhereStr = " Where UserName='"&Cl.MemberName&"'"
	Case "nopass"
		WhereStr = " Where Status=0"
	Case Else
		WhereStr = " Where Status=1"
	end Select
	if keyword<>"" Then
		keyword = Cl.ReplaceBadChar(keyword)
		WhereStr = WhereStr & " and (GuestTitle like '%" & keyword & "%' or GuestContent like '%" & keyword & "%' or UserName like '%" & keyword & "%' or ReplyContent like '%" & keyword & "%') "
	end if
	SQLGuest = "select * from Cl_Guest "
	SQLGuest = SQLGuest & WhereStr & " order by GuestID desc"
	'Response.write SQLGuest
	TempStr		= Template.Read(TemplateIndex)
	Rem 2008-2-16
	If InStr(TempStr,"{$guestmode}")>0 Then
		if Cl.ChkUserGroupID(Cl.Web_Setting(35),5) Then
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/Guest").text)
		Else
		TempStr = Replace(TempStr,"{$guestmode}",Cl.Language.SelectSingleNode("//GuestMode/User").text)
		End if
	End If
	If InStr(TempStr,"{$appearmode}")>0 Then
		if Cl.Web_Setting(6)="Yes" Then
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Check").text)
		Else
		TempStr = Replace(TempStr,"{$appearmode}",Cl.Language.SelectSingleNode("//AppearMode/Show").text)
		End if
	End If
	Rem 2008-2-16 End
	LoopStr		= Template.GetPartContent(TempStr,"[Cl_Loop]","[/Cl_Loop]")
	ReplaceStr	= "[Cl_Loop]" & LoopStr & "[/Cl_Loop]"
	If LoopStr = "" Then
		TempStr = Replace(TempStr,"{$showpage}","")
		Exit Sub
	End if
	set rsGuest = server.createobject("adodb.recordset")
	OpenConn : rsGuest.open SQLGuest,Conn,1,1
	if rsGuest.bof and rsGuest.eof then
		TotalPut=0
		ContentStr = Cl.Language.SelectSingleNode("//GuestNoFind").text
		rsGuest.close : Set rsGuest=Nothing
	else
		Dim rsTotalPut
		Set rsTotalPut= Cl.Execute("Select count(GuestId) from Cl_Guest " & WhereStr)
		TotalPut = rsTotalPut(0)
		rsTotalPut.Close : Set rsTotalPut=Nothing
		if (TotalPut mod PageSize)=0 then
			TotalPages = TotalPut \ PageSize
		else
			TotalPages = TotalPut \ PageSize + 1
		end if
		if CurrentPage > TotalPages then CurrentPage=TotalPages
		if CurrentPage < 2 Then
			CurrentPage=1
		else
			rsGuest.move (CurrentPage-1)*PageSize
		End If
		Dim Node,XMLData,GuestButton
		Set XMLData = Cl.ArrayToxml(rsGuest.GetRows(PageSize),rsGuest,"guest","guestlist")
		'XMLData.Save(Server.MapPath("/guestlist.xml"))
		rsGuest.close:Set rsGuest=Nothing
		regEx.Pattern	= "{\$.[^{\$}]*}"
		If Action="myguest" then
			GuestButton = ""
		Else
			GuestButton = Cl.Language.SelectSingleNode("//GuestButton/Info").text
			GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Email").text
			GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Reply").text
			GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Edit").text
			If Cl.UserGroupID=1 Then
				If Action="nopass" then
				GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Pass").text
				else
				GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/NoPass").text
				End if
				GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/AdminReply").text
				GuestButton = GuestButton & Cl.Language.SelectSingleNode("//GuestButton/Delete").text
			End If
		End if
		LoopStr = Replace(LoopStr,"{$guestbutton}",GuestButton)
		LoopStr = Replace(LoopStr,"{$replyid}",0)
		LoopStr = Replace(LoopStr,"{$webdir}",InstallDir)
		For Each Node In XMLData.DocumentElement.SelectNodes("guest")
			sTemp = LoopStr
			If Clng(Node.SelectSingleNode("@isreply").text)=1 Then
				sTemp = Replace(sTemp,"{$replycontent}",Cl.Language.SelectSingleNode("//ShowReply").text)
			Else
				sTemp = Replace(sTemp,"{$replycontent}","&nbsp;")
			End if
			Set Matches		= regEx.Execute(sTemp)
			For Each Match in Matches
				ArrayStr	= Match.Value
				ArrayStr	= Replace(ArrayStr,"{$","")
				ArrayStr	= Replace(ArrayStr,"}","")
				ArrayStr	= Replace(ArrayStr,"(",",")
				ArrayStr	= Replace(ArrayStr,")","")
				ArrayStr	= Split(ArrayStr,",")
				ArrayStr(0) = LCase(ArrayStr(0))
				Select Case ArrayStr(0)
				Case "userface"
					DataStr = "<img src='" & InstallDir & "images/guestbook/" & Node.SelectSingleNode("@"&ArrayStr(0)).text & ".gif' width='"&ArrayStr(1)&"' height='"&ArrayStr(2)&"' />"
				Case "usergroupname"
					DataStr = Cl.GetUserGroupName(Node.SelectSingleNode("@usergroupid").text)
				Case "guestcontent","replycontent"
					DataStr = Cl.UbbCode(Node.SelectSingleNode("@"&ArrayStr(0)).text)
					'If Node.SelectSingleNode("@hidden").text="True" Then
					'	DataStr = Cl.Language.SelectSingleNode("//ShowHidden").text & DataStr
					'End if
				Case "csspicurl","webdir","installdir"
					DataStr = Match.Value
				Case Else
					'Response.write ArrayStr(0)
					DataStr = Node.SelectSingleNode("@"&ArrayStr(0)).text
				End Select
				sTemp = Replace(sTemp,Match.Value,DataStr & "")
				ArrayStr = Empty
			Next
			Set Matches		= Nothing
			ContentStr = ContentStr & sTemp
		Next
		Set XMLData = Nothing
	end if
	TempStr = Replace(TempStr,ReplaceStr,ContentStr)
	Dim PageFileName
	PageFileName = "Index.asp?Action=" & Action
	if keyword<>"" Then PageFileName = PageFileName & "&keyword=" & keyword
	TempStr = Replace(TempStr,"{$showpage}",Cl.ShowPage(PageFileName,TotalPut,PageSize,GuestItemUnit,GuestItemName))
	Set regEx	= Nothing

End Sub
%>