formdata.inc.asp

商业网站/图片管理系统/投票系统/新闻管理系统/

<%
dim data,datalength,fstart,fend,tstart,tend,tinfo,flag,flaglen,tformname,tfile,tfilename,tfilepath,tfileext,sfilename
dim formdata,updata,tmpdata,key,tcrlf
set formdata=server.CreateObject("Scripting.Dictionary")
set updata=server.CreateObject("ADODB.Stream")
set tmpdata=server.CreateObject("ADODB.Stream")
updata.Type=1'设置对象的数据类型为二进制数据
updata.mode=3'设置对象的打开模式为读写模式
updata.open'打开对象
updata.write request.BinaryRead(request.TotalBytes)
updata.position=0
data=updata.read
datalength=updata.size
tcrlf=chrb(13) & chrb(10)'回车符号代码
flag=leftb(data,instrb(data,tcrlf)-1)'获取每个表单项目数据之间的分隔符
fstart=lenb(flag)+2'搜索开始位置 加2是因为分隔符后有一个回车符号占两个字节
flaglen=fstart'分隔符长度，包含了后面的回车符
'循环处理表单元素
do

  '分离出表单元素信息  即从开始查找位置到有两个回车符之间的信息
  fend=instrb(fstart,data,tcrlf&tcrlf)+3
  '初始化临时STREAM对象
  tmpdata.type=1
  tmpdata.mode=3
  tmpdata.open
  '设置指针位置
  updata.position=fstart
  updata.copyto tmpdata,fend-fstart'将元素表单信息复制到临时STREAM对象
  fstart=instrb(fend,data,flag)-1'查找下一个分隔符所在位置
  'fstart=instrb(fend,data,flag)
  tmpdata.position=0
  tmpdata.type=2'设置读取方式为文本
  tmpdata.charset="gb2312"'设置编码方式为GB2312
  tinfo=tmpdata.readtext
  '取得表单元素的名称
  tstart=instr(22,tinfo,"name=""")+6
  tend=instr(tstart,tinfo,"""",1)
  tformname=mid(tinfo,tstart,tend-tstart)
  '取得表单元素的值
  if instr(tstart,tinfo,"filename=""",1)>0 then '如果是文件
    tmpdata.close
	tmpdata.type=1
	tmpdata.mode=3
	tmpdata.open
    '取得文件属性
	tstart=instr(tend,tinfo,"filename=""",1)+10
	tend=instr(tstart,tinfo,"""",1)
	tfile=mid(tinfo,tstart,tend-tstart)'得到文件全路径
	if tfile<>"" then
		tfilename=mid(tfile,instrrev(tfile,"\")+1)'得到文件名
		tfilepath=left(tfile,instrrev(tfile,"\"))'得到文件路径
		tfileext=mid(tfile,instrrev(tfile,".")+1)' 得到文件后缀
		sfilename=GetRndFileName(tfileext)
		'response.write tfilename & "<br>" & tfilepath & "<br>" & tfileext
		'得到文件数据
		updata.position=fend
		updata.copyto tmpdata,fstart-2-fend
		tmpdata.savetofile server.MapPath("../upfile") & "\" & sfilename,2
		formdata.add tformname,sfilename
	end if
  else
  '如果是表单元素
    tmpdata.close
	tmpdata.type=1
	tmpdata.mode=3
	tmpdata.open
	updata.position=fend'设置指针指向数据区域开始位置
	updata.copyto tmpdata,fstart-fend-2'复制数据到临时STREAM对象：复制长度为一下个分隔符开始位置-2 -2是因为要减掉最后的回车符长度
	tmpdata.position=0
	tmpdata.type=2
	tmpdata.charset="gb2312"
	formdata.add tformname,tmpdata.readtext
  end if
  
  fstart=fstart+flaglen'得到下次搜索开始位置:分隔符开始位置加上分融符长度得到下次搜索开始位置
  tmpdata.close
loop while (fstart+2)<datalength'如果还没有到结尾  因为束标志是 -- 两个字节，所以这里要加2后再判断
set tmpdata=nothing
updata.close
set updata=nothing

'for each key in formdata.keys
'	response.write "form_control_name：" & key & " key：" & formdata.item(key) & "<br />"
'next

' 取随机文件名
Function GetRndFileName(sExt)
	Dim sRnd
	Randomize
	sRnd = Int(900 * Rnd) + 100
	GetRndFileName = year(now) & month(now) & day(now) & hour(now) & minute(now) & second(now) & sRnd & "." & sExt
End Function
%>