frmeducation.frm

金算盘软件代码

VERSION 5.00
Object = "{F42BDC2B-FC9B-11D1-9ABD-444553540000}#4.0#0"; "ATLEDIT.OCX"
Begin VB.Form frmEducation 
   Caption         =   "新增文化程度"
   ClientHeight    =   1545
   ClientLeft      =   2775
   ClientTop       =   2505
   ClientWidth     =   4305
   HelpContextID   =   10239
   KeyPreview      =   -1  'True
   LinkTopic       =   "Form2"
   LockControls    =   -1  'True
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   1545
   ScaleWidth      =   4305
   ShowInTaskbar   =   0   'False
   StartUpPosition =   2  '屏幕中心
   Begin AtlEdit.TEdit txtEducation 
      Height          =   285
      Left            =   270
      TabIndex        =   1
      Top             =   630
      Width           =   2355
      _ExtentX        =   4154
      _ExtentY        =   503
      maxchar         =   20
      BeginProperty Font {0BE35203-8F91-11CE-9DE3-00AA004BB851} 
         Name            =   "宋体"
         Size            =   9
         Charset         =   134
         Weight          =   400
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      Text            =   ""
   End
   Begin VB.CommandButton cmdOk 
      Height          =   350
      Index           =   2
      Left            =   2940
      Style           =   1  'Graphical
      TabIndex        =   4
      Tag             =   "1009"
      Top             =   930
      UseMaskColor    =   -1  'True
      Width           =   1215
   End
   Begin VB.CommandButton cmdOk 
      Cancel          =   -1  'True
      Height          =   350
      Index           =   1
      Left            =   2940
      Style           =   1  'Graphical
      TabIndex        =   3
      Tag             =   "1002"
      Top             =   540
      UseMaskColor    =   -1  'True
      Width           =   1215
   End
   Begin VB.CommandButton cmdOk 
      Height          =   350
      Index           =   0
      Left            =   2940
      Style           =   1  'Graphical
      TabIndex        =   2
      Tag             =   "1001"
      Top             =   150
      UseMaskColor    =   -1  'True
      Width           =   1215
   End
   Begin VB.Label lblEducation 
      Caption         =   "文化程度(&E)"
      Height          =   195
      Left            =   300
      TabIndex        =   0
      Top             =   420
      Width           =   1005
   End
End
Attribute VB_Name = "frmEducation"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'                                                                                                '
'                功能:   完成文化程度的增、删、改。                                              '
'                卡片接口:             EditCard 参数: lngID 记录的ID号                           '
'                作用:                           LNGID为零是增加记录、其它为编辑记录             '
'                                      DelCard 参数: lngID 记录的ID号                            '
'                作用:                           删除ID号为LNGID的记录                           '
'                作者：     苏涛                                                                               '
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''



Option Explicit

Private mblnIsInit As Boolean
Private mblnIsList As Boolean
Private mlngEducateID As Integer   '文化程度ID
Private mblnIsNew As Boolean
Private mblnIsChanged As Boolean
Private mblnIsEmployee As Boolean

Public Property Get getID() As Long
    getID = mlngEducateID
End Property

Public Function AddCard(Optional strName As String = "", Optional intModal As Integer = 0, _
    Optional ByVal IsList As Boolean = False) As Long
    mlngEducateID = 0
    mblnIsNew = True
    mblnIsChanged = True
    mblnIsList = IsList
    InitCard strName
    Caption = "新增文化程度"
    Show intModal
    AddCard = mlngEducateID
End Function

Public Function DelCard(lngID As Long, Optional lnghWnd As Long = 0) As Boolean
    Dim recEdu As rdoResultset, strName As String, strSql As String
    
    DelCard = False
    strSql = "SELECT * FROM Education WHERE lngEducationID=" & lngID
    Set recEdu = gclsBase.BaseDB.OpenResultset(strSql, rdOpenStatic)
    If recEdu.EOF Then
        DelCard = True
        recEdu.Close
        Exit Function
    Else
        strName = recEdu!strEducationName
    End If
    recEdu.Close
    
    If CheckIDUsed("Employee", "lngEducationID", lngID) Then
        ShowMsg lnghWnd, "“" & strName & "”文化程度已经发生业务,不能删除！", _
            vbExclamation + MB_TASKMODAL, "删除文化程度"
        Exit Function
    End If
    If ShowMsg(lnghWnd, "你确实要删除“" & strName & "”文化程度吗？", vbQuestion + vbYesNo + MB_TASKMODAL + vbDefaultButton2, _
        "删除文化程度") = vbNo Then Exit Function
    strSql = "DELETE FROM Education WHERE lngEducationID=" & lngID
    gclsBase.BaseDB.Execute strSql
    gclsSys.SendMessage CStr(Me.hwnd), Message.msgEmployee
    DelCard = True
End Function

Public Sub EditCard(ByVal lngID As Long, Optional intModal As Integer = 0, _
        Optional strEducation As String)
    Dim strMess As String
    
    If Not CheckIDUsed("Education", "lngEducationID", lngID) Then
        If Trim(strEducation) <> "" Then
            strMess = "“" & strEducation & "”"
        Else
            strMess = "该"
        End If
        ShowMsg 0, strMess & "文化程度不存在,不能进行修改！", _
            vbExclamation + MB_TASKMODAL, "修改文化程度"
        Unload Me
    Else
        mlngEducateID = lngID
        mblnIsNew = False
        InitCard
        Caption = "修改文化程度"
        cmdOk(2).Visible = False
        Show intModal
    End If
