del.asp

淘客网上商店网站程序 淘客网上商店网站程序 淘客网上商店网站程序

<!--#include file="Setting.asp"-->
<!--#include file="../Inc/Cl_Md5.asp"-->
<%
Dim Action
Action = LCase(Trim(Request("Action")))
Select Case Action
Case "postdel"
	Del_Post
Case Else
	Del_Main
End Select
Response.write Template.ReplaceAllFlag(TempStr)
CloseAllObj

Sub Del_Main()
	Dim Rs,SQL
	Dim ID,ClassID,LinkType,SiteName,SiteUrl,LogoUrl,SiteAdmin,Email,SiteIntro
	ID = Cl.GetClng(Request("ID"))
	If ID<1 Then Call Cl.OutErr(0,"<br /><li>找不到指定的站点！</li>")
	Set Rs=Cl.Execute("select * from Cl_LinkSite where ID=" & ID)
	if Rs.bof and Rs.eof then
		Rs.close : set Rs=Nothing
		Call Cl.OutErr(0,"<br /><li>找不到指定的站点！</li>")
	end If
	LinkType	= Rs("LinkType")
	ClassID		= Rs("ClassID")
	SiteName	= Rs("SiteName")
	SiteUrl		= Rs("SiteUrl")
	LogoUrl		= Rs("LogoUrl")
	SiteAdmin	= Rs("SiteAdmin")
	Email		= Rs("Email")
	SiteIntro	= Rs("SiteIntro")
	Rs.close : set Rs=Nothing
	TempStr = Template.Read(TemplateDel)
	TempStr = Replace(TempStr,"{$LinkType}",LinkType)
	TempStr = Replace(TempStr,"{$SiteName}",SiteName)
	TempStr = Replace(TempStr,"{$SiteUrl}",SiteUrl)
	TempStr = Replace(TempStr,"{$LogoUrl}",LogoUrl)
	TempStr = Replace(TempStr,"{$SiteAdmin}",SiteAdmin)
	TempStr = Replace(TempStr,"{$Email}",Email)
	TempStr = Replace(TempStr,"{$SiteIntro}",SiteIntro)
	TempStr = Replace(TempStr,"{$ID}",ID)
End Sub


Sub Del_Post()
	Dim SQL,Rs,ID
	Dim OldSitePassword,LinkRegCode
	ID = Cl.GetClng(Request("ID"))
	OldSitePassword = Trim(Request("OldSitePassword"))
	LinkRegCode		= Trim(request("LinkRegCode"))
	If ID<1 Then Call Cl.OutErr(0,"<br /><li>找不到指定的站点！</li>")
	If OldSitePassword="" Then
		Call Cl.OutErr(0,"<br /><li>请输入网站密码！</li>")
	End If
	if Not Cl.CodeIsTrue(LinkRegCode,"LinkRegCode") then
		Call Cl.OutMsg(0,"<br /><li>验证码检验失败！</li>","-1")
	end If
	SQL = "select * from Cl_LinkSite where ID=" & ID
	set Rs=Server.CreateObject("Adodb.RecordSet")
	OpenConn : Rs.open SQL,Conn,1,3
	if Rs.bof and Rs.eof then
		Rs.close:set Rs=Nothing
		Call Cl.OutErr(0,"<br /><li>找不到站点！</li>")
	else
		if md5(OldSitePassword,16)<>Rs("SitePassword") then
			Rs.close:set Rs=Nothing
			Call Cl.OutErr(0,"<br /><li>你输入的旧网站密码不对，没有权限删除！</li>")
		end if
		Rs.delete
		Rs.update
	end If
	Rs.close:set Rs=Nothing
	Call Cl.OutMsg(0,"恭喜您，删除链接成功！","Index.asp")
End Sub
%>
<%
'==================================================
'CreateLive CMS Version 4.0
'							Powered by Aspoo.Net
'
'邮箱: [e-mail]		[e-mail]
'ＱＱ: 3315263				596197794
'网站: www.aspoo.cn			www.aspoo.com
'论坛: bbs.aspoo.cn			bbs.aspoo.com
'
'Copyright (C) 2005-2007 Aspoo.Net All Rights Reserved.
'==================================================
%>