s_asinhf.s

glibc 2.9,最新版的C语言库函数

data8 0x3FE513356667FC57    //log(1/frcpa(1+ 238/256)
data8 0x3FE522AE0738A3D8    //log(1/frcpa(1+ 239/256)
data8 0x3FE5322E26867857    //log(1/frcpa(1+ 240/256)
data8 0x3FE541B5CB979809    //log(1/frcpa(1+ 241/256)
data8 0x3FE55144FDBCBD62    //log(1/frcpa(1+ 242/256)
data8 0x3FE560DBC45153C7    //log(1/frcpa(1+ 243/256)
data8 0x3FE5707A26BB8C66    //log(1/frcpa(1+ 244/256)
data8 0x3FE587F60ED5B900    //log(1/frcpa(1+ 245/256)
data8 0x3FE597A7977C8F31    //log(1/frcpa(1+ 246/256)
data8 0x3FE5A760D634BB8B    //log(1/frcpa(1+ 247/256)
data8 0x3FE5B721D295F10F    //log(1/frcpa(1+ 248/256)
data8 0x3FE5C6EA94431EF9    //log(1/frcpa(1+ 249/256)
data8 0x3FE5D6BB22EA86F6    //log(1/frcpa(1+ 250/256)
data8 0x3FE5E6938645D390    //log(1/frcpa(1+ 251/256)
data8 0x3FE5F673C61A2ED2    //log(1/frcpa(1+ 252/256)
data8 0x3FE6065BEA385926    //log(1/frcpa(1+ 253/256)
data8 0x3FE6164BFA7CC06B    //log(1/frcpa(1+ 254/256)
data8 0x3FE62643FECF9743    //log(1/frcpa(1+ 255/256)
LOCAL_OBJECT_END(log_table_3)


.section .text
GLOBAL_LIBM_ENTRY(asinhf)

{ .mfi
      getf.exp   asinh_GR_f8 = f8        // Must recompute later if x unorm
      fclass.m   p12,p0 = f8, 0x0b       // Test x unorm
      mov        log_GR_exp_17_ones = 0x1ffff
}
{ .mfi
      addl       NR_table_address = @ltoff(log_table_1), gp
      fma.s1     log_y = f8, f8, f1      // y = x^2 + 1
      mov        asinh_GR_comp = 0xfffa
}
;;

{ .mfi
      mov        log_GR_exp_16_ones = 0xffff //BIAS
      fclass.m   p6,p0 = f8, 0xe7        // Test for x = NaN and inf and zero
      mov        log_GR_comp2 = 0x10032
}
{ .mfi
      ld8        NR_table_address = [NR_table_address]
      fma.s1     asinh_w_sq = f8,f8,f0   // x^2
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fcmp.lt.s1 p7,p11 = f8,f0          // if x<0
      nop.i      0
}
{ .mfb
      nop.m      0
      fnorm.s1   fNormX = f8             // Normalize x
(p12) br.cond.spnt ASINH_UNORM           // Branch if x=unorm
}
;;

ASINH_COMMON:
// Return here if x=unorm and not denorm
{ .mfi
      //to get second table address
      adds       log_table_address2 = 0x20, NR_table_address
      fma.s1     log_arg = f8,f1,f8
}
{ .mfb
      nop.m      0
(p6)  fma.s.s0   f8 = f8,f1,f8           // quietize nan result if x=nan
(p6)  br.ret.spnt b0                     // Exit for x=nan and inf and zero
}
;;

{ .mfi
      ldfpd      NR1,NR2 = [log_table_address2],16
      frsqrta.s1 log_y_rs,p0 = log_y     // z=1/sqrt(y)
      nop.i      0
}
;;

{ .mfi
      ldfe       log_C1 = [log_table_address2],16
      nop.f      0
      and        asinh_GR_f8 = asinh_GR_f8,log_GR_exp_17_ones
}
;;

{ .mib
      ldfe       log_C0 = [log_table_address2],16
      cmp.le     p13,p0 = log_GR_comp2,asinh_GR_f8
(p13) br.cond.spnt LOG_COMMON1           // Branch if path 4: |x| >= 2^51
}
;;

{ .mfi
      nop.m      0
      fma.s1     log_y_rs_iter = log_y_rs,log_y,f0  // y*z
      nop.i      0
}
;;

.pred.rel "mutex",p7,p11
{ .mfi
      nop.m      0
(p11) mov        asinh_f8 = fNormX
      nop.i      0
}
{ .mfb
      cmp.gt     p8,p0 = asinh_GR_comp,asinh_GR_f8
(p7)  fnma.s1    asinh_f8 = fNormX,f1,f0
(p8)  br.cond.spnt ASINH_NEAR_ZERO       // Branch if path 2: 0 < |x| < 2^-5
}
;;