End Sub

Private Sub InitCard(Optional strName As String = "")
    Dim recEducation As rdoResultset, strSql As String
   
    mblnIsInit = True
    If Not mblnIsNew Then
        strSql = "SELECT * FROM Education WHERE lngEducationID=" & mlngEducateID
        Set recEducation = gclsBase.BaseDB.OpenResultset(strSql, rdOpenStatic)
        txtEducation.Text = recEducation!strEducationName
        recEducation.Close
    Else
        txtEducation.Text = Trim(strName)
    End If
    mblnIsInit = False
End Sub

Private Sub cmdOK_Click(Index As Integer)
    If Index = 0 Then
        If Not SaveCard Then Exit Sub
    ElseIf Index = 2 Then
        If SaveCard Then
'            mlngEducateID = 0
            mblnIsNew = True
            mblnIsChanged = True
            InitCard
            txtEducation.SetFocus
        End If
        Exit Sub
    End If
    Unload Me
End Sub

Private Sub Form_Activate()
    SetHelpID Me.HelpContextID
End Sub

Private Sub Form_KeyPress(KeyAscii As Integer)
    If mblnIsList Then
        mblnIsList = False
        Exit Sub
    End If
    If KeyAscii = vbKeyReturn Then
        BKKEY Me.ActiveControl.hwnd, vbKeyTab
    End If
End Sub

Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
    If KeyCode = vbKeyReturn And Shift = 2 Then
        cmdOk(0).Value = True
    End If
End Sub

Private Sub Form_Load()
    Dim edtErrReturn As ErrDealType
    
    On Error GoTo ErrHandle
    Utility.LoadFormResPicture Me
'    SendKeys "%{E}"
    Exit Sub
ErrHandle:
    edtErrReturn = Errors.ErrorsDeal
    
    If edtErrReturn = edtResume Then
         Resume
    Else
         On Error Resume Next
         Unload Me
    End If
End Sub

Private Sub Form_Paint()
  FrameBox Me.hwnd, 90, 150, 2775, 1335
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    Dim intMsgReturn As Integer, strMess As String
    
    If UnloadMode <> vbFormControlMenu Then Exit Sub
    If Trim(txtEducation.Text) = "" Then Exit Sub
    If mblnIsChanged Then
        If mblnIsNew Then
            strMess = "您要保存新增的文化程度“" & txtEducation.Text & "”吗？"
        Else
            strMess = "“" & txtEducation.Text & "”" & "文化程度已被修改，是否保存？"
        End If
        intMsgReturn = ShowMsg(hwnd, strMess, vbQuestion + vbYesNoCancel, Caption)
        If intMsgReturn = vbYes Then
            Cancel = Not SaveCard
        ElseIf intMsgReturn = vbCancel Then
            Cancel = True
        End If
    End If
End Sub

Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
    mblnIsChanged = False
    Utility.UnLoadFormResPicture Me
End Sub

Private Sub txtEducation_Change()
    If ContainErrorChar(txtEducation.Text) Then BKKEY txtEducation.hwnd
    If Not mblnIsInit Then mblnIsChanged = True
End Sub

Private Function SaveCard() As Boolean
    Dim recTemp As rdoResultset
    Dim strSql As String
    
    SaveCard = False
    
    If Not mblnIsChanged Then
        SaveCard = True
        Exit Function
    End If
    If txtEducation.Text = "" Then
        ShowMsg hwnd, "文化程度不能为空！", vbExclamation + MB_TASKMODAL, Caption
        txtEducation.SetFocus
        Exit Function
    End If
     
    strSql = "SELECT * FROM Education WHERE strEducationName='" & txtEducation.Text _
        & "' AND lngEducationID <>" & IIf(mblnIsNew, 0, mlngEducateID)
    Set recTemp = gclsBase.BaseDB.OpenResultset(strSql, rdOpenStatic)
    If Not recTemp.EOF Then
        ShowMsg hwnd, "文化程度不能为重复,请重新录入！", vbExclamation + MB_TASKMODAL, Caption
        txtEducation.SetFocus
        recTemp.Close
        Exit Function
    End If
    recTemp.Close
    If mblnIsNew Then
        mlngEducateID = GetNewID("Education")
        strSql = "INSERT INTO Education(lngEducationID,strEducationName) " _
            & "VALUES(" & mlngEducateID & ",'" & txtEducation.Text & "')"
        If Not gclsBase.ExecSQL(strSql) Then Exit Function
'        Strsql = "SELECT * FROM Education WHERE strEducationName='" & Trim(txtEducation.Text) & "'"
'        Set recTemp = gclsBase.BaseDB.OpenResultset(Strsql, rdOpenStatic)
'        mlngEducateID = recTemp!lngEducationID
'        recTemp.Close
    Else
        strSql = "UPDATE Education SET strEducationName='" & Trim(txtEducation.Text) _
            & "'" & "WHERE lngEducationID=" & mlngEducateID
        If Not gclsBase.ExecSQL(strSql) Then Exit Function
    End If
    SaveCard = True
    mblnIsChanged = False
'    gclsSys.SendMessage CStr(Me.hWnd), Message.msgEmployee
End Function