paymentmethodlist.frm

金算盘软件代码

'根据列表中记录数，设置菜单可用属性
Private Sub UpdateMenuStatus()
    Dim blnIsnotEmpty As Boolean
    Dim blnFindNoChange As Boolean
    Dim IsHaveRight As Boolean
    
    IsHaveRight = IsCanDo(24, gclsBase.OperatorID)
    With msgPaymentMethod
         If .Rows > 1 And .ColSel <> 0 And .RowHeight(.Row) > 0 Then
            blnIsnotEmpty = True
         Else
            blnIsnotEmpty = False
         End If
    End With
    With frmMain
        .mnuEditEdit.Caption = "修改(&E)"
        .mnuEditNew.Caption = "新增(&N)"
        .mnuEditDel.Caption = "删除(&D)"
        .mnuEditCopy.Enabled = blnIsnotEmpty
        .mnuEditEdit.Enabled = blnIsnotEmpty And IsHaveRight
        .mnuEditNew.Enabled = True And IsHaveRight
        .mnuEditDel.Enabled = blnIsnotEmpty And IsHaveRight
        .mnuEditInActive.Checked = False
        .mnuEditInActive.Enabled = blnIsnotEmpty And IsHaveRight
        .mnuEditShowAll.Checked = chkShowAll.Value
        .mnuEditShowAll.Enabled = True
        .mnuEditUse.Enabled = blnIsnotEmpty
        .mnuEditSearch.Enabled = True
        .mnuEditColumn.Enabled = True
        .mnuEditFilter.Enabled = True
        .mnuFilePrint.Enabled = True
        .mnuFilePrintSetup.Enabled = True
        .mnuReportQuick.Enabled = blnIsnotEmpty
        .mnuToolRefresh.Enabled = True
    End With
    
    If msgPaymentMethod.ColSel = 0 Then  '无当前选定行
        blnFindNoChange = mclsList.FindNoChange
        mclsList.FindNoChange = True
        txtfind.Text = ""
        mclsList.FindNoChange = blnFindNoChange
        cmdAgain.Enabled = False
    End If
    frmMain.SetToolBar
End Sub

'重画Form
Private Sub RedrawForm()
    '重画MS FlexGrid 控件
    On Error Resume Next
    With msgPaymentMethod
        .Left = ListFormLeft
        .width = Me.ScaleWidth - ListFormLeft - ListFormRight
        .Height = Me.ScaleHeight - ListUpAreaHeight - ListDownAreaHeight
    End With
    
    '重画其余控件
    txtfind.width = Me.ScaleWidth - txtfind.Left - ListFormBottom - cmdAgain.width - 15
    cmdAgain.Left = txtfind.Left + txtfind.width
    cmdPaymentMethod(0).top = Me.ScaleHeight - cmdPaymentMethod(0).Height - ListFormBottom
    cmdPaymentMethod(1).top = cmdPaymentMethod(0).top
    chkShowAll.top = cmdPaymentMethod(0).top
    chkShowAll.Left = Me.ScaleWidth - chkShowAll.width - ListFormBottom
End Sub


Private Sub cmdPaymentMethod_Click(Index As Integer)
    Dim PosX, PosY As Integer
    
    PosX = cmdPaymentMethod(Index).Left
    PosY = cmdPaymentMethod(Index).top + cmdPaymentMethod(Index).Height
    With frmMain
        Select Case Index
               Case 0
                    MakeListEditMenu
                    PopupMenu .mnuListEdit, , PosX, PosY
               Case 1
                    MakeListReportMenu
                    PopupMenu .mnuListReport, , PosX, PosY
        End Select
    End With
End Sub

'
'窗体 Form 控件
'
Private Sub Form_Load()
    Dim i As Integer
    Dim intSortCol As Integer
    On Error GoTo ErrHandle
