frmitemtypelistcard.frm

金算盘软件代码

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    Dim intMsgReturn As Integer, strMess As String
    
    If UnloadMode <> vbFormControlMenu Then Exit Sub
    If Trim(txtInput(0).Text & txtInput(1).Text) = "" Then Exit Sub
    If mblnIsChanged Then
        If mblnIsNew Then
            strMess = "您要保存新增的商品类型"
            If txtInput(0).Text <> "" Then
                strMess = strMess & "“" & txtInput(0).Text & "”"
            End If
            If txtInput(1).Text <> "" Then
                strMess = strMess & "“" & txtInput(1).Text & "”"
            End If
            strMess = strMess & "吗？"
        Else
            strMess = "“" & txtInput(0).Text & "”" & " " _
                & "“" & txtInput(1).Text & "”商品类型已被修改，是否保存？"
        End If
        intMsgReturn = ShowMsg(hwnd, strMess, vbQuestion + vbYesNoCancel, Caption)
        If intMsgReturn = vbYes Then
            Cancel = Not SaveCard
        ElseIf intMsgReturn = vbCancel Then
            Cancel = True
        End If
    End If
End Sub

Private Sub Form_Unload(Cancel As Integer)
    frmItemList.IsShowCard(0) = False
    mblnIsChanged = False
    gclsSys.MainControls.Remove Me
    Set mclsMainControl = Nothing
End Sub

Private Sub Form_Paint()
    FrameBox Me.hwnd, 120, 120, 3735, 2055
End Sub

Private Sub cmdokcancel_Click(Index As Integer)
    Dim strNextCode As String
    
    Select Case Index
        Case 0   '确定
            If SaveCard Then Unload Me
        Case 1   '取消
            Unload Me
        Case 2   '下一个
            If SaveCard Then
                strNextCode = GetNextCode(txtInput(0).Text)
'                mlngItemTypeID = 0
                InitCard
                txtInput(0).Text = strNextCode
                txtInput(0).SetFocus
                txtInput(0).SelStart = 0
                txtInput(0).SelLength = Len(txtInput(0).Text)
            End If
    End Select
End Sub

Private Function MergeCode() As Boolean
    MergeCode = DisplaceActivity("Item", "lngItemTypeID", mlngPCodeID, mlngItemTypeID)
End Function

