frmdefinecard.frm

金算盘软件代码

    End If
    
    intResult = CodeCheck(mstrTableName, "strCustomCode", "lngCustomID", _
        mblnIsNew, txtInput(0).Text, txtInput(1).Text, mstrLastCode, _
        mstrOldFullName, mstrFullName, mlngPCodeID, mblnPIsDetail, mblnPIsInActive, _
        mblnIsDetail)
    If intResult = -1 Then
        If mblnIsNew Then
            If Not blnByAdd Then
                ShowMsg hwnd, "“" & Trim$(txtInput(0).Text) & "“的上级自定项目" _
                    & "不存在,请先增加上级自定项目”" & CodePrefix(txtInput(0).Text) _
                        & "“", vbExclamation, Caption
            End If
        Else
            ShowMsg hwnd, "“" & Trim$(txtInput(0).Text) & "“的上级自定项目" _
                & "不存在,请重新修改自定项目”" _
                & Trim$(txtInput(0).Text) & "“", vbExclamation, Caption
        End If
        txtInput(0).SetFocus
        GoTo ErrHandle
    ElseIf intResult = -2 Then
        If mblnIsNew Then
            If Not blnByAdd Then
                ShowMsg hwnd, "自定项目编码“" & Trim$(txtInput(0).Text) _
                    & "”已经存在,请重新录入自定项目编码", vbExclamation, Caption
                txtInput(0).SetFocus
            End If
            GoTo ErrHandle
        Else
            If Not mblnPIsDetail Or (mblnIsInActive <> mblnPIsInActive) Or Not mblnIsDetail Then
                ShowMsg hwnd, "自定项目“" & mstrLastCode & "”与自定项目“" _
                    & Trim$(txtInput(0).Text) & "”不能合并,请重新修改自定项目编码“" _
                    & Trim$(txtInput(0).Text) & "“", vbExclamation, Caption
                mlngPCodeID = 0
                txtInput(0).SetFocus
                GoTo ErrHandle
            Else
                If ShowMsg(hwnd, "是否将自定项目“" & mstrLastCode & "”与“" _
                    & Trim$(txtInput(0).Text) & "”进行合并?", vbQuestion + vbYesNo, _
                     Caption) = vbNo Then
                    txtInput(0).SetFocus
                    GoTo ErrHandle
                Else
                    blnMerge = True
                End If
            End If
        End If
    ElseIf intResult = -3 Then
        If Not blnByAdd Then
            ShowMsg hwnd, "自定项目编码太长,请重新修改编码!", vbExclamation, Caption
            txtInput(0).SetFocus
        End If
        GoTo ErrHandle
    Else
        If mblnIsNew And mblnPIsDetail Then
            If CodeIsUsed(mlngPCodeID) Then
                If Not blnByAdd Then
                    If ShowMsg(hwnd, "自定项目“" & CodePrefix(txtInput(0).Text) & "”是一个已经发生业务的末级自定项目," _
                        & "是否在该自定项目下新增明细自定项目“" & Trim$(txtInput(0).Text) & "”," _
                        & "并将发生的所有业务转到新增的明细自定项目?", vbQuestion + vbYesNo, _
                        Caption) = vbNo Then
                        txtInput(0).SetFocus
                        GoTo ErrHandle
                    Else
                        blnMerge = True
                    End If
                Else
                    blnMerge = True
                End If
            End If
        End If
    End If
    
