user_consumelog.asp

淘客网上商店网站程序 淘客网上商店网站程序 淘客网上商店网站程序

<!--#include file="Inc/Const.asp"-->
<%
const PageSize=20
dim Action,ID,SearchType,Field,Keyword
Action		= Trim(request("Action"))
ID			= Trim(request("ID"))
CurrentPage	= Cl.GetClng(request("page"))
SearchType	= Cl.GetClng(request("SearchType"))
Field		= Trim(request("Field"))
Keyword		= Trim(request("Keyword"))
FileName = "User_ConsumeLog.asp?SearchType="&SearchType&"&Field="&Field&"&Keyword="&Keyword&""
Header
%>
<script language="JavaScript" type="text/javascript">
function unselectall(){
	if(document.myform.chkAll.checked){
	document.myform.chkAll.checked = document.myform.chkAll.checked;
	}
}
function CheckAll(form){
	for (var i=0;i<form.elements.length;i++){
		var e = form.elements[i];
		if (e.name != 'chkAll'&&e.disabled==false)
		e.checked = form.chkAll.checked;
	}
}
function ConfirmDel(){
	if(document.myform.Action.value=='Del'){
		if(confirm('确定要删除选中的记录吗？'))
			return true;
		else
			return false;
	}
}
</script>
<table width="100%" border="0" align="center" cellpadding="2" cellspacing="1" Class="border">  
	<tr class="title"><td height="22" colspan="2" align="center"><b>消 费 记 录 管 理</b></td></tr>    
	<tr class="tdbg" height="30">
		<form name="form1" action="User_ConsumeLog.asp" method="get">
		<td>快速查询：
			<select size=1 name="SearchType" onChange="javascript:submit()">  
			<option value="0" selected>所有记录</option>
			<option value="1">今 天 的记录</option>
			<option value="2">本 周 的记录</option>
			<option value="3">本 月 的记录</option>
			<option value="4">三个月内的记录</option>
			</select>&nbsp;&nbsp;&nbsp;&nbsp;<a href="User_ConsumeLog.asp">记录管理首页</a></td>
		</form>
		<form name="form2" method="post" action="User_ConsumeLog.asp">
		<td><b>高级查询：</b>
			<select name="ChannelID" id="ChannelID">
			<option value="0" selected>所有频道</option>
			<%
			Dim Node
			For Each Node In Application(Cl.CacheName & "_channellist").DocumentElement.selectNodes("channel[@moduleid!=0][@moduleid!=6]")
			Response.write "<option value=""" & Node.selectSingleNode("@channelid").text& """>" & Node.selectSingleNode("@channelname").text& "</option>"
			Next
			Set Node = Nothing%>
			</select>
			<select name="Field" id="Field">
			<option value="InfoID">内容ID</option>
			<option value="ConsumePoint" selected>消费点数</option>
			<option value="ConsumeMoney">消费金钱</option>
			</select>
			<input name="Keyword" type="text" id="Keyword" size="20" maxlength="30">
			<input type="submit" name="Submit2" value=" 查 询 ">
			<input name="SearchType" type="hidden" id="SearchType" value="5">
		</td>
		</form>
	</tr>
</table>
<script language="JavaScript" type="text/javascript">
CheckSel('ChannelID','<%=ChannelID%>');
CheckSel('SearchType','<%=SearchType%>');
CheckSel('Field','<%=Field%>');
</script>
<br />
<%
Select Case Action
Case "DelLog"
   call DelLog()
Case else
   call LogMain()
end Select

Footer

Sub LogMain()
	Dim WhereStr
	if ChannelID>0 then
		WhereStr = " Where ChannelID="&ChannelID&" "
	else
		WhereStr = " Where ChannelID>-1 "
	end if
	WhereStr=WhereStr & " and UserID="&Cl.UserID&" "
	Select Case SearchType
	Case 1
		If IsSqlDataBase_L=1 Then
			WhereStr=WhereStr & " and datediff(d,ConsumeTime,GetDate())<1 "
		else
			WhereStr=WhereStr & " and datediff('d',ConsumeTime,Now())<1 "
		end if
	Case 2
		If IsSqlDataBase_L=1 Then
			WhereStr=WhereStr & " and datediff(week,ConsumeTime,GetDate())<1 "
		else
			WhereStr=WhereStr & " and datediff('w',ConsumeTime,Now())<1 "
		end if
	Case 3
		If IsSqlDataBase_L=1 Then
			WhereStr=WhereStr & " and datediff(month,ConsumeTime,GetDate())<1 "
		else
			WhereStr=WhereStr & " and datediff('m',ConsumeTime,Now())<1 "
		end if
	Case 4
		If IsSqlDataBase_L=1 Then
			WhereStr=WhereStr & " and datediff(month,ConsumeTime,GetDate())<3 "
		else
			WhereStr=WhereStr & " and datediff('m',ConsumeTime,Now())<3 "
		end if
	Case 5
		WhereStr=WhereStr & " and "
		Select Case Field
		Case "InfoID"
			WhereStr=WhereStr & "InfoID="&Cl.GetClng(Keyword)&" "
		Case "UserID"
			WhereStr=WhereStr & "UserID="&Cl.GetClng(Keyword)&" "
		Case "UserName"
			WhereStr=WhereStr & "UserName='"&Cl.CheckStr(Keyword)&"' "
		Case "ConsumePoint"
			WhereStr=WhereStr & "ConsumePoint>="&Cl.GetClng(Keyword)&" "
		Case "ConsumeMoney"
			WhereStr=WhereStr & "ConsumeMoney>="&Cl.GetClng(Keyword)&" "
		Case Else
			WhereStr=WhereStr & "UserName='"&Cl.CheckStr(Keyword)&"' "
		End Select
	End Select
	SQL="Select ID,ChannelID,InfoID,Title,Url,UserID,UserName,ConsumePoint,ConsumeMoney,ConsumeNums,ConsumeLog,ConsumeTime,ConsumeType from Cl_ConsumeLog " & WhereStr& " Order by ID Desc"
	Set rs= Server.CreateObject("ADODB.Recordset")
	OpenConn_L : rs.open sql,Conn_L,1,1
	if rs.eof and rs.bof then
		TotalPut=0
		response.write "<p align=center><br />找不到记录！<br /></p>"
		rs.close:set rs=Nothing:Exit Sub
	End if
	Dim rsTotalPut
	Set rsTotalPut= Cl.Execute_L("Select count(ID) from Cl_ConsumeLog " & WhereStr)
	TotalPut = rsTotalPut(0)
	rsTotalPut.Close : Set rsTotalPut=Nothing
	if (TotalPut mod PageSize)=0 then
		TotalPages = TotalPut \ PageSize
	else
	  	TotalPages = TotalPut \ PageSize + 1
	end if
	if CurrentPage > TotalPages then CurrentPage=TotalPages
	if CurrentPage < 1 then CurrentPage=1
	rs.move (CurrentPage-1)*PageSize
	SQL		= rs.GetRows(PageSize)
	rs.close : set rs=Nothing
	%>
	<table border="0" cellspacing="1" align="center" cellpadding="0" class="border">
	<tr align="center" class="title">
		<td width="30">选中</td>
		<td width="60">频道ID</td>
		<td>标题</td>
		<td width="100">用户名</td>
		<td width="60">点数</td>
		<td width="60">金钱</td>
		<td width="120">时间</td>
		<td width="100">操作</td>
	</tr>
	<%'ID,ChannelID,InfoID,Title,Url,UserID,UserName,ConsumePoint,ConsumeMoney,ConsumeNums,ConsumeLog,ConsumeTime,PayType
	For i=0 to Ubound(SQL,2)%>
	<tr align="center" class="tdbg" onMouseOut="this.className='tdbg'" onMouseOver="this.className='tdbg2'">
		<td width="30"><input name="ID" type="checkbox" onclick="unselectall()" id="ID" value="<%=SQL(0,i)%>"></td>
		<td width="60"><a href="User_ConsumeLog.asp?ChannelID=<%=SQL(1,i)%>"><%=SQL(1,i)%></a></td>
		<td><a href="User_ConsumeLog.asp?ChannelID=<%=SQL(1,i)%>&InfoID=<%=SQL(2,i)%>"><%=SQL(3,i)%></a></td>
		<td width="100"><%=SQL(6,i)%></td>
		<td width="60"><font color="red"><%=SQL(7,i)%></font></td>
		<td width="60"><font color="red"><%=SQL(8,i)%></font></td>
		<td width="120"><%=SQL(11,i)%></td>
		<td width="100" align="center">
		<a href="<%=SQL(4,i)%>">查看</a>
		</td>
	</tr>
	<%Next%>
	</table>
	<%
	Response.write Cl.ShowPage(FileName,TotalPut,PageSize,"个","记录")
	SQL=Empty
End sub

Sub DelLog()
	If Clng(Cl.User_Purview(0))<>1 then
		Cl.ShowErr("<br /><li>对不起，你的权限不够！</li>")
	end if
	if ID="" then
		Cl.ShowErr("<br /><li>请先选择要删除的记录ID！</li>")
	end if
	if Instr(ID,",")>0 then
		ID=replace(ID," ","")
		Cl.Execute_L("delete from Cl_ConsumeLog where ID in (" & ID & ")")
	else
		ID=Cl.GetClng(ID)
		Cl.Execute_L("delete from Cl_ConsumeLog where ID = " & ID & " ")
	end if
	Cl.SaveAdminLog
	Call Cl.OutMsg(0,"操作成功，所选记录已被删除！",ComeUrl)
End Sub
%>
<!--
'┌───────────────────────────────────────────────────────┐
'│														 │
'│		CreateLive CMS Version 4.0						 │
'│　　　　　　　　				Powered by Aspoo.CN	 	 │
'│　		　　　　　　　　　　						 │
'│　	邮箱: [e-mail]		[e-mail]　　	 │
'│		ＱＱ: 3315263				596197794			 │
'│		网站: www.aspoo.cn			www.aspoo.com		 │
'│		论坛: bbs.aspoo.cn			bbs.aspoo.com		 │
'│														 │
'│	Copyright (C) 2005-2007 Aspoo.CN All Rights Reserved.	 │
'└───────────────────────────────────────────────────────┘
'-->