mydataformat.as

Flex3实现的掼蛋游戏

//格式化日期类
package com.dmh2002.util{
	//
	import ascb.util.NumberFormat;
	//
	public class MyDataFormat {

	  /** 将毫秒数格式化成二段式 用以显示时间
		* 参数 nTotalSeconds 秒数（Number）
		* 返回 00:00 样式时间(String)
		* 当时间小于60分钟时，返回的二段式为  分钟：秒数
		* 当时间大于60分钟时：返回的二段式为  小时：分钟
		* 范 例
		* trace(MyDataFormat.formatSecondsToTwoSegment(-1))   //00:00
		* trace(MyDataFormat.formatSecondsToTwoSegment(0))    //00:00
		* trace(MyDataFormat.formatSecondsToTwoSegment(1))    //00:01
		* trace(MyDataFormat.formatSecondsToTwoSegment(59))   //00:59
		* trace(MyDataFormat.formatSecondsToTwoSegment(60))   //01:00
		* trace(MyDataFormat.formatSecondsToTwoSegment(90))   //01:30
		* trace(MyDataFormat.formatSecondsToTwoSegment(120))  //02:00
		* trace(MyDataFormat.formatSecondsToTwoSegment(3661)) //01:01
		* trace(MyDataFormat.formatSecondsToTwoSegment(7461)) //02:04 
		*/

		public static function formatSecondsToTwoSegment(nTotalSeconds:Number):String {
			var maxTime:Number=100*3600-1;
			var nTotalSeconds:Number;
			nTotalSeconds=nTotalSeconds>=0?nTotalSeconds:0;
			nTotalSeconds=nTotalSeconds<=maxTime?nTotalSeconds:0;
			//获取格式化 方法
			var nfFormatter:NumberFormat=new NumberFormat("00");
			var _hour:uint=Math.floor(nTotalSeconds / 3600);
			var _minutes:uint=_hour < 1?Math.floor(nTotalSeconds / 60):Math.floor((nTotalSeconds - (3600*_hour))/60);
			var _seconds:uint=nTotalSeconds % 60;
			//
			var sHour:String=nfFormatter.format(_hour);
			var sMinutes:String=nfFormatter.format(_minutes);
			var sSeconds:String=nfFormatter.format(_seconds);
			//
			var sTime:String=_hour < 1?sMinutes + ":" + sSeconds:sHour + ":" + sMinutes;
			return sTime;
		}//end function

	  /**将毫秒数格式化成三段式 用以显示时间
		*参数 nTotalMilliseconds 毫秒数（Number）
		*返回 00:00:00 样式时间(String)
		*当时间小于60分钟时，返回的三段式为  分钟：秒数：毫秒数
		*当时间大于60分钟时：返回的三段式为  小时：分钟：秒数
		* 范例
		* var miao:uint=1000
		* var fen:uint=60*miao
		* var h:uint=60*fen
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(-1))                      //00:00:00
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(0))                       //00:00:00
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(10))                      //00:00:10
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(59))                      //00:00:05        
		* //
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(1*miao))                  //00:01:00
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(1*miao+120))              //00:01:12
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(1*fen+1*miao+120))        //01:01:12
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(1*h+11*fen+30*miao))      //01:11:30
		* trace(MyDataFormat.formatMillisecondsToThreeSegment(100*h+11*fen+30*miao))    //00:00:00
		*/
		public static function formatMillisecondsToThreeSegment(nTotalMilliseconds:Number):String {
			var maxTime:Number=100*3600*100-1;
			var nTotalMilliseconds:Number;
			nTotalMilliseconds=Math.floor(nTotalMilliseconds/10);
			nTotalMilliseconds=nTotalMilliseconds>=0?nTotalMilliseconds:0;
			nTotalMilliseconds=nTotalMilliseconds<=maxTime?nTotalMilliseconds:0;
			//获取格式化 方法
			var nfFormatter:NumberFormat=new NumberFormat("00");
			//
			var _hour:uint=Math.floor(nTotalMilliseconds / (3600*100));
			var _minutes:uint= _hour < 1?Math.floor(nTotalMilliseconds / (60*100)) : Math.floor((nTotalMilliseconds - (3600*100*_hour))/(60*100));
			var _seconds:uint= _hour < 1?Math.floor((nTotalMilliseconds - (60*100*_minutes))/100) : Math.floor((nTotalMilliseconds - (3600*100*_hour+60*100*_minutes))/100);

			var _milliseconds:uint=nTotalMilliseconds %100;
			//
			var sHour:String=nfFormatter.format(_hour);
			var sMinutes:String=nfFormatter.format(_minutes);
			var sSeconds:String=nfFormatter.format(_seconds);
			var sMilliseconds:String=nfFormatter.format(_milliseconds);
			//
			var sTime:String=_hour < 1? sMinutes+ ":" +sSeconds+ ":" + sMilliseconds  : sHour+ ":" + sMinutes + ":" +sSeconds;
			//
			return sTime;
		}
		//
	/**返回中文星期 使用了方法重载
	 * 参数 ...args 
	 * 如果对象是Date
	 * 则使用Date的getDay()方法获取星期
	 * 如果对象是uint
	 * 则直接使用该数字，数字尝过6，返回null
	 * 
	 */
	 public static function getChineseWeekLable(...args):String
	 {
	 	var weekDayLabels:Array = new Array("星期日","星期一","星期二","星期三","星期四","星期五","星期六");
   
        switch (typeof(args[0])) {             
             case "object" :
             	return weekDayLabels[args[0].getDay()];
                break;
             case "number" :
                if(args[0]>6){
                 return null
                }else{
                 return weekDayLabels[args[0]];
                }             
                break;
             default :
                return  null           
        }
	 }
		//
	}
}