rfc1465.txt

中、英文RFC文档大全打包下载完全版 .

                   "591"/NS+39756F11111111010000014560AA00040005E100;
                   MTS-TP-84



Eppenberger                                                    [Page 24]

RFC 1465        Routing Coordination for X.400 Services         May 1993


  Called-address:  DCC+756+x11111111010000014560AA00040005E100
  #
  # For X.400(88) over CLNS
  #
  Calling-address: Int-CLNS/CLNS/TP4;
                   "592"/NS+39756F11111111010000014560AA00040005E100;
                   MTS-T
  Called-address:  DCC+756+x11111111010000014560AA00040005E100
  #
  System: HW=SUN 4/690MP; OS=SunOS 4.1.1; SW=PP-6.0
  #
  LocalDomain: O=switch; OU1=chx400; P=switch; A=arcom; C=ch;
  #
  EchoServer:  S=echo; O=switch; OU1=chx400; P=switch; A=arcom; C=ch;
  #
  Administrator: CN=Felix Kugler, O=SWITCH, C=CH
  Administrator: CN=Christoph Graf, O=SWITCH, C=CH

Appendix A3:  Example of a DOMAIN document

  Community: COSINE-MHS
  #
  Update: FORMAT=V3; DATE=921218; START=930201
  ##
  Domain: *     P=SWITCH; A=ARCOM; C=CH;
  Domain: *     P=SANDOZ; A=ARCOM; C=CH;
  Domain: *        P=ABB; A=ARCOM; C=CH;
  Domain: *        P=UBS; A=ARCOM; C=CH;
  Domain: *      P=ISREC; A=ARCOM; C=CH;
  Domain: *    P=ALCATEL; A=ARCOM; C=CH;
  Domain: *        P=ITU; A=ARCOM; C=CH;
  Domain: * P=OSILABMAIL; A=ARCOM; C=CH;
  Domain: *        P=WHO; A=ARCOM; C=CH;
  Domain: *       P=CERN; A=ARCOM; C=CH;
  Domain: *   P=CERBERUS; A=ARCOM; C=CH;
  #
  Administrator: CN=Christoph Graf, O=SWITCH, C=CH
  Administrator: S=postmaster; O=SWITCH; P=SWITCH; A=ARCOM; C=CH;
  #
  RELAY-MTA: P=SWITCH; A=ARCOM; C=CH; MTAname=chx400.switch.ch; 0
  #
  RELAY-MTA: P=SWITCH; A=ARCOM; C=CH; MTAname=vms.switch; 10

Appendix A4:  Example of a PERSON document

  Community: COSINE-MHS
  #
  Update: FORMAT=V3; DATE=921218; START=930201



Eppenberger                                                    [Page 25]

RFC 1465        Routing Coordination for X.400 Services         May 1993


  #
  Key: CN=Christoph Graf, O=SWITCH, C=CH
  #
  Name:    Christoph Graf
  #
  Address: S=Graf; O=SWITCH; P=SWITCH; A=ARCOM; C=CH;
  RFC822:  [e-mail]
  #
  Phone:   [phone]
  Fax:     [phone]
  #
  Mail:    SWITCH Head Office /
           Christoph Graf /
           Limmatquai 138 /
           CH-8001 Zurich /
           Switzerland
  #
  Reachable: 09:00-12:00; 14:00-17:30; UTC+0100

































Eppenberger                                                    [Page 26]

RFC 1465        Routing Coordination for X.400 Services         May 1993


Appendix B:  BNF Definitions

      <called-connection> ::= "Called-address: " \
                            <Service-type> "; " \
                            <P-address> "; " <MTS> \
                            ["; " <Service-priority>] <CR>

      <calling-connection> ::= "Calling-address: " \
                            <Service-type> "; " \
                            <P-address> <CR>

      <checkpoint-size> ::= "RTS-checkpoint-size: " \
                            'checkpoint size' <CR>

      <COMMUNITY-document> ::= <Community-Identifier> \
                            <Update-info> \
                            <COMMUNITY-document-body>

      <COMMUNITY-document-body> ::= <Coordination> \
                            [{<Macro-definition>}] \
                            {<Connections>}

      <Community-Identifier> ::= "Community: " \
                            ('community name' | <DirectoryName>) <CR>

      <connection-info> ::= <password> <RTS> \
                            {<called-connection><calling-connection>}\
                            [<system>] \
                            [<local-domain>] \
                            [<echo-server>]

      <Connections> ::= {<mandatory-service>} \
                            {[<optional-service>]}

      <contact-info> ::= {"Administrator: " <UniquePersonKey> <CR>}

      <Coordination> ::= <EMail> <Phone> <FAX> \
                            <Mail> <Operation> <File-server>

      <Country-Code> ::= 'Two Character Country Code ISO-3166'

      <dialog-mode> ::= "RTS-dialog-mode: " \
                            ("TWA" | "MONOLOGUE") <CR>

      <DirectoryName> ::= 'Distinguished Name'

      <DOMAIN-document> ::= <Community-Identifier> \
                            <Update-info> \



Eppenberger                                                    [Page 27]