// Here if main path, 2^-5 <= |x| < 2^51
///////////////////////////////// The first iteration /////////////////////////
{ .mfi
      ldfpd      log_P3,log_P2 = [NR_table_address],16
      fnma.s1    log_y_rs_iter2 = log_y_rs_iter,log_y_rs,NR2    // 3-(y*z)*z
      nop.i      0
}
{ .mfi
      nop.m      0
      fma.s1     log_y_rs_iter1 = log_y_rs,NR1,f0               // 0.5*z
      nop.i      0
}
;;

{ .mfi
      ldfpd      log_P1,log2 = [NR_table_address],16
      // (0.5*z)*(3-(y*z)*z)
      fma.s1     log_y_rs_iter = log_y_rs_iter1,log_y_rs_iter2,f0
      nop.i      0
}
{ .mfi
      nop.m      0
      // (0.5*z)*(3-(y*z)*z)
      fma.s1     log_arg_early = log_y_rs_iter1,log_y_rs_iter2,f0
      nop.i      0
}
;;

////////////////////////////////// The second iteration ////////////////////////
{ .mfi
      nop.m      0
      fma.s1     log_y_rs = log_y_rs_iter,log_y,f0
      nop.i      0
}
{ .mfi
      nop.m      0
      fma.s1     log_y_rs_iter1 = log_y_rs_iter,NR1,f0
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fma.s1     log_arg_early = log_arg_early,log_y,asinh_f8
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fnma.s1    log_y_rs = log_y_rs,log_y_rs_iter,NR2
      nop.i      0
}
{ .mfi
      nop.m      0
      fma.s1     log_y_rs_iter1 = log_y_rs_iter1,log_y,f0
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      frcpa.s1   log_C,p0 = f1,log_arg_early
      nop.i      0
}
;;

{ .mfi
      getf.exp   log_GR_signexp_f8 = log_arg_early
      nop.f      0
      nop.i      0
}
;;

{ .mfi
      getf.sig   log_GR_significand_f8 = log_arg_early
      // (0.5*z)*(3-(y*z)*z)*y + |x|
      fma.s1     log_arg = log_y_rs_iter1,log_y_rs,asinh_f8
      //to get third table address
      adds       log_table_address3 = 0x30, NR_table_address
}
;;

/////////////////////////////////////////// The end NR iterations /////////////

{ .mfi
      nop.m      0
      nop.f      0
      //significant bit destruction
      and        log_GR_exp_f8 = log_GR_signexp_f8, log_GR_exp_17_ones
}
;;

{ .mfi
      //BIAS subtraction
      sub        log_GR_true_exp_f8 = log_GR_exp_f8, log_GR_exp_16_ones
(p7)  fnma.s1    log2 = log2,f1,f0
      nop.i      0
}
;;

{ .mfi
      setf.sig   log_int_Nfloat = log_GR_true_exp_f8
      fms.s1     log_r = log_C,log_arg,f1  //C = frcpa(x); r = C * x - 1
      extr.u     log_GR_index = log_GR_significand_f8,55,8 //Extract 8 bits
}
;;

{ .mmi
      //pre-index*16 + index
      shladd     log_table_address3 = log_GR_index,3,log_table_address3
;;
      ldfd       log_T = [log_table_address3]
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fma.s1     log_rsq = log_r, log_r, f0          //r^2
      nop.i      0
}
{ .mfi
      nop.m      0
      fma.s1     log_rp_p32 = log_P3, log_r, log_P2  //P3*r + P2
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fma.s1     log_rp_p10 = log_P1, log_r, f1
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      //convert N to the floating-point format
      fcvt.xf    log_Nfloat = log_int_Nfloat
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fma.s1     log_rp_p2 = log_rp_p32, log_rsq, log_rp_p10
      nop.i      0
}
;;

.pred.rel "mutex",p7,p11
{ .mfi
      nop.m      0
(p11) fma.s1     log_T_plus_Nlog2 = log_Nfloat,log2,log_T  //N*log2 + T if x>0
      nop.i      0
}
{ .mfi
      nop.m      0
(p7)  fms.s1     log_T_plus_Nlog2 = log_Nfloat,log2,log_T  //N*log2 - T if x<0
      nop.i      0
}
;;

{ .mfi
      nop.m      0
(p11) fma.s.s0   f8 = log_rp_p2,log_r,log_T_plus_Nlog2
      nop.i      0
}
{ .mfb
      nop.m      0
(p7)  fnma.s.s0  f8 = log_rp_p2,log_r,log_T_plus_Nlog2
      br.ret.sptk b0          // Exit main path, path 3: 2^-5 <= |x| < 2^51
}
;;


