treeview.frm

Javascript异步动态加载目录导航树

VERSION 5.00
Object = "{831FDD16-0C5C-11D2-A9FC-0000F8754DA1}#2.0#0"; "MSCOMCTL.OCX"
Begin VB.Form Demo 
   Caption         =   "TreeView"
   ClientHeight    =   4350
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   6840
   LinkTopic       =   "Form1"
   ScaleHeight     =   4350
   ScaleWidth      =   6840
   StartUpPosition =   3  '窗口缺省
   Begin MSComctlLib.TreeView TVW 
      Height          =   4095
      Left            =   0
      TabIndex        =   0
      Top             =   120
      Width           =   6735
      _ExtentX        =   11880
      _ExtentY        =   7223
      _Version        =   393217
      LineStyle       =   1
      Style           =   7
      Checkboxes      =   -1  'True
      Appearance      =   1
   End
End
Attribute VB_Name = "Demo"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
'Download by http://www.codefans.net
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Private Sub Form_Load()
    ' 初始化控件的内容
    Call InitTreeData
    TVW.Nodes(1).Selected = True    ' 根节点为当前节点
    TVW.Nodes(1).EnsureVisible      ' 根节点可见
End Sub

' 初始化控件的内容
Private Sub InitTreeData()
    Dim i As Integer
    
    ' 增加节点
    TVW.Nodes.Add , , "Root", "Root"
    For i = 1 To 5
        TVW.Nodes.Add "Root", tvwChild, "Child" & CStr(i), "Child1" & CStr(i)
    Next i
    For i = 1 To 5
        TVW.Nodes.Add "Child1", tvwChild, "1GrandChild" & CStr(i), "GrandChild" & CStr(i)
    Next i
    For i = 1 To 5
        TVW.Nodes.Add "Child3", tvwChild, "2GrandChild" & CStr(i), "GrandChild" & CStr(i)
    Next i
    For i = 1 To 5
        TVW.Nodes.Add "Child5", tvwChild, "3GrandChild" & CStr(i), "GrandChild" & CStr(i)
    Next i
    For i = 1 To 5
        TVW.Nodes.Add "1GrandChild1", tvwChild, "GreatGrandChild" & CStr(i), "GreatGrandChild" & CStr(i)
    Next i
    
    ' 将节点展开
    TVW.Nodes(1).Expanded = True
End Sub

' 选取节点
Private Sub TVW_NodeCheck(ByVal Node As MSComctlLib.Node)
     gCheckChildrenBySelf TVW, Node.Index, Node.Checked
     gCheckParentBySibling TVW, Node.Index
End Sub

' 根据自身选取情况，确定全选或取消其下所有子项
Private Sub gCheckChildrenBySelf(TVW As TreeView, ByVal curIndex As Integer, ByVal bCh As Integer)
    Dim n As Integer

    If TVW.Nodes(curIndex).Children <= 0 Then
        Exit Sub
    Else
        n = TVW.Nodes(curIndex).Child.Index
        Do While n <> TVW.Nodes(curIndex).Child.LastSibling.Index
            TVW.Nodes(n).Checked = bCh
            gCheckChildrenBySelf TVW, n, bCh
            n = TVW.Nodes(n).Next.Index
        Loop
        TVW.Nodes(n).Checked = bCh
        gCheckChildrenBySelf TVW, n, bCh
    End If
End Sub

' 根据同层、同父节点的选取情况，确定是否选取其父（乃至更上层），直至根节点
Private Sub gCheckParentBySibling(TVW As TreeView, ByVal curIndex As Integer)
    Dim n As Integer
    Dim bHaveChecked As Boolean

    If TVW.Nodes(curIndex).FirstSibling.Index = 1 Then
        Exit Sub
    Else
        bHaveChecked = False
        n = TVW.Nodes(curIndex).FirstSibling.Index
        Do While n <> TVW.Nodes(curIndex).LastSibling.Index
            If TVW.Nodes(n).Checked = True Then
                bHaveChecked = True
                Exit Do
            End If
            n = TVW.Nodes(n).Next.Index
        Loop
        If TVW.Nodes(n).Checked = True Then
            bHaveChecked = True
        End If
        
        If bHaveChecked = True Then
            TVW.Nodes(curIndex).Parent.Checked = vbChecked
        Else
            TVW.Nodes(curIndex).Parent.Checked = vbUnchecked
        End If
        
        gCheckParentBySibling TVW, TVW.Nodes(curIndex).Parent.Index
    End If
End Sub