'    If CheckSameName(mstrTableName, "strCustomCode", txtInput(0).Text, _
'        "strCustomName", txtInput(1).Text, "lngCustomID", _
'        IIf(mblnIsNew, 0, mlngCustomID)) Then
'        If Not blnByAdd Then
'            ShowMsg hWnd, "已有同级自定项目使用了" & "“" & txtInput(1).Text & "“" & _
'                ",请重新录入自定项目名称!", vbExclamation, Caption
'            txtInput(1).SetFocus
'        End If
'        recCustom.Close
'        GoTo ErrHandle
'    End If
    mstrCode = Trim(txtInput(0).Text)
    mstrName = Trim(txtInput(1).Text)
    mblnIsInActive = (chkStop.Value = vbChecked)
    mblnIsDetail = True
    mstrStartDate = Format(gclsBase.BaseDate, "YYYY-MM-DD")
    mintLevel = stringCount(Trim(txtInput(0).Text), "-") + 1
    If mblnIsNew Then
        If mblnPIsDetail Then
            If blnMerge Then    '上级编码是已使用的末级编码,合并业务
                If Not TransActivity(mlngPCodeID) Then GoTo ErrHandle
            Else
                strSql = "UPDATE " & mstrTableName & " SET blnIsDetail=0 WHERE " _
                    & "lngCustomID=" & mlngPCodeID
                If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
            End If
        End If
        If Not mblnIsInActive And mblnPIsInActive And mlngPCodeID <> 0 Then
            If Not blnByAdd Then
                If ShowMsg(hwnd, "上级自定义项目已经被停用,是否启用上级自定义项目？", _
                    vbQuestion + vbYesNo, Caption) = vbNo Then
                    mblnIsInActive = True
                     strSql = "UPDATE " & mstrTableName & " SET blnIsInActive=1 WHERE " _
                        & "lngCustomID=" & mlngPCodeID
                    If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
                Else
                    mblnIsInActive = False
                End If
            Else
                mblnIsInActive = False
            End If
        End If
        mlngCustomID = GetNewID(mstrTableName)
        strSql = "INSERT INTO " & mstrTableName & "(lngCustomID,strCustomCode,strCustomName," _
            & "strFullName,blnIsInActive,intLevel,blnIsDetail," _
            & "strStartDate) VALUES(" & mlngCustomID & ",'" & mstrCode & "','" & mstrName _
            & "','" & mstrFullName & "'," & IIf(mblnIsInActive, 1, 0) & "," _
            & mintLevel & "," & IIf(mblnIsDetail, 1, 0) & ",'" & mstrStartDate & "')" '插入数据库
        gclsBase.BaseDB.Execute strSql
        If blnMerge Then mlngCustomID = mlngPCodeID
'        If Not mblnIsInActive Then
'            strSql = "SELECT * FROM " & mstrTableName & " WHERE strCustomCode='" & Trim(txtInput(0).Text) & "'"
'            Set recCustom = gclsBase.BaseDB.OpenResultset(strSql, rdOpenStatic)
'            mlngCustomID = recCustom!lngCustomID
'            recCustom.Close
'        End If
    Else
        '进行编码合并
        If blnMerge Then
            If Not MergeCode Then GoTo ErrHandle
            strSql = "DELETE FROM " & mstrTableName & " WHERE lngCustomID=" & mlngCustomID
            If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
        Else
            strSql = "UPDATE " & mstrTableName & " SET strCustomCode='" & mstrCode _
                & "',strCustomName='" & mstrName & "',strFullName='" & mstrFullName _
                & "',blnIsInActive=" & IIf(mblnIsInActive, 1, 0) & ",intLevel =" & mintLevel _
                & " WHERE lngCustomID=" & mlngCustomID
            gclsBase.BaseDB.Execute strSql
            If Not ChangeLowerCardCodeAndFullName(mstrTableName, "strCustomCode", _
                "strFullName", "lngCustomID", mstrLastCode, mstrOldFullName, mstrCode, _
                mstrFullName, mintOldLevel, mintLevel) Then GoTo ErrHandle
'            If Not ChangeLowerCardCodeAndFullName("Custom", "strCustomCode", _
                "strFullName", mstrLastCode, mstrLastName, mstrCode, mstrName, "lngCustomID") _
                    Then GoTo ErrHandle
            If mblnIsInActive Then      '本级停用时改变下级的停用属性
                If Not ChangeLowerActive(mstrTableName, "strCustomCode", mstrCode) _
                    Then GoTo ErrHandle
            End If
            If mblnPIsDetail Then
                strSql = "UPDATE " & mstrTableName & " SET blnIsDetail=0 WHERE lngCustomID=" _
                    & mlngPCodeID
                If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
            End If
        End If
        If Not ChangeHigherCardDetail(mstrTableName, "strCustomCode", mstrLastCode) Then GoTo ErrHandle
    End If
    If Not mblnIsInActive And mblnPIsInActive Then  '本级是活动时改变上级的停用属性
        If Not ChangeHigherActive(mstrTableName, "strCustomCode", mstrCode) _
            Then GoTo ErrHandle
    End If
    gclsBase.BaseWorkSpace.CommitTrans
    SaveCard = True
    mblnIsChanged = False
    Select Case CInt(mintCustomIndex)
        Case 0
            gclsSys.SendMessage CStr(Me.hwnd), Message.msgCustom1
        Case 1
            gclsSys.SendMessage CStr(Me.hwnd), Message.msgCustom2
        Case 2
            gclsSys.SendMessage CStr(Me.hwnd), Message.msgCustom3
        Case 3
            gclsSys.SendMessage CStr(Me.hwnd), Message.msgCustom4
        Case 4
            gclsSys.SendMessage CStr(Me.hwnd), Message.msgCustom5
        Case 5
            gclsSys.SendMessage CStr(Me.hwnd), Message.msgCustom6
    End Select
    Exit Function