'    Me.Hide
'    Me.Left = -30000
    MsgForm.PleaseWait
    Me.HelpContextID = 30040
    '付款方式列表窗体初始化
    Debug.Print "start load form time:", Timer
    Set mclsList = New list
    mclsList.FlexNoChange = True
    mclsList.FindNoChange = True
    Set mclsList.FlexGrid = msgPaymentMethod
    Set mclsList.FindKind = cboFindKind
    Set mclsList.Find = txtfind
    Set mclsList.Again = cmdAgain
    mclsList.ListSet.ViewId = intViewID
    mclsList.InitFlexGrid
    
    '得到付款方式列表记录集
    Set datPaymentMethod.Recordset = GetList()
    If Not datPaymentMethod.Recordset.EOF Then
       datPaymentMethod.Recordset.MoveLast
    End If
    datPaymentMethod.Recordset.Close
   ' Set datPaymentMethod.Recordset = Nothing
    mclsList.SetFlexGrid
    
    '初始化查找复合列表框
    mclsList.InitcboFindKind
    mclsList.FlexNoChange = False
    mclsList.FindNoChange = False
    
    '设置第一行为选定行
    With msgPaymentMethod
        If .Rows > 1 Then .Row = 1
        .col = 0
        .ColSel = .Cols - 1
    End With
    chkShowAll.Value = 0
    mclsList.DoShowAll False
    UpdateMenuStatus
   
    '设置钩子对象
    Set mclsSubClass = New SubClass32.SubClass
    mclsSubClass.hwnd = msgPaymentMethod.hwnd
    mclsSubClass.Messages(WM_PAINT) = True
    mclsSubClass.Messages(WM_LBUTTONUP) = True
    mclsSubClass.Messages(WM_LBUTTONDOWN) = True
    mclsSubClass.Messages(WM_MOUSEMOVE) = True
    
    Set mclsSubClassform = New SubClass32.SubClass
    mclsSubClassform.hwnd = Me.hwnd
    mclsSubClassform.Messages(WM_GETMINMAXINFO) = True
    Debug.Print "last end form time:", Timer
    Unload MsgForm
    Set mclsMainControl = gclsSys.MainControls.Add(Me)
     Exit Sub
    
'错误处理
ErrHandle:
    Dim edtErrReturn As ErrDealType
    edtErrReturn = Errors.ErrorsDeal
    If edtErrReturn = edtResume Then
         Resume
    Else
         On Error Resume Next
         Unload MsgForm
         Unload Me
    End If
End Sub

'右键菜单
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, y As Single)
    If Button = vbRightButton And frmMain.ActiveForm Is Me Then
        MakeListEditMenu
        PopupMenu frmMain.mnuListEdit
    End If
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    If UnloadMode = vbFormControlMenu And mIsShowCard Then
        MsgBox "请先关闭付款方式卡片！", vbExclamation
        Cancel = True
'        frmPaymentMethodListCard.Show
'        frmPaymentMethodListCard.ZOrder 0
    End If
End Sub

Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
'    If mIsShowCard Then Unload frmPaymentMethodListCard
    mclsList.SaveListSet
    Set mclsSubClass = Nothing
    Set mclsSubClassform = Nothing
    Set mclsList = Nothing
    gclsSys.MainControls.Remove Me
    Set mclsMainControl = Nothing
End Sub

Private Sub Form_Resize()
'    If mblnFormNoRezise Then Exit Sub
    On Error Resume Next
    If Me.WindowState = 1 Then Exit Sub
    If Me.Left + Me.width < 0 Or Me.Left > Screen.width Then
       Me.Left = 300
    End If
'    If Me.Height < intFormHeight Then Me.Height = intFormHeight
'    If Me.Width < intFormWidth Then Me.Width = intFormWidth
    RedrawForm
End Sub

Private Sub Form_KeyPress(KeyAscii As Integer)
    If KeyAscii = vbKeyEscape Then
        Unload Me
    End If
End Sub

Private Sub Form_Activate()
    mclsMainControl_ChildActive  '响应消息
    gclsSys.CurrFormName = Me.hwnd
    'msgPaymentMethod.SetFocus
    msgPaymentMethod.Redraw = True
    UpdateMenuStatus
    'If (Me.Left + Me.Width < 0 Or Me.Left > Screen.Width) Then Me.Left = 300
    If Me.WindowState = 1 Then Me.WindowState = 0
End Sub

'
'显示全部记录/未停用记录 CheckBox 控件
'
Private Sub chkShowAll_Click()
    msgPaymentMethod.Redraw = False
    mclsList.DoShowAll chkShowAll.Value
    'cboFindKind_Click
    UpdateMenuStatus
    msgPaymentMethod.Redraw = True
End Sub

