dailyschedule.as

来自「用Flex实现的一个关于减肥系统的web界面,内部没有实际的业务逻辑,只是一个原」· AS 代码 · 共 56 行

package diet.vo.schedule
{
	import diet.util.ActivityType;
	import diet.vo.activity.DietActivity;
	import diet.vo.activity.DinnerActivity;
	import diet.vo.activity.SportActivity;
	
	import mx.collections.ArrayCollection;
	[Bindable]
	public class DailySchedule
	{
		public var date:Date;//当日日期
		
		//每天减重活动的集合
		public var activityArray:ArrayCollection = new ArrayCollection();
		public var dailyCalorieSum:Number;//当日计划卡路里消耗/获取总和
		
		public var goalWeight:Number;//当日目标体重
		public var actualWeight:Number;//当日实际体重
		
		public function initActivityArray():void
		{
			//var timeZone:TimeZone = new TimeZone();
			for(var i:int=0;i<ActivityType.typeArray.length;i++)
			{
				var activity:DietActivity;
				var type:String = ActivityType.typeArray[i];
				switch(type)
				{
					case ActivityType.BREAKFAST:
					case ActivityType.LUNCH:
					case ActivityType.SUPPER:
					{
						activity = new DinnerActivity();
						activity.startTime = new Date(this.date.getTime());
						activity.endTime = new Date(this.date.getTime());
						DinnerActivity(activity).initDinnerTime(type);
						DinnerActivity(activity).initFoodArray();
						break;
					}
					case ActivityType.SPORTS:
					{
						activity = new SportActivity();
						activity.startTime = new Date(this.date.getTime());
						activity.endTime = new Date(this.date.getTime());
						SportActivity(activity).initSportTime();
						SportActivity(activity).initSport();
						break;
					}
				}
				activity.type = type;
				this.activityArray.addItem(activity);
			}
		}
	}
}