ErrHandle:
    gclsBase.BaseWorkSpace.RollBacktrans
    If InStr(Err.Description, "违反唯一约束条件") > 0 Then
        If Not blnByAdd Then
            ShowMsg hwnd, "已有同级自定项目使用了" & "“" & txtInput(1).Text & "“" & _
                ",请重新录入自定项目名称!", vbExclamation, Caption
            txtInput(1).SetFocus
        End If
    End If
End Function

'查找自定项目表表名
Private Function SelectTable(strTitleName As String) As Boolean
    Dim strSql As String
    Dim recSelect As rdoResultset
    
    strSql = "SELECT strKey FROM Setting WHERE lngModuleID=8 AND strSetting='" _
              & strTitleName & "'"
    Set recSelect = gclsBase.BaseDB.OpenResultset(strSql, rdOpenStatic)
    If Not recSelect.EOF Then
        mintCustomIndex = Mid(recSelect!strKey, 5, 1)
        mstrTableName = "Custom" & mintCustomIndex
        SelectTable = True
    Else
        SelectTable = False
    End If
    recSelect.Close
End Function

Private Sub txtInput_Change(Index As Integer)
    Dim strErr As String
    
    If Index = 0 Then
        strErr = "'""|?`~!^*"
    Else
        strErr = "'""|?`~-!^*"
    End If
    If ContainErrorChar(txtInput(Index).Text, strErr) Then
        BKKEY txtInput(Index).hwnd
    End If
    If Not mblnIsInit Then mblnIsChanged = True
End Sub

Private Function TransActivity(ByVal lngPID As Long) As Boolean
    Dim intLevel As Integer
    Dim recCustom As rdoResultset
    Dim strSql As String, strFullName As String, strNotes As String
    
    strSql = "SELECT * FROM " & mstrTableName & " WHERE lngCustomID=" & lngPID
    Set recCustom = gclsBase.BaseDB.OpenResultset(strSql, rdOpenStatic)
    With recCustom
    mblnIsDetail = False
'    mblnIsInActive = !blnIsInActive
    mintLevel = !intLevel
    mstrStartDate = !strStartDate
    mstrCode = !strCustomCode
    mstrName = !strCustomName
    strFullName = !strFullName
    strNotes = !strNotes
    End With
    recCustom.Close
    
    intLevel = stringCount(Trim(txtInput(0).Text), "-") + 1
    strSql = "UPDATE " & mstrTableName & " SET strCustomCode='" & Trim(txtInput(0).Text) _
        & "',strCustomName='" & Trim(txtInput(1).Text) & "',strFullName='" & mstrFullName _
        & "',blnIsInActive=" & (chkStop.Value = vbChecked) & ",intLevel =" & intLevel _
        & ",strNotes='" & mstrNotes & "',strStartDate='" _
        & Format(Date, "YYYY-MM-DD") & "' WHERE lngCustomID=" & lngPID
    TransActivity = gclsBase.ExecSQL(strSql)
    If TransActivity Then
        mstrFullName = strFullName
        mstrNotes = strNotes
    End If
End Function

Private Sub txtInput_KeyPress(Index As Integer, KeyAscii As Integer)
    If Index = 0 Then
        If InStr("'""|?`~!^*", Chr(KeyAscii)) > 0 Then KeyAscii = 0
    Else
        If InStr("'""|?`~-!^*", Chr(KeyAscii)) > 0 Then KeyAscii = 0
    End If
End Sub