RFC 1465        Routing Coordination for X.400 Services         May 1993


                            <DOMAIN-document-body>

      <DOMAIN-document-body>::= {<Domain-entry>} <responsible> \
                            {<Relay>}

      <Domain-entry> ::= "Domain: " <OR-matching> <MHS-subtree> <CR>

      <echo-server> ::= "EchoServer: " <X.400 address> <CR>

      <EMail> ::= "Address: " <X.400 address> <CR>

      <email-server> ::= "Mail-server: "<X.400 address> <CR>

      <extension> ::= 'local extension'

      <Fax> ::= "Fax: " <tel-no-list> <CR>

      <File-server> ::= <email-server> [{<FTP-server>}] \
                            [{<FTAM-server>]}

      <FTAM-server> ::= "FTAM-server: " <P-address> "; "\
                            'account-name' ["; " 'password'] \
                            ["; X.500 " <DirectoryName>] <CR>

      <FTP-server> ::= "FTP-server: " 'domain name' "; " \
                            'account-name' ["; " 'password'] <CR>

      <int-pref> ::= 'international prefix'

      <local-domain> ::= "LocalDomain: " <MHS-subtree> <CR>

      <Macro-definition> ::= "Macro: " 'Macro name' " " \
                            'Macro value' <CR>

      <Mail> ::= "Mail: " 'postal address information' <CR>

      <mandatory-service> ::= "Mandatory-Service: " \
                            <Service-type> <CR>

      <MHS-subtree> ::= ["O=" 'Organization-name' "; "] \
                            ["OU1="'OrganizationalUnit'"; "\
                            ["OU2=" 'OrganizationalUnit' "; " \
                            ["OU3=" 'OrganizationalUnit' "; " \
                            ["OU4=" 'OrganizationalUnit' "; "]]]] \
                            ["P=" 'PRMDname' "; "] \
                            "A=" 'ADMDname' "; " \
                            "C=" <Country-Code> ";"




Eppenberger                                                    [Page 28]

RFC 1465        Routing Coordination for X.400 Services         May 1993


      <MTS> ::= "MTS-T" | "MTS-TP" | "MTS-TP-84"

      <Name>  ::= "Name: " 'name of person' <CR>

      <national number> ::= 'national telephone number'

      <Network-name> ::= 'Name of a network'

      <Network-service> ::= 'Name of a network service'

      <Operation> ::= "Reachable: "  {<time> "-" <time> "; "} \
                            <Time-zone> <CR>

      <optional-service> ::= "Optional-Service: " \
                            <Service-type> <CR>

      <OR-matching> ::=  ( "* " | "= " )

      <P-address> ::= 'String encoded Presentation Address'

      <password> ::= "Password: " \
                            ("secret" | "none" | \
                            "value=\"" 'password' "\"") <CR>

      <PERSON-document> ::= <Community-Identifier> \
                            <Update-info> \
                            <PERSON-document-identifier> \
                            <PERSON-document-body>

      <PERSON-document-identifier> ::= "Key: " <UniquePersonKey> <CR>

      <PERSON-document-body>::= <Name> {<EMail>} {<RFC822>} \

      <Phone> ::= "Phone: " <tel-no-list> <CR>

      <Relay> ::=         "Relay: " \
                            'UniqueRELAY-MTAkey' "; " \
                            <RELAY-MTA-Priority> <CR>

      <RELAY-MTA-document> ::= <Community-Identifier> \
                            <Update-info> \
                            <RELAY-MTA-document-Identifier> \
                            <RELAY-MTA-document-body>

      <RELAY-MTA-document-body> ::= <Status> <connection-info> \
                            <contact-info>

      <RELAY-MTA-document-Identifier> ::= \



Eppenberger                                                    [Page 29]

RFC 1465        Routing Coordination for X.400 Services         May 1993


                            "RELAY-MTA: " <UniqueRELAY-MTAkey> <CR>

      <RELAY-MTA-Priority> ::= <Integer 0..99>

      <responsible> ::= {"Administrator: " <UniquePersonKey> <CR>}

      <RFC822> ::= "RFC822: " <RFC-822-address> <CR>

      <RTS> ::= <dialog-mode> \
                            [<checkpoint-size> <window-size>]

      <Service-priority> ::= 'Integer 0..99'

      <Service-type> ::= <Network-name> "/" \
                            <Network-service> "/" \
                            <Transport-Protocol>

      <Status> ::= "Status: " ("primary" | "secondary") <CR>

      <system> ::= "System: HW=" 'computer type' "; " \
                            "OS=" 'operating system' "; " \
                            "SW=" 'MHS  software' <CR>

      <tel-no-list> ::= <tel-number> [{"; " <tel-number>}]

      <tel-number> ::=  {"+" <int-pref> " " <national number> \
                            [" x" <extension>]}

      <time> ::= 'hh:mm'

      <Time-zone> ::= ("UTC+" | "UTC-") 'hhmm'

      <Transport-Protocol> ::= 'Name of a transport protocol'

      <UniquePersonKey> ::= (<X.400 address> | <DirectoryName> )

      <UniqueRELAY-MTAkey> ::= (([ "P=" 'PRMDname' "; " ] \
                            ["A=" 'ADMDname' "; " ] \
                            "C=" <Country-Code> "; " \
                            "MTAname=" 'MTAname')
                            | <DirectoryName> )