comment_function.asp

一个用jsp 编写的个人主页网站哦。希望对大家有所帮助啊

<%
'过滤非法字符
Function ChkBadWords(fString)
    Dim bwords,wordnum
    bwords = split(badWordStr, "|")
    
    For wordnum = 0 To ubound(bwords)
        fString = Replace(fString, bwords(wordnum), string(len(bwords(wordnum)),"*"),1,-1,1) 
    Next
    ChkBadWords = fString
End Function

'ubb转html
Function ubbCode(strContent)
    on error resume next
	strContent = ChkBadWords(strContent)
	dim objRegExp
	Set objRegExp=new RegExp
	objRegExp.IgnoreCase =true
	objRegExp.Global=True

    strContent = Server.HTMLEncode(strContent)

    strContent = Replace(strContent, "[br]", "<br>")

	objRegExp.Pattern="(\[b\])(.[^\[]*)(\[\/b\])"
	strContent=objRegExp.Replace(strContent,"<b>$2</b>")
	objRegExp.Pattern="(\[i\])(.[^\[]*)(\[\/i\])"
	strContent=objRegExp.Replace(strContent,"<i>$2</i>")
	objRegExp.Pattern="(\[u\])(.[^\[]*)(\[\/u\])"
	strContent=objRegExp.Replace(strContent,"<u>$2</u>")

	objRegExp.Pattern="(\[face=(.[^\[]*)\])(.[^\[]*)(\[\/face\])"
	strContent=objRegExp.Replace(strContent,"<font face=""$2"">$3</font>")
	objRegExp.Pattern="(\[size=(.[^\[]*)\])(.[^\[]*)(\[\/size\])"
	strContent=objRegExp.Replace(strContent,"<font size=""$2"">$3</font>")
	objRegExp.Pattern="(\[color=(.[^\[]*)\])(.[^\[]*)(\[\/color\])"
	strContent=objRegExp.Replace(strContent,"<font color=""$2"">$3</font>")

	objRegExp.Pattern="(\[URL=(.[^\[]*)\])(.[^\[]*)(\[\/URL\])"
	strContent= objRegExp.Replace(strContent,"<A HREF=""$2"" TARGET=""_blank""> <IMG SRC=""htmledit/url.gif"" border=""0"" alt=""点此打开链接!"" height=""16"" width=""16"">$3</A>")

	objRegExp.Pattern="(\[IMG\])(.[^\[]*)(\[\/IMG\])"
	strContent=objRegExp.Replace(strContent,"<IMG SRC=""htmledit/img.gif"" border=""0"" height=""16"" width=""16""> 图片如下：<br><a href=""$2"" TARGET=""_blank""><IMG onload='javascript:if(this.width>body.clientHeight)this.width=body.clientHeight' SRC=""$2"" border=""0"" alt=""按此在新窗口浏览图片"" onload=""javascript:if(this.width>500)this.width=500""></A>")

	objRegExp.Pattern = "\[email=(.[^\]]*)\](.*?)\[\/email]"
	strContent = objRegExp.Replace(strContent,"<img align=absmiddle src=htmledit/email.gif> <a href=""mailto:$1"">$2</a>")
	objRegExp.Pattern = "\[email](.*?)\[\/email]"
	strContent = objRegExp.Replace(strContent,"<img align=absmiddle src=htmledit/email.gif> <a href=""mailto:$1"">$1</a>")

	objRegExp.Pattern="\[quote\][\n\r]*(.[^\[]*)[\n\r]*\[\/quote\]"
	strContent=objRegExp.Replace(strContent,"<div class='msgbody'><div class='msgheader'>QUOTE:</div><div class='msgborder'>$1</div></div>")

        objRegExp.Pattern="\[em](.*?)\[\/em]"
	strContent=objRegExp.Replace(strContent,"<img src=htmledit/qq/em$1.gif>")

	set objRegExp=Nothing
	ubbCode=strContent
End Function

'分页函数
Function pageInc(pageNum)
pageInc=""
onPage = int(Request("page"))
pageNum = int(pageNum)
 IF onPage = 0 Then onPage=1
 IF onPage - 2 < 1 Then
 FirstPage = 1
 Else
 FirstPage = onPage - 2
 End IF
 
 IF pageNum > FirstPage + 8 Then
 LastPage = FirstPage + 8
 Else
 LastPage = pageNum
 End IF
 
 IF (onPage-1)=0 Then
   pageInc=pageInc&"<li>首页</li> "&"<li>上一页</li> "
 Else
     pageInc=pageInc&"<li><a href=""javascript:pageAjax('1')"">首页</a> "&"<a href=""javascript:pageAjax("&(onPage-1)&")"">上一页</a></li> "
 End IF
 
 For p=FirstPage To LastPage
  IF onPage=p Then
    pageInc=pageInc&"<li class=currentpage>"&p&"</li> "
  Else
    pageInc=pageInc&"<li><a href=""javascript:pageAjax("&p&")"">"&p&"</a></li> "
  End IF
 Next
 
 IF onPage = pageNum or (LastPage+1)=14 or pageNum=0 Then
   pageInc=pageInc&"<li>下一页</li> "&"<li>末页</li> "
 Else
     pageInc=pageInc&"<li><a href=""javascript:pageAjax("&(onPage+1)&")"">下一页</a> "&"<a href=""javascript:pageAjax("&pageNum&")"">末页</a></li> "
 End IF
 
 'IF LastPage<pageNum Then
  'pageInc=pageInc&"... "&pageNum
 'End IF 
End Function

'ip最后一个地址转换成*
Function iptostart(ip)
 iptostart = left(ip,InStrRev(ip,"."))
 iptostartTem = len(right(ip,len(ip)-InStrRev(ip,".")))
 For l=1 To iptostartTem
 iptostart = iptostart&"*"
 Next
End Function

'检查验证码是否正确
	Function CodeIsTrue()
		Dim CodeStr
		CodeStr=Lcase(Trim(Request("CodeStr")))
		If CStr(Session("GetCode"))=CStr(CodeStr) And CodeStr<>""  Then
			CodeIsTrue=True
			Session("GetCode")=empty
		Else
			CodeIsTrue=False
			Session("GetCode")=empty
		End If	
	End Function
%>