ordersgrids.vb

来自「wrox出版社的另一套经典的VB2005数据库编程学习书籍,收集了书中源码,郑重」· VB 代码 · 共 56 行

Imports System.Data
Imports System.Web.Services.Protocols

Public Class OrdersGrids
    Private dsOrders As DataSet

    Private Sub btnLoadGrids_Click(ByVal sender As System.Object, _
     ByVal e As System.EventArgs) Handles btnLoadGrids.Click
        With DCOrdersWS1
            .UseDefaultCredentials = True
            .Timeout = 10000 'milliseconds
            dsOrders = .GetTopOrdersAndDetails(CInt(txtTopN.Text))
        End With
        OrdersBindingSource.DataSource = dsOrders
        'Remaining BindingSource properties are correct
    End Sub

    Private Sub bindingNavigatorSaveItem_Click(ByVal sender As System.Object, _
     ByVal e As System.EventArgs) Handles bindingNavigatorSaveItem.Click
        'Send updategram of DataSet updates, if any
        OrdersBindingSource.EndEdit()
        Order_DetailsBindingSource.EndEdit()
        'Completes partial edits (no tab from changed column)
        OrdersDataGridView.EndEdit()
        Order_DetailsDataGridView.EndEdit()
        Dim strMsg As String = Nothing
        If dsOrders.HasChanges Then
            Try
                Dim dsUpdate As DataSet = dsOrders.GetChanges
                Dim intUpdates As Integer
                Dim lngTicks As Long = Now.Ticks
                intUpdates = DcOrdersWS1.UpdateDataSet(dsUpdate)
                If intUpdates > 0 Then
                    lngTicks = Now.Ticks - lngTicks
                    strMsg = "Updated " + intUpdates.ToString + " record(s) in " + _
                      Format(lngTicks / 10000000, "0.000") + " secs." + vbCrLf + vbCrLf + _
                      "Click Load Grids to verify the changes and enable updates."
                Else
                    strMsg = "Updates failed."
                End If
            Catch excSoap As SoapException
                MsgBox(excSoap.Message, MsgBoxStyle.Exclamation, _
                  "SOAP Exception Updating DataSet")
                Return
            Catch excOther As Exception
                MsgBox(excOther.Message, MsgBoxStyle.Exclamation, _
                  "General Exception Updating DataSet")
                Return
            End Try
        Else
            strMsg = "There are no DataSet updates to process."
        End If
        MsgBox(strMsg, MsgBoxStyle.Information, "Updating Base Tables")
    End Sub

End Class