review.asp

网人分类信息5.0商业版。非常优秀的分类信息系统。比较少见。

<!--#include file="../inc/Conn.asp"-->
<!--#include file="../Inc/Cls.Common.asp"-->
<!--#include file="../Inc/Cls.Templates.asp"-->
<!--#include file="Channel_Config.asp"-->
<%
    Dim ReviewTitle,Midst,MidstC,WM_Key,ID,MidstContent,B_Place,L_Place,B_ParentPath,i,reUrl,Contact,User,FromUrl
    Dim Msg,n,IsToPost,Dir
    If Revert < 1 Or Int(FlagClass(10)) < 1 Then Call WRMPS.ErrView("·您没有权限使用此功能",0)
    ID = WRMPS.CheckStr(Request("ID"),1)
    If ID = "" Then Call WRMPS.ErrView("·操作错误",0)

    Call DBConnBegin() 
    Set Rs=server.createobject("adodb.recordset")
    
	If WRMPS.CheckStr(Request.Form("Action"),0) = "PostRe" Then
	  Call WRMPS.CheckSubmit()
	  FromUrl = WRMPS.CheckStr(Request.Form("FromUrl"),0)
	  If FromUrl <> "" Then FromUrl = Request.ServerVariables("HTTP_REFERER") Else FromUrl = WR_Setting(3)&ChannelDir&"/Review.asp?ID="&ID
	  Content = WRMPS.CheckStr(Request.Form("Content"),2)
	  If Content = "" Or Len(Content) > Int(UserFlag(13)) Then Call WRMPS.ErrView("·请输入不超过 "&Int(UserFlag(13))&" 字符的评论内容<meta http-equiv='refresh' content='1;URL="&FromUrl&"'>",0)
	  Contact = WRMPS.CheckStr(Request.Form("Contact"),0)
	  If Contact = "" Then Contact = NULL
	  If Len(Contact) > 50 Then Call WRMPS.ErrView("·联系方式不能超过50字符<meta http-equiv='refresh' content='1;URL="&FromUrl&"'>",0)
	  If WRMPS.CheckCode("Re",1) Then
	    If WRMPS.CheckStr(Request.Form("Code"),0) = "" Then Call WRMPS.ErrView("·请输入验证码<meta http-equiv='refresh' content='1;URL="&FromUrl&"'>",0)
        If WRMPS.CheckStr(Request.Form("Code"),0) <> WRMPS.GetCookies("Code") Then Call WRMPS.ErrView("·您的验证码输入有误<meta http-equiv='refresh' content='1;URL="&FromUrl&"'>",0)
      End If
	  If WRUser.ChkLogin Then User = MemName Else User = NULL
	  If Int(FlagClass(13)) = 1 Then WM_Key = 1 Else WM_Key = 0
	  IsToPost = WRMPS.CheckStr(Request.Form("IsToPost"),1)
	  If IsToPost = "" Then IsToPost = 0
	  If WM_Key > 0 and WRUser.ChkLogin Then Call WRDB.SaveConsume(0,MemName,0,Int(FlagClass(12)),Int(FlagClass(11)),0,"分类信息回复成功")
	  '判断是否用会员发布，否则不能使用只给发布人功能
	  Set Rs = Conn.Execute("Select WM_ID From WM_ClassAD Where WM_PostType = 1 and WM_ID="&ID)
	  If Rs.Eof Then
         IsToPost = 0
	  End If
	  Rs.Close
	  Rs.open "Select WM_ChannelID,WM_ParentID,WM_Content,WM_DateTime,WM_User,WM_Key,WM_Contact,WM_IsToPost From WM_ClassRevert",conn,1,3
	  Rs.AddNew
	    Rs(0) = ChannelID
		Rs(1) = ID
		Rs(2) = Content
		Rs(3) = Now()
		Rs(4) = User
		Rs(5) = WM_Key
		Rs(6) = Contact
		Rs(7) = IsToPost
	  Rs.Update
	  Rs.Close
	  WRMPS.DelCookies "Code"
	  If WR_Mail(5) <> "NO" Or Int(WR_Mail(17)) > 0 Then
	    Rs.Open "Select Top 1 WM_Email,WM_PostTime,WM_ClassDir,WM_Title,WM_AreaID,WM_Post From WM_ClassAD Where WM_PostType = 1 and WM_ID="&ID&"",Conn,1,1
	    If Not Rs.Eof Then
	        MailBody = WR_Mail(8)
	        MailBody = Replace(MailBody,"{$Url}",WRMPS.GetShowUrl(1,1,0,ID,Rs(1),ChannelDir&"/"&Rs(2),ChannelID))
	        MailBody = Replace(MailBody,"{$Title}",Rs(3))
            Subject = "您在"&WR_Setting(0)&"的信息有人回复了！"
  	        If WR_Mail(5) <> "NO" Then Call WRMPS.SendMail(WRTemp.SiteLabel(MailBody&vbCrLf&vbCrLf&WR_Mail(4)),WRTemp.SiteLabel(WR_Setting(0)),WRTemp.SiteLabel(Subject),Rs(0))
	        If Int(WR_Mail(17)) > 0 Then
		      Call WRDB.SendMessage(Rs(5),Null,"您发布的信息“"&Rs(3)&"”有人回复了！",WRTemp.SiteLabel(MailBody))
	        End If
	    End If
	    Rs.Close
	    Set Rs = Nothing
	  End If
	  If WM_Key < 1 Then
	    Msg = "<br>·请等待管理员的审核"
	  Else
	    Conn.Execute("Update WM_ClassAD Set WM_Re=WM_Re+1 where WM_ID="&ID)
	  End If
	  Call WRMPS.ErrView("·评论提交成功"&Msg&"<br>·1秒钟后自动跳转到上一页<meta http-equiv='refresh' content='1;URL="&FromUrl&"'>",1)
    End If
    '##################################################
	Call WRMPS.FsoBegin()
	Content = WRTemp.SiteTemplates(1,0,20,ChannelID)
    Call WRMPS.FsoEnd()
	
	Set Rs = Conn.Execute("Select WM_Title,WM_ClassID,WM_PostTime,WM_ClassDir,WM_AreaID From WM_ClassAD Where WM_Key=1 and WM_ID="&ID&"")
    If Rs.Eof Then
	   Call WRMPS.ErrView("·内容不存在",0)
	Else
	   ReUrl = WRMPS.GetShowUrl(1,1,0,ID,Rs(2),ChannelDir&Rs(3),ChannelID)
	   Content = WRMPS.GetReplace(Content,"{$Url}",reUrl)
       Set Rst = Conn.Execute("Select WM_ID,WM_Name,WM_ParentPath,WM_ParentDir,WM_Dir From WM_ClassSort Where WM_ID="&Rs(1)&"")
         If Not Rst.Eof Then
		     B_Place = ",<a href="&WRMPS.GetClassUrl(0,1,1,ChannelDir&Rst(3)&Rst(4),Rst(0))&">"&Rst(1)&"</a>,评论："&Rs(0)
	         ClassName = Rst(1)
	         ClassID = Rst(0)
	          If Rst(2) <> "0" Then
	            B_ParentPath = Right(Rst(2),Len(Rst(2))-2)
	            B_ParentPath = Split(B_ParentPath,",")
	            L_Place = ""
		        For i=0 to UBound(B_ParentPath)
	             Set Rso = Conn.Execute("Select WM_ID,WM_Name,WM_ParentDir,WM_Dir From WM_ClassSort Where WM_ID="&Int(B_ParentPath(i))&"")
		           L_Place = L_Place & ",<a href="&WRMPS.GetClassUrl(0,1,1,ChannelDir&Rso(2)&Rso(3),Rso(0))&">"&Rso(1)&"</a>"
				 Rso.Close
	           Next
	         End If  
         Else
	       Rst.Close
	       Call WRMPS.ErrView("·分类不存在",0)
         End If
	     Rst.Close
	SitePath = WRMPS.GetSitePath(-1,",<a href="&WR_Setting(3)&ChannelDir&"/>"&ChannelName&"</a>"&L_Place&B_Place)
    ReviewTitle = Rs(0)
	End If
	Rs.Close
	
	Page = WRMPS.CheckStr(Request("Page"),1)
	If Page = "" Then Page = 1
    If Instr(Content,"{$CycBegin}") > 0 Then
	  Dim ShowNum
      ShowNum = WRMPS.HCode(2,Content,"{\$CycBegin}【","】")
	  MidstContent = WRMPS.HCode(2,Content,"{\$CycBegin}【"&ShowNum&"】","{\$CycEnd}")
	  Set ClsPageList = New Cls_PageView  
      ClsPageList.strTableName = "WM_ClassRevert"  
      ClsPageList.strPageUrl = ""
      ClsPageList.strFieldsList = "WM_Content,WM_User,WM_DateTime,WM_Contact"  
      ClsPageList.strCondiction = "WM_ParentID="&ID&" and WM_ChannelID="&ChannelID&" and WM_IsToPost = 0 and WM_Key=1"
      ClsPageList.strOrderList = "WM_ID Desc"
      ClsPageList.strPrimaryKey = "WM_ID"  
      ClsPageList.intPageSize = ShowNum
      ClsPageList.intPageNow = Page
      ClsPageList.strCookiesName = "RecordCount"  
      ClsPageList.strPageVar = "Page"  
      ClsPageList.intRefresh = 1 
      ClsPageList.objConn = Conn  
      ClsPageList.InitClass  
      arrPage = ClsPageList.arrPage  
      strPageList = ClsPageList.strPageList
      Set ClsPageList = nothing
	  
      If IsArray(arrPage) Then
        For i = 0 to UBound(arrPage, 2)
	       User = WRUser.DispUser(0,arrPage(1,i))
		   Midst = WRMPS.GetReplace(MidstContent,"{$ReviewNumber}",i)
		   Midst = WRMPS.GetReplace(Midst,"{$ReviewUser}",User)
		   Midst = WRMPS.GetReplace(Midst,"{$ReviewContent}",arrPage(0,i))
		   Midst = WRMPS.GetReplace(Midst,"{$ReviewContact}",arrPage(3,i))
		   Midst = WRMPS.GetReplace(Midst,"{$ReviewTime}",arrPage(2,i))
		   MidstC = MidstC & Midst
		Next
	  End If
	  Content = WRMPS.HCode(1,Content,"{\$CycBegin}","{\$CycEnd}") & MidstC & WRMPS.HCode(3,Content,"{\$CycBegin}","{\$CycEnd}")
    End If
    Content = WRMPS.GetReplace(Content,"{$NextPage}",strPageList)
	If Instr(Content,"{$IDCode}") > 0 Then
	  If WRMPS.CheckCode("Re",1) Then
	      Content = WRMPS.GetReplace(Content,"{$IDCode}","")
	  Else
		  Content = WRMPS.GetReplace(Content,"{$IDCode}"," style=""display:none""")
	  End If
    End If
    Content = WRMPS.GetReplace(Content,"{$ReviewID}",ID)
    Content = WRMPS.GetReplace(Content,"{$ReviewTitle}",reviewTitle)
    Content = WRTemp.SiteClass(Content)
    Content = WRTemp.SiteChannel(Content)
    Content = WRTemp.SiteLabel(Content)

    Set Rst = Nothing
    Set Rs = Nothing
    Call ClassEnd()
    Call DBConnEnd()
    Response.write Content
%>