sdjs.bas

Gwbasic下的程序源代码

5 REM 6*37钢索双股主索 埋设地锚 加空索道
10 PRINT "DH:地锚深度 m  DA:横杆直径 m  AD:挖坑宽度 m DL挖坑长度 m"
15 PRINT "HD:锚地距出索面的距离 m  DR:土的比重  DC:土的凝聚力 DW:内摩擦力"
20 PRINT "WD:计算抗拔角度"
25 PRINT "DE:DF:横杆内外径 m DN:横杆根数 DB:出索角度"
30 PRINT "L:水平距 m LA:下地锚水平距  LB:上地锚水平距  H:主索高差"
35 PRINT "HA:下锚索顶距地锚高差  HB:上锚索顶距地锚高差  F:主索垂度  FC:后牵引索垂度"
40 PRINT "Q0:吊重 T Q1:小车自重 T Q2:吊钩自重 T Q3: 吊钩与小车间索重 T"
45 PRINT "D:主索直径 mm D1:牵引索直径 mm D2:起重索直径 mm G3:  索夹 T/M T:温差"
50 PRINT "K:主索安全系数  DS:主索钢丝直径MM E0:钢弹性模量  EM: 钢索弹性模量系数"
55 PRINT "JY:钢索强度KG/mm2  J:钢索有效拉力系数 R:索鞍半径 mm R1:小车轮半径 mm"
60 PRINT "R2:轮轴半径 mm U1:轮与轴之间摩察系数  FU:滑轮阻力系数"
70 PRINT "S1:S2:S3:S4:S5: 地面斜线长度 A:索道距吊物间距 m"
80 PRINT "A1:A2:A3:A4:A5:地面水平夹角 N:主索上轮数 N1:小车上起重索经过的轮数"
90 PRINT "N2:吊钩轮数 N3:牵引索转向轮数 G0:主索 T/M G1:牵引索 T/M G2:起重索 T/M"
100 L = 523: LA = .1: LB = .1: H = 270.5: HA = 0: HB = 0: HC = 97: F = 25: FC = 0
110 Q0 = 5: Q1 = .45: Q2 = .15: Q3 = .05: D = 39: D1 = 21.5: D2 = 17.5: G3 = 0: T = 0: W = 57.29578
120 K = 3: DS = 1.8: E0 = 21000: EM = .5: JY = 170: J = .82: R = 300: R1 = 150: R2 = 25: U1 = .08: FU = 1.04
130 S1 = 158: S2 = 121.4: S3 = 240: S4 = 114: S5 = 54
140 A = 4: A1 = 0 / W: A2 = 58.5 / W: A3 = 37 / W: A4 = 56 / W: A5 = 38 / W
150 N = 2: N1 = 3: N2 = 2: N3 = 1: G0 = .35 * D * D / 100000: G1 = .35 * D1 ^ 2 / 100000: G2 = .35 * D2 ^ 2 / 100000
160 DH = 2: DA = .3: AD = 1: DL = 3: HD = 1: DR = 1.8: DC = 5: DW = 18 / W: WD = 30 / W
170 DE = .27: DF = .23: DI = DL / 4: DN = 2: DB = 15 / W
180 L1 = S1 * COS(A1): L2 = S2 * COS(A2): L3 = S3 * COS(A3): L4 = S4 * COS(A4): L5 = S5 * COS(A5)
190 H1 = S1 * SIN(A1): H2 = S2 * SIN(A2): H3 = S3 * SIN(A3): H4 = S4 * SIN(A4): H5 = S5 * SIN(A5)
200 Q = Q0 + Q1 + Q2 + Q3: G = G0 + G1 / 4 + G2 / 3 + G3 / 2000: E = EM * E0
210 B = ATN(H / L): BA = ATN(HA / LA): BB = ATN(HB / LB)
220 LL = L1 + L2 + L3 + L4 + L5: HH = H1 + H2 + H3 + H4 + H5
230 HM = G * L * L / 8 / F / COS(B) + Q / 2 * L / 4 / F: VB = (G * L / COS(B) + Q / 2) / 2 + HM * H / L
240 TB = SQR(VB ^ 2 + HM ^ 2): TP = TB * K / J: DK = INT(D * D * 53 / 1000 * J / 140 * JY / TB * 10) / 10
250 LS = LA / COS(BA) + LB / COS(BB) + L / COS(B): DG = G0 * LS * 2
260 PRINT TAB(0); "L="; L; TAB(15); "H="; H; TAB(30); "F="; F; TAB(40); "Q0="; Q0; TAB(50); 'Q=';Q;TAB(62);"DH=";DH
270 PRINT "B主索斜角="; B * W; TAB(35); "F/L="; F / L
280 PRINT TAB(0); "BA下地锚水平夹角="; BA * W; TAB(35); "BB上锚水平角="; BB * W
290 PRINT TAB(0); "HH主索高差="; HH; TAB(35); "LL主索水平距="; LL
300 PRINT TAB(0); "HM单主索水平力="; HM; TAB(35); "TB单主索拉力="; TB
310 PRINT TAB(0); "TB所需主索破断力="; TB; TAB(35); "K0主索安全倍数="; DK
320 I1 = .1 * (1 + 120 / TB / 1000) / (R1 / 5 - 10) * D ^ 2 / 100: I2 = 1 / (180 * (D / 2 / R1) ^ (2 / 3)) * ATN(F / L * 2) * 2
330 I = I1 * I2: U = U1 * R2 / R1 + .055 / R1: M = .35 * D ^ 2 / TP / 100000
340 H0 = 4 / I / M / K - SQR((4 / (I * M * K)) ^ (2 / 3)) * ATN(F / L * 2) * 2: H1 = 1 / M / K - SQR((1 / M / K) ^ 2 - L * L)
350 S = .37 * D ^ 2: QW = TB * 1000 / S + Q * 500 / N * SQR(E / TB / 1000 / S)
360 KW = JY / QW * J: QZ = TB * 1000 / S + E * DS / R / 2: KY = J * JY / QZ: YB = 1 / (Q / 2 / N / TB)
370 PRINT TAB(0); "LS主索长度="; LS; TAB(35); "DG双股主索重量T="; DG
380 PRINT TAB(0); "KW轮与索间安全系数>=3="; KW; TAB(35); "KY索鞍轮与索安全系数>=2="; KY
390 PRINT TAB(0); "H0自由下滑高差="; H0; TAB(35); "H1控制下滑高差="; H1
400 PRINT "YB轮压应力比>=20="; YB
410 NN = L / LS: GA = G0 / COS(BA): GL = G / COS(B): GB = G0 / COS(BB)
420 GC = GA * LA: GD = GL * L: GE = GB * LB: ES = 12 * 10 ^ (-6) * T * LS
430 J1 = E * NN * S / 10 ^ 3 * (COS(B)) ^ 2 / 24: J2 = 3 * Q / 2 * (Q / 2 + G * L / COS(B)) + (G * L / COS(B)) ^ 2
440 J3 = 0: J4 = GC ^ 2 * LA * (COS(B)) ^ 2 / L / (COS(BA)) ^ 2 + GE ^ 2 * LB * (COS(B)) ^ 2 / L / (COS(BB)) ^ 2
450 X = L / 2
460 C1 = J1 / HM ^ 2 * (J2 + J4) - HM
470 GOSUB 2010
480 P0 = P: F0 = G0 * L ^ 2 / 8 / P0 / (COS(B)) ^ 2
490 J3 = 12 * (Q1 + Q2 + Q3) / 2 * ((Q1 + Q2 + Q3) / 2 + G * L / COS(B))
500 C1 = J1 / HM ^ 2 * (J2 + J4) - HM
510 GOSUB 2010
520 P1 = P: F1 = GD * L / 8 / P1 + (Q1 + Q2 + Q3) / 2 * L / 4 / P1
530 Y0 = GA * L / 2 / COS(B) - P0 * H / L: T0 = SQR(Y0 ^ 2 + PO ^ 2)
540 Y0 = GA * L / 2 / COS(B) + P0 * H / L: TA = SQR(Y0 ^ 2 + P0 ^ 2)
550 V1 = GA * L / 2 / COS(B) - P1 * H / L + (Q1 + Q2 + Q3) / 2: T1 = SQR(V1 ^ 2 + P1 ^ 2)
560 V1 = GA * L / 2 / COS(B) + P1 * H / L + (Q1 + Q2 + Q3) / 2: TC = SQR(V1 ^ 2 + P1 ^ 2)
570 J3 = 12 * Q / 2 * (Q / 2 + GD)
580 GOSUB 2000
590 PA = P: F = GD * L / 8 / P + Q / 2 * L / 4 / P
600 X = L * (1 - .04)
610 GOSUB 2000
620 CR = ATN(TAN(B) + (2 * X - L) / 2 / P * (G / COS(B) + Q / L))
630 IF FC = 0 THEN 660
640 CP = Q * (SIN(CR) + U * COS(CR)) + G1 * L ^ 2 / 8 / FC
650 GOTO 670
660 CP = Q * (SIN(CR) + U * COS(CR))
670 PC = CP * FU ^ (N1 + N2 + N3)
680 D1 = INT(SQR(PC * 5 * 1000 / J * 140 / JY / 53) * 10) / 10
690 J3 = 12 * (Q1 + Q2 + Q3) / 2 * ((Q1 + Q2 + Q3) / 2 + G * L / COS(B))
700 X = .1 * L
710 GOSUB 2000
720 CR = ATN(TAN(B) + (2 * X - L) / 2 / P * (G / COS(B) + (Q1 + Q2 + Q3) / L))
730 CP = (Q1 + Q2) * (SIN(CR) - U * COS(CR))
740 PD = CP * FU ^ (N1 + N2 + N3)
750 PG = Q / FU ^ 2 / (1 / FU + 1 / FU ^ 2 + 1 / FU ^ 3 + 1 / FU ^ 4)
760 D2 = INT(SQR(PG * 6 * 1000 / J * 140 / JY / 53) * 10) / 10
770 PRINT TAB(0); "P0架索时主索拉力="; P0; TAB(35); "F0架索时垂度="; F0
780 PRINT TAB(0); "P1有小车时主索拉力="; P1; TAB(35); "F1有小车时主索垂度="; F1
790 PRINT TAB(0); "TOX架索时主索下拉力="; T0; TAB(35); "TOS架索时主索上拉力="; TA
800 PRINT TAB(0); "T1X有小车时主索下拉力="; T1; TAB(35); "T1S有小车时主索上拉力="; TC
810 PRINT TAB(0); "HM单主索水平拉力="; PA; TAB(35); "F吊重主索垂度="; F
820 PRINT TAB(0); "PCX小车最小下拉力="; PD; TAB(35); "PCS吊重最大牵引力="; PC
830 PRINT TAB(0); "D1牵引索直径="; D1; TAB(35); "D2起重索直径="; D2
840 J3 = 12 * Q / 2 * (Q / 2 + GD)
850 PRINT "地锚距离  吊钩距地面高差  单主索水平拉力  主索垂度   牵引力"
860 FOR X = 0 TO L STEP 20
870 GOSUB 2000
880 F = G / 2 / P / COS(B) * (L - X) * X + Q / P / L * (L - X) * X / 2
890 CR = ATN(TAN(B) + (2 * X - L) / 2 / P * (G / COS(B) + Q / L))
900 IF FC = 0 THEN 930
910 CP = Q * (SIN(CR) + U * COS(CR)) + G1 * L ^ 2 / 8 / FC
920 GOTO 940
930 CP = Q * (SIN(CR) + U * COS(CR))
940 PC = CP * FU ^ (N1 + N2 + N3)
950 IF X > L1 THEN 1000
960 M1 = X * TAN(A1)
970 Y = HC + X * TAN(B) - M1 - F - A - AH
980 PRINT TAB(0); "X="; X; TAB(12); "Y="; Y; TAB(28); "P="; P; TAB(45); "F="; F; TAB(60); "PC="; PC
990 NEXT X
1000 FOR S = X TO L STEP 20
1010 X = S
1020 M1 = L1 * TAN(A1)
1030 IF X > (L1 + L2) THEN 1110
1040 M2 = M1 + (X - L1) * TAN(A2)
1050 GOSUB 2000
1060 GOSUB 2180
1070 Y = HC + X * TAN(B) - M2 - F - A - AH
1080 PRINT TAB(0); "X="; X; TAB(12); "Y="; Y; TAB(28); "P="; P; TAB(45); "F="; F; TAB(60); "PC="; PC
1090 S = X
1100 NEXT S
1110 FOR S = X TO L STEP 20
1120 X = S
1130 IF X > (L1 + L2 + L3) THEN 1220
1140 M2 = L1 * TAN(A1) + L2 * TAN(A2)
1150 M3 = M2 + (X - L1 - L2) * TAN(A3)
1160 GOSUB 2000
1170 GOSUB 2180
1180 Y = HC + X * TAN(B) - M3 - F - A - AH
1190 PRINT TAB(0); "X="; X; TAB(12); "Y="; Y; TAB(28); "P="; P; TAB(45); "F="; F; TAB(60); "PC="; PC
1200 S = X
1210 NEXT S
1220 FOR S = X TO L STEP 20
1230 X = S
1240 IF X > (L1 + L2 + L3 + L4) THEN 1330
1250 M3 = L1 * TAN(A1) + L2 * TAN(A2) + L3 * TAN(A3)
1260 M4 = M3 + (X - L1 - L2 - L3) * TAN(A4)
1270 GOSUB 2000
1280 GOSUB 2180
1290 Y = HC + X * TAN(B) - M4 - F - A - AH
1300 PRINT TAB(0); "X="; X; TAB(12); "Y="; Y; TAB(28); "P="; P; TAB(45); "F="; F; TAB(60); "PC="; PC
1310 S = X
1320 NEXT S
1330 FOR S = X TO L STEP 20
1340 X = S
1350 IF X > (L1 + L2 + L3 + L4 + L5) THEN 1430
1360 M4 = L1 * TAN(A1) + L2 * TAN(A2) + L3 * TAN(A3) + L4 * TAN(A4)
1370 M5 = M4 + (X - L1 - L2 - L3 - L4) * TAN(A5)
1380 GOSUB 2000
1390 GOSUB 2180
1400 Y = HC + X * TAN(B) - M5 - F - A - AH
1410 PRINT TAB(0); "X="; X; TAB(12); "Y="; Y; TAB(28); "P="; P; TAB(45); "F="; F; TAB(60); "PC="; PC
1420 NEXT S
1430 X = L
1440 GOSUB 2000
1450 M5 = L5 * TAN(A5) + L4 * TAN(A4) + L3 * TAN(A3) + L2 * TAN(A2) + L1 * TAN(A1)
1460 F = G / 2 / COS(B) * (L - X) * X + Q / P / L * (L - X) * X / 2
1470 Y = HC + X * TAN(B) - M5 - F - A - AH
1480 PRINT TAB(0); "X="; X; TAB(12); "Y="; Y; TAB(28); "P="; P; TAB(45); "F="; F; TAB(60); "PC="; PC
1490 BB = B
1500 PRINT TAB(0); "BB地锚水平角="; B * W
1510 IF HD = 0 THEN 1660
1520 VQ = 1 / 2.2 * (AD * DH * DL + 1 / 2 * DL * DH ^ 2 * TAN(WD)) * DR / SIN(BB)
1530 HQ = .25 * HD * DH * DL * DR * ((TAN(45 / W + DW / 2)) ^ 2 + 2 * DC * TAN(45 / W + DW / 2)) / COS(BB)
1540 VK = VQ / TB / SIN(BB) / 2
1550 HK = HQ / TB / COS(BB) / 2
1560 PRINT TAB(0); "VQ1地锚铅垂分力="; VQ; TAB(35); "HQ地锚水平分力="; HQ
1570 PRINT TAB(0); "VK1铅垂分力安全系数>=1="; VK; TAB(35); "HK水平安全系数>=1="; HK
1580 QP = .3 * DH * DR * DL * HD * ((TAN(45 / W + DW)) ^ 2 + (TAN(45 / W - DW)) ^ 2) / TB
1590 PRINT "DK1土压应力安全系数>=0.5="; QP
1600 QV = AD * DH * DL * DR / (2 * SIN(BB) - .5 * COS(BB))
1610 KV = QV / TB / SIN(BB) / 2
1620 PRINT TAB(0); "VQ2地锚允许铅垂分力="; QV; TAB(35); "VK2实际安全系数="; KV
1630 QP = .3 * DH * DR * DL * HD * ((TAN(45 / W + DW)) ^ 2 + (TAN(45 / W - DW)) ^ 2) / TB
1640 PRINT "DK2实际土应力安全系数>=0.5="; QP
1650 GOTO 1720
1660 QV = DA * DL * DH / SIN(BB) + (DA + DL) * (DH / SIN(BB) ^ 2 * TAN(WD) + 4 / 3 * (DH / SIN(BB)) ^ 3 * (TAN(WD))) ^ 2
1670 VQ = QV * DR * SIN(BB) / 2.5
1680 VK = VQ / TB / SIN(BB) / 2
1690 PRINT TAB(0); "VQ地锚铅垂分力="; QV; TAB(35); "VK铅垂安全系数>=1="; VK
1700 QP = .3 * DH * DR * DL * HD * (TAN(.785398 + DW)) ^ 2 + (TAN(.785398 - DW)) ^ 2 / VQ
1710 PRINT "DKV土压应力安全系数>=0.5="; QP
1720 IF DB > 0 THEN 1760
1730 QL = VQ / COS(BB) * DL / 8 / (.98 * (DE ^ 3 - DF ^ 3) * DN) + (VQ / COS(BB) / (DE - DF) / 3.14159) / DN
1740 PRINT "QL="; QL
1750 GOTO 1790
1760 QL = TB / COS(BB) * DI ^ 2 / 2 / DL / (.098 * (DE ^ 3 - DF ^ 3) * DN) + VQ / COS(BB) / 2 * TAN(DB) / (DE - DF) / 3.14159 / DN
1780 PRINT "QL地锚横杆应力="; QL
1790 END
2000 C1 = J1 / HM ^ 2 * (J2 + J4) - HM + 24 * J1 / L * ES
2010 C2 = J1 * (J4 + GD ^ 2) + J1 * J3 / L / L * (L - X) * X
2020 P = 10: EZ = .01
2030 CZ = P ^ 3 + C1 * P ^ 2 - C2
2040 Y = P
2050 GOSUB 2100
2060 P = Y - CZ / AZ
2070 IF ABS(Y - P) >= EZ THEN 2030
2080 P = INT(1000 * P + .5) / 1000
2090 RETURN
2100 DZ = 0
2110 FOR N = 9 TO 10
2120 GZ = DZ
2130 P = Y + .5 ^ N
2140 DZ = (P ^ 3 + C1 * P ^ 2 - C2 - CZ) / (P - Y)
2150 NEXT N
2160 AZ = 2 * DZ - GZ
2170 RETURN
2180 F = G / 2 / P / COS(B) * (L - X) * X + Q / P / L * (L - X) * X / 2
2190 CR = ATN(TAN(B) + (2 * X - L) / 2 / P * (G / COS(B) + Q / L))
2200 IF FC = 0 THEN 2100
2210 CP = Q * (SIN(CR) + U * COS(CR)) + G1 * L * L / 8 / FC
2220 GOTO 940
2230 CP = Q * (SIN(CR) + U * COS(CR))
2240 PC = CP * FU ^ (N1 + N2 + N3)
2250 RETURN