📄 book2.asp

📁 网上购物系统 asp+sql server 2005
💻 ASP
字号:
<!--#include file="../include/dbopenbd.asp"-->
<!--#include file="checkadmin.asp"-->
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="manage.css" type="text/css">
<script language="JavaScript" type="text/JavaScript">
function CheckAll(form) {
	for (var i=0;i<form.elements.length;i++) {
		var e = form.elements[i];
		if (e.name != 'chkall') e.checked = form.chkall.checked; 
	}
}
</script>
</head>
<BODY background="../images/admin/back.gif">

<%
allpages=0
page=1
totalrec=0
per_page_num=20
url="book2.asp"

'参数
action=request("action")
'列表显示情况
if action="" then call book_index()
'添加、修改的显示和提交处理开始
id=request("id")
'提交
if action="bookok" then call bookok()
'显示
if action="modify" then call bookmodify()
'多选功能处理开始
ids=replace(request("id"),"'","")
if ids="" then mGoBack "您什么也没有选择，单击“确定”返回上一页！"
'关闭
if action="关闭" then call bookclose()
'打开
if action="打开" then call bookopen()
'删除
if action="删除" then call bookdel()

sub book_index()
%>

<table width="98%" border="1" cellpadding="3" bordercolor="#333333" style="border-collapse: collapse;" style="word-break:break-all">
	<tr class=backs><td colspan=6 class=td height=18>商品评论管理 &nbsp;</td></tr>
	<form name=Prodlist action=book2.asp method=post><tr>	
	<td align=center width=5%>选</td>
	<td align=center width=7%>商品</td>
	<td align=center width=18% height=15>姓名</td> 
	<td align=center width=45%>内容</td>
	<td align=center width=15%>日期</td>
	<td align=center width=10%>审核</td>
	</tr>
<%
pages = per_page_num
Set rs=Server.CreateObject("ADODB.Recordset")
sql="select * from s_pinglun order by adddate desc"
rs.open sql,conn,1,1 
if rs.eof and rs.bof then
	response.write "<tr><td colspan=6 align=center><BR>暂时没有商品评论<BR><BR></td></tr>"
else
	totalrec = RS.RecordCount
	rs.pageSize = pages
	allPages = rs.pageCount
	page = Request("page")
	If not isNumeric(page) then page=1
	if isEmpty(page) or int(page) <= 1 then
	page = 1
	elseif int(page) >= allPages then
	page = allPages 
	end if
	rs.AbsolutePage = page
	 
	do while not rs.eof and pages>0
	content=rs("nr")	
	name=rs("name")

	Response.write "<tr><td align=center><input type='checkbox' value='"&rs("ID")&"' name=id></td>"
	Response.write "<td align=center><a target='_blank' href=../list.asp?prodid="&rs("prodid")&"><img alt='查看该评论相关商品' border=0 src='../images/admin/goto.gif'></td><td>"&name&"</td><td><a href='book2.asp?action=modify&id="&rs("ID")&"'>"
	response.write lleft(server.htmlencode(content),50)
	response.write "</a></td><td  align=center>"&split(rs("adddate"))(0)&"</td><td  align=center>"
	if rs("status")="0" then
 	  response.write "<font color=red>隐藏</font>"
	else
	  response.write "公开"
	end if
	response.write "</td></tr>"
	pages=pages-1
	rs.movenext		
	loop
end if

rs.close
conn.close
set rs=nothing
set conn=nothing
%>
<tr><td colspan=6>
	<input type='checkbox' name=chkall onclick='CheckAll(this.form)'>全选 
	<input type="submit" name="action" value="关闭" onclick="{if(confirm('确定隐藏这条新闻吗？')){this.document.newslist.submit();return true;}return false;}"> <input type="submit" name="action" value="打开" onclick="{if(confirm('确定要显示这条新闻吗？')){this.document.newslist.submit();return true;}return false;}">
	<input type="submit" name="action" value="删除" onclick="{if(confirm('该操作不可恢复！\n\n确定删除选定的新闻？')){this.document.newslist.submit();return true;}return false;}"> 
	</td></tr></form></table>
<%
call listPages()
response.end
end sub


