index.asp

淘客网上商店网站程序 淘客网上商店网站程序 淘客网上商店网站程序

<!--#include file="Setting.asp"-->
<%
Dim PageBeginTime,PageEndTime
Dim PageSize,TotalPut,CurrentPage,TotalPages
Dim ClassID,TypeID,FileName
Dim regEx,sTemp,ContentStr,ReplaceStr,LoopStr
Dim Matches,Match,TempValue,ArrayStr,DataStr
Dim XMLData,Node
PageBeginTime = Timer
ClassID	= Cl.GetClng(Request("ClassID"))
TypeID	= Cl.GetClng(Request("TypeID"))
CurrentPage = Cl.GetClng(Request("Page"))
PageSize= 20
TotalPut= 0
TotalPages= 0
FileName= "Index.asp?ClassID=" & ClassID & "&TypeID=" & TypeID
Call ShowLinkSite()
Response.write Template.ReplaceAllFlag(TempStr)

Sub ShowLinkSite()

	Cl.Path=Cl.Language.selectSingleNode("//CurrentPath").text & "<a href='" & Cl.Web_info(4) & "'>" & Cl.Web_info(0) & "</a> &gt;&gt; " & Cl.Language.selectSingleNode("//LinkSite/Title").text
	Cl.Title=Cl.Language.selectSingleNode("//LinkSite/Title").text & " " & Cl.Title 
	Call Template.Load(0,3)
	TempStr = Template.Html'Template.Read(TemplateIndex)
	TempStr = Cl.ReplaceDir(TempStr)
	LoopStr	= Template.GetPartContent(TempStr,"[Cl_Loop]","[/Cl_Loop]")
	ReplaceStr = "[Cl_Loop]" & LoopStr & "[/Cl_Loop]"

	dim SQL,Rs',i,strHTML,strTemp,sLogoUrl
	SQL = "select ID,ClassID,LinkType,SiteName,SiteUrl,SiteIntro,LogoUrl,SiteAdmin,Email,Hits from Cl_LinkSite where IsOK=True "
	if TypeID > 0 then SQL = SQL & " and LinkType="&TypeID&" "
	if ClassID>0 then
		Dim tClass
		set tClass=Cl.Execute("select ClassID,Child,arrChildID from Cl_LinkClass where ClassID=" & ClassID)
		if not(tClass.bof and tClass.eof) then
			if tClass(1)>0 then
				SQL = SQL & " and ClassID in (" & tClass(2) & ")"
			else
				SQL = SQL & " and ClassID=" & ClassID
			end if
		else
			SQL = SQL & " and ClassID=" & ClassID
		end if
		set tClass=Nothing
	end if
	SQL = SQL & " Order by OrderID,ID Asc"
	set Rs = Server.CreateObject("ADODB.Recordset")
	OpenConn : Rs.open SQL,Conn,1,1
	if Rs.eof and Rs.bof then
		Rs.close:set Rs=Nothing
		TempStr = Replace(TempStr,"{$showpage}","")
		TempStr = Replace(TempStr,ReplaceStr,"")
		Exit Sub
	End if
	TotalPut = Rs.recordcount
	if (TotalPut mod PageSize)=0 then
		TotalPages = TotalPut \ PageSize
	else
		TotalPages = TotalPut \ PageSize + 1
	end if
	if CurrentPage > TotalPages then CurrentPage=TotalPages
	if CurrentPage < 2 Then
		CurrentPage=1
	else
		Rs.move (CurrentPage-1)*PageSize
	End if
	Set XMLData = Cl.ArrayToXml(Rs.GetRows(PageSize),Rs,"link","linklist")
	Rs.close:set Rs=Nothing
	Set regEx	= New RegExp
	regEx.IgnoreCase= True
	regEx.Global	= True
	regEx.Pattern	= "{\$.[^{\$}]*}"
	For Each Node In XMLData.DocumentElement.SelectNodes("link")
		sTemp = LoopStr
		Set Matches		= regEx.Execute(sTemp)
		For Each Match in Matches
			ArrayStr	= Match.Value
			ArrayStr	= Replace(ArrayStr,"{$","")
			ArrayStr	= Replace(ArrayStr,"}","")
			ArrayStr	= Replace(ArrayStr,"(",",")
			ArrayStr	= Replace(ArrayStr,")","")
			ArrayStr	= Split(ArrayStr,",")
			ArrayStr(0) = LCase(ArrayStr(0))
			Select Case ArrayStr(0)
			Case "logourl"
				if CLng(Node.SelectSingleNode("@linktype").text)=1 then
				DataStr = Cl.ReplaceDir(Node.SelectSingleNode("@logourl").text)
				Else
				DataStr = InstallDir & "Images/NoLogo.gif"
				End if
			Case "showlogo"
				if CLng(Node.SelectSingleNode("@linktype").text)=1 then
					Dim sLogoUrl
					sLogoUrl=Cl.ReplaceDir(Node.SelectSingleNode("@logourl").text)
					if lcase(right(sLogoUrl,3))="swf" then
						DataStr = "<object classid='clsid:D27CDB6E-AE6D-11cf-96B8-444553540000' codebase='http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=5,0,0,0' width='"&ArrayStr(1)&"' height='"&ArrayStr(2)&"'><param name='movie' value='" & sLogoUrl & "'><param name='quality' value='high'><embed src='" & sLogoUrl & "' pluginspage='http://www.macromedia.com/shockwave/download/index.cgi?P1_Prod_Version=ShockwaveFlash' type='application/x-shockwave-flash' width='"&ArrayStr(1)&"' height='"&ArrayStr(2)&"'></embed></object>"
					else
						DataStr = "<img src='" & sLogoUrl & "' width='"&ArrayStr(1)&"' height='"&ArrayStr(2)&"' border='0' alt='' />"
					end If
				Else
					DataStr = "<img src='" & InstallDir & "Images/NoLogo.gif' width='"&ArrayStr(1)&"' height='"&ArrayStr(2)&"' border='0' alt='' />"'InstallDir & "Images/NoLogo.gif"
				End if
			Case "linktype"
				if CLng(Node.SelectSingleNode("@linktype").text)=1 then
					DataStr = Cl.Language.selectSingleNode("//LinkSite/LogoLink").text
				else
					DataStr = Cl.Language.selectSingleNode("//LinkSite/TextLink").text
				end If
			Case "typeid"
				DataStr = Node.SelectSingleNode("@linktype").text
			Case Else
				DataStr = Node.SelectSingleNode("@"&ArrayStr(0)).text
			End Select
			sTemp = Replace(sTemp,Match.Value,DataStr)
			ArrayStr = Empty
		Next
		Set Matches		= Nothing
		ContentStr = ContentStr & sTemp
	Next
	TempStr = Replace(TempStr,"{$showpage}",Cl.ShowPage(FileName,TotalPut,PageSize,"个","站点"))
	TempStr = Replace(TempStr,ReplaceStr,ContentStr)
	Set Node = Nothing
	Set regEx = Nothing
	Set XMLData = Nothing
End Sub 
%>
<%
'==================================================
'CreateLive CMS Version 4.0
'                           Powered by Aspoo.Net
'
'邮箱: [e-mail]     [e-mail]
'ＱＱ: 3315263, 596197794, 6450835, 123996661
'网站: www.aspoo.cn         www.aspoo.com
'论坛: bbs.aspoo.cn         bbs.aspoo.com
'
'Copyright (C) 2005-2007 Aspoo.Net All Rights Reserved.
'==================================================
%>