'
'查找条件类型 ComboBox 控件
'
Private Sub cboFindKind_Click()
    Dim i As Integer
    Dim strFind As String
    mclsList.ReGetColCaption
    With msgPaymentMethod
        .Redraw = False
        For i = 1 To .Cols - 1
            If .TextMatrix(0, i) = cboFindKind.Text Then
                If .RowHeight(.Row) > 0 Then strFind = .TextMatrix(.Row, i)
                mclsList.FixrowSortBold i
                Exit For
            End If
       Next
    End With
       
    '恢复以前选定行
    If msgPaymentMethod.Rows > 1 Then
        If txtfind.Text = strFind Then
            txtFind_Change
        Else
            txtfind.Text = strFind
        End If
    End If
    msgPaymentMethod.Redraw = True
End Sub

'响应消息
Private Sub mclsMainControl_ChildActive()
    Dim vntMessage As Variant
    gclsSys.CurrFormName = Me.hwnd
    For Each vntMessage In mclsMainControl.Messages
        If vntMessage = Message.msgPaymentMethod Then '接收到付款方式改变消息
            mclsMainControl_ToolRefresh
            mclsMainControl.Messages.Remove CStr(vntMessage) '清除付款方式改变消息
        End If
    Next
    mclsMainControl.Messages.Clear
    UpdateMenuStatus
  Debug.Print "do the childactive"
End Sub

Private Sub mclsMainControl_EditColumn()
    Dim strFind As String
    Dim strSort As String
    Dim intCount As Integer
    
    With msgPaymentMethod
        strFind = .TextMatrix(.Row, mclsList.SortCol)
        strSort = cboFindKind.Text
        If mclsList.ListSet.ShowListSet(intViewID) Then
            .Redraw = False
            msgPaymentMethod.Cols = 0
            Set datPaymentMethod.Recordset = GetList()
            If Not datPaymentMethod.Recordset.EOF Then
               datPaymentMethod.Recordset.MoveLast
            End If
            datPaymentMethod.Recordset.Close
           ' Set datPaymentMethod.Recordset = Nothing
            mclsList.SetFlexGrid
            UpdateMenuStatus
            
            '初始化查找复合列表框
            mclsList.InitcboFindKind
            For intCount = 0 To cboFindKind.ListCount - 1
                If cboFindKind.list(intCount) = strSort Then
                    txtfind.Text = strFind
                    Exit For
                End If
            Next intCount
            If chkShowAll.Value = 0 Then mclsList.DoShowAll False
            .Redraw = True
        End If
    End With
End Sub

Private Sub mclsMainControl_EditFilter()
    Dim blnFlage As Boolean
    
    If Not mblnIsSaveListset Then
        If Not FindlngViewID(intViewID) Then mclsList.ListSet.SaveList
        mblnIsSaveListset = True
    End If
    Filter.ShowFilter mclsList.ListSet.ListID, 1, , , , , blnFlage
    If Not blnFlage Then Exit Sub
    mclsList.SaveListSet
    mclsList.ListSet.ViewId = intViewID
    msgPaymentMethod.Cols = 0
    Set datPaymentMethod.Recordset = GetList()
    If Not datPaymentMethod.Recordset.EOF Then
       datPaymentMethod.Recordset.MoveLast
    End If
    datPaymentMethod.Recordset.Close
    'Set datPaymentMethod.Recordset = Nothing
    mclsList.SetFlexGrid
    UpdateMenuStatus
    
    '初始化查找复合列表框
    mclsList.InitcboFindKind
    If chkShowAll.Value = 0 Then mclsList.DoShowAll 0
End Sub

'打印设置
Private Sub mclsMainControl_FilePrintSetup()
    Dim MyPrintSet As PrintClass
    Set MyPrintSet = New PrintClass
    MyPrintSet.PrintSetUp gclsBase.BaseDB, mclsList.FlexGrid, , , , 31, " " & Chr(1) & gclsBase.BaseName & Chr(1) & gclsBase.OperatorName
    Set MyPrintSet = Nothing
End Sub

Private Sub mclsMainControl_ListReportMenu(ByVal intIndex As Integer)
'    If intIndex = 0 Then
'       mclsMainControl_ReportQuick
'    Else
      ' mclsMainControl_ListPaymentMethod
      Report.ShowListReport 85, 139
   ' End If
    
End Sub