clslistsorder.cls

金算盘软件代码

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsListSOrder"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False

Private intFormType As Integer
Private WithEvents mfrmSOrder As frmAListTemplate   '模版窗体
Attribute mfrmSOrder.VB_VarHelpID = -1
Private mclsSOrder As clsSalesOrder                 '接口类
Private frmEdit As Form                             '接口窗体
Private blnIsVoid    As Boolean                     '是否已作废
Private blnIsInvoice As Boolean                     '开票标志
Private blnChange As Boolean                        '只能编辑和删除自己制作的单据
Private mblnFinish As Boolean
Private mIsShowEdit As Boolean
Private clsListType As String
Public Function SetListType(ByVal strList As String)
    mfrmSOrder.strListType = strList
    clsListType = strList
End Function
Private Sub cMsgBox(strMsg As String, Optional strTitle As String)
    If Trim(strTitle) = "" Then
        strTitle = "提示信息"
    End If

    ShowMsg mfrmSOrder.hWnd, strMsg, MB_OK + MB_ICONEXCLAMATION + MB_SYSTEMMODAL, strTitle
End Sub
Private Sub Class_Initialize()
    Set mfrmSOrder = New frmAListTemplate
    mfrmSOrder.blnReceptionList = True
    mfrmSOrder.mTitle = "商品销售订单列表"
    mfrmSOrder.mHelpID = 40003
    mfrmSOrder.blnIsHavingReport = True
    mfrmSOrder.ReportCount = 3
    mfrmSOrder.ReportName(0) = "销售订单汇总表"
    mfrmSOrder.ReportName(1) = "销售订单明细表"
    mfrmSOrder.ReportName(2) = "销售订单执行情况表"
    
    mfrmSOrder.Tabs = 1
    mfrmSOrder.SpViewID(0) = 77
    mfrmSOrder.blnEditByRight(0) = IsCanDo(frmRightsID.frmListSalesOrderID, gclsBase.OperatorID)
    
    mfrmSOrder.SpSelect(0) = "SaleOrder.lngSaleOrderID, Min(decode(SaleOrder.blnIsVoid,1,'√',' ')) AS ""作废"""
    mfrmSOrder.ShowAll(0) = "SaleOrder.blnIsVoid=0"
    mfrmSOrder.SpGoupBy(0) = "SaleOrder.lngSaleOrderID"
    If Not IsCanDo(262, gclsBase.OperatorID) Then
        mfrmSOrder.SpWhere(0) = "SaleOrder.lngOperatorID=" & gclsBase.OperatorID
    End If
    
    mfrmSOrder.SpPrintID(0) = 38
    mfrmSOrder.SpPrintTitle(0) = "商品销售订单列表" & Chr(1) & gclsBase.BaseName & Chr(1) & gclsBase.OperatorName
    mfrmSOrder.MenuEnbaleOnPage(0) = 1
    mfrmSOrder.MenuEnbaleOnPage(1) = 1
    mfrmSOrder.MenuEnbaleOnPage(2) = 1
    mfrmSOrder.MenuEnbaleOnPage(3) = 1
    mfrmSOrder.MenuEnbaleOnPage(4) = 1
    mfrmSOrder.MenuEnbaleOnPage(5) = 1
    mfrmSOrder.MenuEnbaleOnPage(6) = 1
    mfrmSOrder.MenuEnbaleOnPage(7) = 1
End Sub

Public Function Showlist()
    mfrmSOrder.Show
    mfrmSOrder.ZOrder 0
    Set mclsSOrder = New clsSalesOrder
    mclsSOrder.SethWnd mfrmSOrder.hWnd
    Set frmEdit = FrmSaleOrder
End Function

Private Sub mfrmSOrder_ListChildActive()
    Dim vntMessage As Variant
    For Each vntMessage In mfrmSOrder.mclsMainControl.Messages
        If vntMessage = Message.msgReceipt12 Then
            mfrmSOrder.ToolRefresh
            mfrmSOrder.mclsMainControl.Messages.Remove CStr(vntMessage) '清除消息
        End If
    Next
    mfrmSOrder.mclsMainControl.Messages.Clear
End Sub

