dbclass.asp

一个很精美,功能很齐全的网络游戏交易站,自带后台,管理非常方便

<%
'****************************************************************
'类名称:Cls_DataBase
'类作用:创建数据库连接，执行查询，修改，插入等数据库操作
'类属性:Name 连接数据库名(只写)
'类方法:Execute(Command) 数据库操作函数 ConnObj()返回数据对象
'类作者: Bruce He  [e-mail]
'****************************************************************
Class Cls_DataBase
	Private	Conn,ConnString
	Public IsSql
	
	Private Sub Class_Initialize()
		IsSql = 0
	End Sub
	
	Private Sub Class_Terminate()
		If IsObject(Conn) Then Conn.Close : Set Conn = Nothing
	End Sub
	
	Rem --------------------------------
	Rem 创建connection对象
	Rem --------------------------------
	Private Sub ConnCreate
		Set Conn = Server.CreateObject("ADODB.Connection")
		On Error Resume Next		
		'数据库连接打开语句，在此输入数据库名称	
		Conn.Open ConnString
		If Err.Number<>0 Then
			Response.Write(Err.Description)
			Err.Clear
			Set Conn = Nothing
			'Response.Write("数据库连接错误!请检查数据库地址是否正确")
			Response.End()
		End If
	End Sub
	
	Rem ======================================
	Rem 获取连接数据库名
	Rem ======================================
	Public Sub SetName(db,User,Password,ServerIP)
		If IsSql = 0 Then
			ConnString= "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(""&db&"")
		Else
			ConnString= "Provider=sqloledb;Data Source="&ServerIP&";Initial Catalog="&db&";User Id="&User&"; Password="&Password&";"
		End If
	End Sub
	
	Rem ======================================
	Rem 数据库操作主函数
	Rem ======================================
	Public Function Execute(Command)
		If Not IsObject(Conn) Then ConnCreate
		On Error Resume Next
		Set Execute = Conn.Execute(Command)
		If Err Then
			Response.Write(Err.description)
			err.Clear
			Set Conn = Nothing
			Response.Write "数据库操作的时候发生错误。"
			Response.End
		End If
	End Function
	
	Rem =====================================
	Rem 返回数据连接对象
	Rem =====================================
	Public Function ConnObj()
		If Not IsObject(Conn) Then ConnCreate
		Set ConnObj = Conn
	End Function
End Class
%>