Private Function SaveCard() As Boolean
    Dim blnMerge As Boolean     'NEW--转移业务  EDIT--合并代码
    Dim intResult As Integer    '编码检查结果:1--合法 -1--上级编码不存在 -2--编码已存在 -3--编码超长
    Dim recItemType As rdoResultset, strSql As String
    Dim intIsDetail As Integer, intIsInActive As Integer
    
    On Error GoTo ErrHandle
    
    SaveCard = False
    
    gclsBase.BaseWorkSpace.BeginTrans
    
    If Trim$(txtInput(0).Text) = "" Then
        ShowMsg hwnd, "商品类型编码不能为空!", vbExclamation, Caption
        txtInput(0).SetFocus
        GoTo ErrHandle
    End If
    
    If InStr(1, txtInput(0).Text, mstrOldCode & "-") <> 0 And Not mblnIsNew Then
        ShowMsg hwnd, "商品类型不能修改为自己的下级商品类型!", vbExclamation, Caption
        txtInput(0).SetFocus
        GoTo ErrHandle
    End If
    If InStr(1, mstrOldCode, txtInput(0).Text & "-") <> 0 And Not mblnIsNew Then
        ShowMsg hwnd, "商品类型不能修改为自己的上级商品类型!", vbExclamation, Caption
        txtInput(0).SetFocus
        GoTo ErrHandle
    End If
    If Trim$(txtInput(1).Text) = "" Then
        ShowMsg hwnd, "商品类型名称不能为空!", vbExclamation, Caption
        txtInput(1).SetFocus
        GoTo ErrHandle
    End If
    
    intResult = CodeCheck("ItemType", "strItemTypeCode", "lngItemTypeID", _
        mblnIsNew, txtInput(0).Text, txtInput(1).Text, mstrOldCode, _
        mstrOldFullName, mstrFullName, mlngPCodeID, mblnPIsDetail, mblnPIsInActive, _
        mblnIsDetail)
    If intResult = -1 Then
        If mblnIsNew Then
            ShowMsg hwnd, "“" & Trim$(txtInput(0).Text) & "“的上级商品类型" _
                & "不存在,请先增加上级商品类型”" & CodePrefix(txtInput(0).Text) & "“", vbExclamation, Caption
        Else
            ShowMsg hwnd, "“" & Trim$(txtInput(0).Text) & "“的上级商品类型" _
                & "不存在,请重新修改商品类型”" _
                & Trim$(txtInput(0).Text) & "“", vbExclamation, Caption
        End If
        txtInput(0).SetFocus
        GoTo ErrHandle
    ElseIf intResult = -2 Then
        If mblnIsNew Then
            ShowMsg hwnd, "商品类型编码“" & Trim$(txtInput(0).Text) _
                & "”已经存在,请重新录入商品类型编码", vbExclamation, Caption
            txtInput(0).SetFocus
            GoTo ErrHandle
        Else
            If Not mblnPIsDetail Or (mblnIsInActive <> mblnPIsInActive) Or Not mblnIsDetail Then
                ShowMsg hwnd, "商品类型“" & mstrOldCode & "”与商品类型“" _
                    & Trim$(txtInput(0).Text) & "”不能合并,请重新修改商品类型编码“" _
                    & Trim$(txtInput(0).Text) & "“", vbExclamation, Caption
                txtInput(0).SetFocus
                GoTo ErrHandle
            Else
                If ShowMsg(hwnd, "是否将商品类型“" & mstrOldCode & "”与“" _
                    & Trim$(txtInput(0).Text) & "”进行合并?", vbQuestion + vbYesNo, _
                     Caption) = vbNo Then
                    txtInput(0).SetFocus
                    GoTo ErrHandle
                Else
                    blnMerge = True
                End If
            End If
        End If
    ElseIf intResult = -3 Then
        ShowMsg hwnd, "商品类型编码太长,请重新修改编码!", vbExclamation, Caption
        txtInput(0).SetFocus
        GoTo ErrHandle
    Else
        If mblnIsNew And mblnPIsDetail Then
            If CodeUsed(mlngPCodeID) Then
                If ShowMsg(hwnd, "商品类型“" & CodePrefix(txtInput(0).Text) & "”是一个已经发生业务的末级商品类型," _
                    & "是否在该商品类型下新增明细商品类型“" & Trim$(txtInput(0).Text) & "”," _
                    & "并将发生的所有业务转到新增的明细商品类型?", vbQuestion + vbYesNo, _
                    Caption) = vbNo Then
                    txtInput(0).SetFocus
                    GoTo ErrHandle
                Else
                    blnMerge = True
                End If
            End If
        End If
    End If
    
    If CheckSameName("ItemType", "strItemTypeCode", txtInput(0).Text, _
        "strItemTypeName", txtInput(1).Text, "lngItemTypeID", _
        IIf(mblnIsNew, 0, mlngItemTypeID)) Then
        ShowMsg hwnd, "已有同级商品类型使用了" & "“" & txtInput(1).Text & "“" & _
            ",请重新录入商品类型名称!", _
            vbExclamation, Caption
        txtInput(1).SetFocus
        recItemType.Close
        GoTo ErrHandle
    End If
    mstrCode = txtInput(0).Text
    mstrName = txtInput(1).Text
    mblnIsInActive = (chkPause.Value = vbChecked)
    mblnIsDetail = True
    mstrStartDate = Format(gclsBase.BaseDate, "YYYY-MM-DD")
    mintLevel = stringCount(Trim(txtInput(0).Text), "-") + 1
    If mblnIsNew Then
        If mblnPIsDetail Then
            If blnMerge Then    '上级编码是已使用的末级编码,合并业务
                If Not TransActivity(mlngPCodeID) Then GoTo ErrHandle
            Else
                strSql = "UPDATE ItemType SET blnIsDetail=0 WHERE " _
                    & "lngItemTypeID=" & mlngPCodeID
                If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
            End If
        End If
        If Not mblnIsInActive And mblnPIsInActive And mlngPCodeID <> 0 Then
            If ShowMsg(hwnd, "上级商品类型已经被停用,是否启用上级商品类型？", _
                vbQuestion + vbYesNo, Caption) = vbNo Then
                mblnIsInActive = True
                 strSql = "UPDATE ItemType SET blnIsInActive=True WHERE " _
                    & "lngItemTypeID=" & mlngPCodeID
                If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
            Else
                mblnIsInActive = False
            End If
        End If
        mlngItemTypeID = GetNewID("Itemtype")
        intIsDetail = IIf(mblnIsDetail, 1, 0)
        intIsInActive = IIf(mblnIsInActive, 1, 0)
        strSql = "INSERT INTO ItemType(lngItemtypeID,strItemTypeCode,strItemTypeName," _
            & "strFullName,blnIsInActive,intLevel,blnIsDetail," _
            & "strStartDate) VALUES (" & mlngItemTypeID & ",'" & mstrCode & "','" _
            & mstrName & "','" & mstrFullName & "'," & intIsInActive & "," _
            & mintLevel & "," & intIsDetail & ",'" & mstrStartDate & "')"   '插入数据库
        If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
'        Strsql = "SELECT * FROM ItemType WHERE strItemTypeCode='" & txtInput(0).Text & "'"
'        Set recItemType = gclsBase.BaseDB.OpenResultset(Strsql, rdOpenForwardOnly)
'        mlngItemTypeID = recItemType!lngItemTypeID
'        recItemType.Close
    Else
        '进行编码合并
        If blnMerge Then
            If Not MergeCode Then GoTo ErrHandle
            strSql = "DELETE FROM ItemType WHERE lngItemTypeID=" & mlngItemTypeID
            If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
        Else
            intIsInActive = IIf(mblnIsInActive, 1, 0)
            strSql = "UPDATE ItemType SET strItemTypeCode='" & mstrCode _
                & "',strItemTypeName='" & mstrName & "',strFullName='" & mstrFullName _
                & "',blnIsInActive=" & intIsInActive & ",intLevel =" & mintLevel _
                & " WHERE lngItemTypeID=" & mlngItemTypeID
            If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
            If Not ChangeLowerCardCodeAndFullName("ItemType", "strItemTypeCode", _
                "strFullName", "lngItemTypeID", mstrOldCode, mstrOldFullName, mstrCode, _
                mstrFullName, mintOldLevel, mintLevel) Then GoTo ErrHandle