Private Sub mfrmSOrder_ListDel()
    Dim lngActivityID As Long
    lngActivityID = mfrmSOrder.ListID
    If lngActivityID = 0 Then Exit Sub
    If GetItemStatus(lngActivityID) = False Then Exit Sub
    If mIsShowEdit Then
        If lngActivityID = frmEdit.getID Then
            cMsgBox "不能删除当前编辑的单据！"
            Exit Sub
        End If
    End If
    If Not blnChange Then
        cMsgBox "不能删除由他人制作的单据！"
        Exit Sub
    End If
    If Not mclsSOrder.DeleteSalesOrder(lngActivityID) Then Exit Sub
    mfrmSOrder.ToolRefresh
End Sub

Private Sub mfrmSOrder_ListEdite()
    Dim lngActivityID As Long
    
    mfrmSOrder.Enabled = False
    mblnFinish = True
    lngActivityID = mfrmSOrder.ListID
    If lngActivityID = -1 Then Exit Sub
    If mIsShowEdit Then
        frmEdit.ShowAOldBill (lngActivityID) '调用接口
    Else
        mIsShowEdit = True
        frmEdit.ShowAOldBill (lngActivityID) '调用接口
    End If
    mblnFinish = False
    mfrmSOrder.Enabled = True
End Sub

Private Sub mfrmSOrder_oListInActive()
    Dim lngActivityID As Long
    
On Error GoTo TheErr
    If mfrmSOrder.IsInActive Then Exit Sub
    lngActivityID = mfrmSOrder.ListID
    If lngActivityID = 0 Then Exit Sub
    If Not GetItemStatus(lngActivityID) Then Exit Sub
    If Not blnChange Then
        cMsgBox "不能作废由他人制作的单据！"
        Exit Sub
    End If
    If Not mclsSOrder.DeleteSalesOrder(lngActivityID, True) Then Exit Sub
    mfrmSOrder.ToolRefresh
    Exit Sub
TheErr:
    'cMsgBox "操作失败！"
End Sub

Private Sub mfrmSOrder_ListInActive(blnLevel As Boolean, blnSuceess As Boolean)
    Dim lngActivityID As Long
    
On Error GoTo TheErr
blnLevel = False
blnSuceess = False
    If mfrmSOrder.IsInActive Then Exit Sub
    lngActivityID = mfrmSOrder.ListID
    If lngActivityID = 0 Then Exit Sub
    If Not GetItemStatus(lngActivityID) Then Exit Sub
    If Not blnChange Then
        cMsgBox "不能作废由他人制作的单据！"
        Exit Sub
    End If
    If Not mclsSOrder.DeleteSalesOrder(lngActivityID, True) Then Exit Sub
    'mfrmSOrder.ToolRefresh
    blnSuceess = True
    Exit Sub
TheErr:
    'cMsgBox "操作失败！"
End Sub

Private Sub mfrmSOrder_ListNew()
    mblnFinish = True
    If mIsShowEdit Then
        frmEdit.ShowANewBill
    Else
        frmEdit.ShowANewBill
        mIsShowEdit = True
    End If
    mblnFinish = False
End Sub

Private Sub mfrmSOrder_ListPrintReceipt()
    frmPrintReceipt.ShowfrmPrintReceipt 24
End Sub

Private Sub mfrmSOrder_ListReorpt(ByVal Index As Integer)
    Select Case Index
    Case 0:
         Report.ShowSumReport 1592, 716
    Case 1:
         Report.ShowStandardReport 1593, 717
    Case 2:
         Report.ShowSumReport 1594, 718
    End Select
End Sub

Private Sub mfrmSOrder_ListShowAll()
    With mfrmSOrder
        If .chkShowall = 0 Then
            .ShowAll(0) = "SaleOrder.blnIsVoid=0"
        Else
            .ShowAll(0) = ""
        End If
        .ToolRefresh
    End With
End Sub

Private Function GetItemStatus(lngActivityID As Long) As Boolean
    Dim strSql As String
    Dim recTemp As rdoResultset
    
    strSql = "SELECT SaleOrder.lngOperatorID From SaleOrder WHERE SaleOrder.lngSaleOrderID=" & lngActivityID & ""
    Set recTemp = gclsBase.BaseDB.OpenResultset(strSql, rdOpenForwardOnly)
    If recTemp.BOF And recTemp.EOF Then Exit Function
    If gclsBase.OperatorID = recTemp(0) Then
        blnChange = True
    Else
        blnChange = False
    End If
    
    Set recTemp = Nothing
   
    '判断采购订单是否已执行
    GetItemStatus = True
End Function

'告诉列表：编辑窗口已关闭
Public Sub IAmCLosed()
    mIsShowEdit = False
End Sub