// Here if path 4, |x| >= 2^51
LOG_COMMON1:
{ .mfi
      ldfpd      log_P3,log_P2 = [NR_table_address],16
      nop.f      0
      nop.i      0
}
;;

{ .mfi
      ldfpd      log_P1,log2 = [NR_table_address],16
      frcpa.s1   log_C,p0 = f1,log_arg
      nop.i      0
}
;;

{ .mfi
      getf.exp   log_GR_signexp_f8 = log_arg
      nop.f      0
      //to get third table address
      adds       log_table_address3 = 0x30, NR_table_address
}
;;

{ .mfi
      getf.sig   log_GR_significand_f8 = log_arg
      nop.f      0
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      nop.f      0
      //to destroy the most bit in the significant area
      and        log_GR_exp_f8 = log_GR_signexp_f8, log_GR_exp_17_ones
}
;;

{ .mmf
      nop.m      0
      //BIAS subtraction
      sub        log_GR_true_exp_f8 = log_GR_exp_f8, log_GR_exp_16_ones
      fms.s1     log_r = log_C,log_arg,f1  //C = frcpa(x); r = C * x - 1
}
;;

{ .mfi
      setf.sig   log_int_Nfloat = log_GR_true_exp_f8
      nop.f      0
      extr.u     log_GR_index = log_GR_significand_f8,55,8 //Extract 8 bits
}
;;

{ .mmi
      //pre-index*16 + index
      shladd     log_table_address3 = log_GR_index,3,log_table_address3
;;
      ldfd       log_T = [log_table_address3]
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fma.s1     log_rsq = log_r, log_r, f0          //r^2
      nop.i      0
}
{ .mfi
      nop.m      0
      fma.s1     log_rp_p32 = log_P3, log_r, log_P2  //P3*r + P2
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      fma.s1     log_rp_p10 = log_P1, log_r, f1
      nop.i      0
}
{ .mfi
      nop.m      0
(p7)  fnma.s1    log2 = log2,f1,f0
      nop.i      0
}
;;

{ .mfi
      nop.m      0
      //convert N to the floating-point format
      fcvt.xf    log_Nfloat = log_int_Nfloat
      nop.i      0
}
{ .mfi
      nop.m      0
      fma.s1     log_rp_p2 = log_rp_p32, log_rsq, log_rp_p10
      nop.i      0
}
;;

.pred.rel "mutex",p7,p11
{ .mfi
      nop.m      0
(p11) fma.s1     log_T_plus_Nlog2 = log_Nfloat,log2,log_T  //N*log2 + T if x>0
      nop.i      0
}
{ .mfi
      nop.m      0
(p7)  fms.s1     log_T_plus_Nlog2 = log_Nfloat,log2,log_T  //N*log2 - T if x<0
      nop.i      0
}
;;

{ .mfi
      nop.m      0
(p11) fma.s.s0   f8 = log_rp_p2,log_r,log_T_plus_Nlog2
      nop.i      0
}
{ .mfb
      nop.m      0
(p7)  fnma.s.s0  f8 = log_rp_p2,log_r,log_T_plus_Nlog2
      br.ret.sptk b0           // Exit path 4, |x| >= 2^51
}
;;

// Here if path 2, 0 < |x| < 2^-5
ASINH_NEAR_ZERO:
{ .mfi
      nop.m      0
      fma.s1     asinh_w_1 = asinh_w_sq,log_C1,log_C0
      nop.i      0
}
{ .mfi
      nop.m      0
      fma.s1     asinh_w_cube = asinh_w_sq,fNormX,f0
      nop.i      0
}
;;

{ .mfb
      nop.m      0
      fma.s.s0   f8 = asinh_w_1,asinh_w_cube,fNormX
      br.ret.sptk b0          // Exit path 2, 0 < |x| < 2^-5
}
;;

ASINH_UNORM:
// Here if x=unorm
{ .mfi
      getf.exp   asinh_GR_f8 = fNormX  // Recompute if x unorm
      fclass.m   p0,p13 = fNormX, 0x0b // Test x denorm
      nop.i      0
}
;;

{ .mfb
      nop.m      0
      fcmp.eq.s0 p14,p0 = f8, f0       // Dummy to set denormal flag
(p13) br.cond.sptk ASINH_COMMON        // Continue if x unorm and not denorm
}
;;

.pred.rel "mutex",p7,p11
{ .mfi
      nop.m      0
(p7)  fma.s.s0   f8 = f8,f8,f8         // Result x+x^2 if x=-denorm
      nop.i      0
}
{ .mfb
      nop.m      0
(p11) fnma.s.s0  f8 = f8,f8,f8         // Result x-x^2 if x=+denorm
      br.ret.spnt b0                   // Exit if denorm
}
;;

GLOBAL_LIBM_END(asinhf)