'            If Not ChangeLowerCardCodeAndFullName("ItemType", "strItemTypeCode", _
                "strFullName", mstrOldCode, mstrOldName, mstrCode, mstrName, "lngItemTypeID") _
                    Then GoTo ErrHandle
            If mblnIsInActive Then      '本级停用时改变下级的停用属性
                If Not ChangeLowerActive("ItemType", "strItemTypeCode", mstrCode) _
                    Then GoTo ErrHandle
            End If
            If mblnPIsDetail Then
                strSql = "UPDATE ItemType SET blnIsDetail=0 WHERE lngItemTypeID=" & mlngPCodeID
                If Not gclsBase.ExecSQL(strSql) Then GoTo ErrHandle
            End If
        End If
        If Not ChangeHigherCardDetail("ItemType", "strItemTypeCode", mstrOldCode) Then GoTo ErrHandle
    End If
    If Not mblnIsInActive And mblnPIsInActive Then  '本级是活动时改变上级的停用属性
        If Not ChangeHigherActive("ItemType", "strItemTypeCode", mstrCode) _
            Then GoTo ErrHandle
    End If
    gclsBase.BaseWorkSpace.CommitTrans
    SaveCard = True
    mblnIsChanged = False
    gclsSys.SendMessage Me.hwnd, Message.msgItemType
    Exit Function
ErrHandle:
    gclsBase.BaseWorkSpace.RollbackTrans
End Function

Private Function TransActivity(ByVal lngPID As Long) As Boolean
    Dim intLevel As Integer
    Dim recItemType As rdoResultset
    Dim strSql As String, strFullName As String
    
    strSql = "SELECT * FROM ItemType WHERE lngItemTypeID=" & lngPID
    Set recItemType = gclsBase.BaseDB.OpenResultset(strSql, rdOpenForwardOnly)
    With recItemType
    mblnIsDetail = False
'    mblnIsInActive = !blnIsInActive
    mintLevel = !intLevel
    mstrStartDate = !strStartDate
    mstrCode = !strItemTypeCode
    mstrName = !strItemTypeName
    strFullName = !strFullName
    End With
    recItemType.Close
    
    intLevel = stringCount(Trim(txtInput(0).Text), "-") + 1
    strSql = "UPDATE ItemType SET strItemTypeCode='" & txtInput(0).Text _
        & "',strItemTypeName='" & txtInput(1).Text & "',strFullName='" & mstrFullName _
        & "',blnIsInActive=" & chkPause.Value & ",intLevel =" & intLevel _
        & ",strStartDate='" & Format(Date, "YYYY-MM-DD") _
        & "' WHERE lngItemTypeID=" & lngPID
    TransActivity = gclsBase.ExecSQL(strSql)
    If TransActivity Then mstrFullName = strFullName
End Function

Private Sub txtInput_Change(Index As Integer)
    Dim strErr As String
    
    If Index = 0 Then
        strErr = "'""|?/`~\.>, <;;:!@#$%^&*=+"
    Else
        strErr = "'""|?/`~\.>,-<;;:!@#$%^&*=+"
    End If
    If ContainErrorChar(txtInput(Index).Text, strErr) Then
        BKKEY txtInput(Index).hwnd
    End If
    If Not mblnIsInit Then mblnIsChanged = True
End Sub

Private Function IsContinue() As Boolean
    Dim lngResult As Long
    
    IsContinue = True
    If mblnIsChanged Then
        Me.ZOrder 0
        lngResult = ShowMsg(Me.hwnd, "上一次编辑的商品类型还未保存，是否继续编辑它？", vbYesNoCancel + vbQuestion, "商品类型卡片提示信息")
        If lngResult = vbYes Then       '继续编辑上一次的商品类型
            SendKeys "%{C}"
            Exit Function
        Else
            lngResult = ShowMsg(Me.hwnd, "是否保存上一次编辑的商品类型？", vbYesNoCancel + vbQuestion, "商品类型卡片提示信息")
            If lngResult = vbYes Then       '保存上一次编辑的商品类型
                If Not SaveCard Then      '保存失败
                    lngResult = ShowMsg(Me.hwnd, "上一次编辑的商品类型保存失败，是否继续编辑它？", vbYesNoCancel + vbQuestion, "商品类型卡片提示信息")
                    If lngResult = vbYes Then
                        SendKeys "%{C}"
                        Exit Function
                    End If
                End If
            End If
        End If
    End If
    IsContinue = False
End Function