scenechangeeffect.as.svn-base

Flex3实现的掼蛋游戏

 /**
  * Project: 用以过场转换的自定义效果 效果生成类
  * 原库类为 com.oreilly.programmingflex.effects 此处引用略有修改
  * Author : dmh2002 Blog:http://dmh2002.com/
  * QQ:122054933 MSN:[e-mail] 
  * Date : 2008.04.05 
  */   
package com.dmh2002.games.cardgame.effects {

	import mx.core.UIComponent;
	import mx.effects.Effect;
	import mx.effects.IEffectInstance;
	import mx.events.EffectEvent;
	
	public class SceneChangeEffect extends Effect
	{
		/** 定义属性 */		
		private var _toX:Number;
		private var _toY:Number;
		private var _toWidth:Number;
		private var _toHeight:Number;
		private var _toComp:UIComponent;
		private var _formComp:UIComponent;
                
        /** get/set 存储器 */
        public function set toX(value:Number):void 
        {
			_toX = value;
		}		
		public function set toY(value:Number):void 
		{
			_toY = value;
		}
		public function set toWidth(value:Number):void 
		{
			_toWidth = value;
		}
		public function set toHeight(value:Number):void 
		{
			_toHeight = value;
		}
		public function set toComp(value:UIComponent):void 
		{
			_toComp = value;
		}
		
		/** 构造函数 
		 * 继承Effect必须定义的方法
		 * 必须调用super()方法来调用父类的构造函数
		 * 并且必须接收一个参数来指定目标对象
		 */
		public function SceneChangeEffect(newTarget:Object = null) {
			super(newTarget);
			instanceClass = SceneChangeEffectInstance;
		}
		
		/** initInstance()方法
		 * 继承Effect必须定义的方法
		 * 将生成类的属性转到实例对象中，这个方法由
		 * 并且必须接收一个参数来指定目标对象Effect对象内部调用，不在外部使用。
		 * 另外，覆盖的函数体中必须执行函数:super.initInstance(instance);
		 */		
		override protected function initInstance(instance:IEffectInstance):void 
		{
			super.initInstance(instance);
            SceneChangeEffectInstance(instance).toX = _toX;
            SceneChangeEffectInstance(instance).toY = _toY;
            SceneChangeEffectInstance(instance).toWidth = _toWidth;
            SceneChangeEffectInstance(instance).toHeight = _toHeight;
            SceneChangeEffectInstance(instance).toComp = _toComp;    
		}
		
		/** getAffectedProperties()方法
		 * 继承Effect必须定义的方法
		 * 返回一个字符串数组，包括目标对象被改变的属性名。
		 * 如果没有改变，则返回空数组
		 */	
		override public function getAffectedProperties():Array
		{
			return ["toX","toY","toWidth","toHeight"];
		}
	}
}