sub listPages() 
response.write "<br> &nbsp;&nbsp;&nbsp; 总留言数："&totalrec& "&nbsp;&nbsp; 每页："& per_page_num&" 条记录&nbsp;&nbsp;&nbsp;"
if allpages <= 1 then exit sub 
if page = 1 then
response.write " <font color=#878787>首页 上页</font>"
else
response.write " <a href='"&request.ServerVariables("script_name")&"?page=1'>首页</a> "
response.write " <a href='"&request.ServerVariables("script_name")&"?page="&page-1&"'>上页</a> "
end if
if page = allpages then
response.write "<font color=#878787>下页 末页</font>"
else
response.write " <a href='"&request.ServerVariables("script_name")&"?page="&page+1&"'>下页</a> "
response.write " <a href='"&request.ServerVariables("script_name")&"?page="&allpages&"'>末页</a> "
end if
response.write "&nbsp;&nbsp;&nbsp;第"&page&"/"&allpages&"页"
end sub

sub bookopen()
	sql="update s_pinglun set status=1 where id in ("&ids&")"
	conn.execute sql
	mGoTo url,"所选评论已被打开！"
end sub

sub bookclose()
	sql="update s_pinglun set status=0 where id in ("&ids&")"
	conn.execute sql
	mGoTo url,"所选评论已被关闭！"
end sub

sub bookdel()
	sql="delete from s_pinglun where id in ("&ids&")"
	conn.execute sql
	mGoTo url,"所选评论已被删除，单击“确定”返回评论列表！"
end sub

sub bookok()	
	Set rs=Server.CreateObject("ADODB.Recordset")
	if id="" then
		sql = "select * from s_pinglun where 1=2"
		rs.open sql,conn,1,3
		rs.Addnew
	else
		sql = "select * from s_pinglun where id="&id
		rs.open sql,conn,1,3
	end if
	if request.form("nr")="" then
		rs("nr")=null
	else
		rs("nr")=request.form("nr")
	end if
	rs("status")=request("view")
	rs.update	
	rs.close
	conn.close
	set rs=nothing
	set conn=nothing
	
	mGoTo url,"操作成功，单击“确定”返回评论列表！"
end sub

sub bookmodify()
	set rs = server.createobject("adodb.recordset")
	sql = "select * from s_pinglun where id="&id
	rs.open sql,conn,1,1
	if not (rs.eof and rs.bof) then 
		nr=rs("nr")
		IP=rs("IP")
		adddate=rs("adddate")
		name=rs("name")
		Mail=rs("Mail")
		jibie=rs("jibie")
		view=rs("status")
	end if
	rs.close
	set rs=nothing
%>
   <table width="98%" border="1" cellpadding="3" bordercolor="#333333" style="border-collapse: collapse;">
	<tr class=backs><td colspan=2 class=td height=18>评论信息管理</td></tr>
		 <form name="repl" method="post" action='book2.asp?action=bookok&id=<%=id%>'>
		 <tr><TD align="right" WIDTH=20% height=15>评论人IP地址</TD><td><%=IP%></td></tr>
		 <tr><TD align="right" >评论日期</TD><td><%=adddate%></td></tr>		 
		 <tr><TD align="right" >评论人姓名</TD><td><%=name%></td></tr>
		<tr><TD align="right" >电子邮箱</TD><td><%=Mail%></td></tr>
		<tr><TD align="right" >评 级</TD><td>
<%
for i=1 to clng(jibie)
	response.write "<font color=orange>☆</font>"
next
%> 
		</td></tr>
		 <tr><TD align="right" >评论内容</TD><td><textarea style="overflow:auto" name="nr" cols="60" rows="8"><%=nr%></textarea></td></tr>
		<tr><TD align="right" >是否隐藏</TD><td><input type="radio" name="view" value="0" <%if view="0" then%>checked<%end if%>>
			  隐藏<input type="radio" name="view" value="1" <%if view="1" then%>checked<%end if%>>
			  公开 </td></tr>
			<TR><TD align="right" >&nbsp;<INPUT TYPE="hidden" name=send value=ok></TD><TD>
				<input type="submit" name="action" value=" 提 交 "></TD></TR>
			</form></TABLE>

<%
response.end
end sub
%>

</body>
</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -