userfile.asp

博客模块：Blog是继Email、BBS、ICQ后的第四种网络交流方式

<!--#include file='conn.asp'-->
<!--#include file="user_chkpass.asp"-->
<!--#include file="inc/function.asp"-->
<%

dim tablename,sql,filetype
dim rs,strLine
dim sdate,edate,nurl

nUrl=trim("http://" & Request.ServerVariables("SERVER_NAME"))
nUrl=lcase(nUrl & request.ServerVariables("SCRIPT_NAME"))
nurl=left(nUrl,instrrev(nUrl,"/"))

filetype = lcase(trim(request("filetype")))
sdate=request("selecty")&"-"&request("selectm")&"-"&request("selectd")
edate=request("selectey")&"-"&request("selectem")&"-"&request("selected")
tablename = sdate&"到"&edate&"的日志"

username=ReplaceBadChar(request("username"))
if issqldate then
	sql="select topic,addtime,logtext from blog where username='"&username&"' and addtime<='"&edate&"' and addtime>='"&sdate&"'"
else
	sql="select topic,addtime,logtext from blog where username='"&username&"' and addtime<=#"&edate&"# and addtime>=#"&sdate&"#"
end if
Set rs = Conn.Execute(sql)
if filetype="xml" then
	Response.contenttype="text/xml"
	Response.Charset = "gb2312"
	Response.AddHeader "Content-Disposition", "attachment;filename="&tablename&".xml"
	Response.write "<?xml version=""1.0"" encoding=""gb2312""?>"
	Response.write vbnewline&"<root>"
	strLine=""
	While not rs.EOF
		strLine= vbnewline&chr(9)&"<row>"
		strLine=  strLine & vbnewline&chr(9)&chr(9)&"<log>"
		strLine=  strLine &"<title>"&rs(0)&"</title>"
		strLine=  strLine & "<PubDate>"&rs(1)&"</PubDate>"
		strLine=  strLine &"<![CDATA["& newurl(rs(2),nurl) &"]]>"		
		strLine=  strLine &"</log>"	
		Response.write strLine &vbnewline& chr(9)&"</row>"
		rs.MoveNext
	Wend
	Response.write vbnewline&"</root>"
elseif filetype="txt" then
	Response.contenttype="text"
	Response.AddHeader "Content-Disposition", "attachment;filename="&tablename&".txt"
	While not rs.EOF
		strLine=""
		strLine=strLine & "日志标题："&rs(0) & vbnewline
		strLine=strLine & "发表时间："&rs(1) & vbnewline
		strLine=strLine & "日志内容："&trim(stripHTML(rs(2)))
		Response.write strLine & vbnewline & vbnewline
		rs.MoveNext	
	Wend
else
if filetype="htm" then'弹出下载html的对话框
		Response.contenttype="application/ms-download"
		Response.AddHeader "Content-Disposition", "attachment;filename="&tablename&".htm"
end if
	
	While not rs.EOF
	strLine= ""
	Response.write chr(9)&"<table style='font-size:10pt;TABLE-LAYOUT: fixed; WORD-BREAK: break-all' width='98%'align='center' bgColor=#ffffff border=1 >"& vbnewline
	Response.write chr(9)&"<tr>"& vbnewline
	strLine= strLine&chr(9)&chr(9)&"<td>"
	strLine= strLine&"日志标题："&rs(0)&"<br>"& vbnewline
	strLine= strLine&"发表时间："&rs(1)&"<br>"& vbnewline
	strLine= strLine&newurl(rs(2),nurl) &"</td>"& vbnewline
	Response.write strLine
	Response.write chr(9)&"</tr>"& vbnewline
	Response.write "</table><br>"& vbnewline
	rs.MoveNext
	Wend
end if

rs.close
conn.close
Set rs=nothing
Set conn=nothing 

Function stripHTML(strHTML)

  Dim objRegExp, strOutput
  Set objRegExp = New Regexp

  objRegExp.IgnoreCase = True
  objRegExp.Global = True
  objRegExp.Pattern = "<.+?>"

  strOutput = objRegExp.Replace(strHTML, "")

  strOutput = Replace(strOutput, "<", "<")
  strOutput = Replace(strOutput, ">", ">")
  
  stripHTML = replace(strOutput,"&nbsp;","")

  Set objRegExp = Nothing
End Function


Function newurl(strContent,byval url)           
    dim tempReg
    set tempReg=new RegExp
    tempReg.IgnoreCase=true
    tempReg.Global=true
    tempReg.Pattern="(^.*\/).*$"'含文件名的标准路径
    Url=tempReg.replace(url,"$1")
    tempReg.Pattern="((?:src|href).*?=[\'\u0022](?!ftp|http|https|mailto))"
    newurl=tempReg.replace(strContent,"$1"+Url)
    set tempReg=nothing
end Function
%>