index.asp

网人分类信息5.0商业版。非常优秀的分类信息系统。比较少见。

<!--#include file="../inc/Conn.asp"-->
<!--#include file="../Inc/Cls.Common.asp"-->
<!--#include file="../Inc/Cls.Templates.asp"-->
<!--#include file="Channel_Config.asp"--> 
<%
If Int(FlagMsg(4)) < 1 Then Call WRMPS.ErrView("·您没有权限使用此功能", 0)
  Dim ReviewTitle,Midst,MidstC,MidstContent,Contact,User,Msg,i,n,MessageContact,Code
  Dim Tit
  Call DBConnBegin() 
  Set Rs=server.createobject("adodb.recordset")
    If WRMPS.CheckStr(Request.Form("Action"),0) = "PostRe" Then
	  Call WRMPS.CheckSubmit()
	  Tit = WRMPS.CheckStr(Request.Form("Tit"),0)
	  If Tit = "" Or Len(Tit) > 50 Then Call WRMPS.ErrView("·标题不能超过 50 字符",0)
      For i = 1 To Request.Form("Content").Count
        Content = Content & Request.Form("Content")(i)
      Next
	  If Content = "" Or Len(Content) > 1000 Then Call WRMPS.ErrView("·内容不能超过 1000 字符",0)
	  Contact = WRMPS.CheckStr(Request.Form("Contact"),0)
	  If Contact = "" Then Contact = NULL
	  If Len(Contact) > 50 Then Call WRMPS.ErrView("·联系方式不能超过50字符",0)
	  Code = WRMPS.CheckStr(Request.Form("Code"),0)
	  If WRMPS.CheckCode("GuestBook",1) Then If Code <> WRMPS.GetCookies("Code") Then Call WRMPS.ErrView("·您没有输入验证码或验证码不正确",0)
	  If WRUser.ChkLogin Then User = MemName Else User = NULL
	  If Int(FlagMsg(7)) > 0 and WRUser.ChkLogin Then Call WRDB.SaveConsume(0,MemName,0,Int(FlagMsg(6)),Int(FlagMsg(5)),0,"留言“"&Tit&"”成功")
	  Rs.open "Select WM_User,WM_Tit,WM_Content,WM_Time,WM_Key,WM_Contact,WM_Type From WM_GuestBook",conn,1,3
	  Rs.AddNew
		Rs(0) = User
		Rs(1) = Tit
		Rs(2) = Content
		Rs(3) = Now()
		Rs(4) = Int(FlagMsg(7))
		Rs(5) = Contact
		Rs(6) = 0
	  Rs.Update
	  Rs.Close
	  WRMPS.DelCookies "Code"
	  If Int(FlagMsg(7)) < 1 Then Msg = "<br>·请等待管理员的审核"
	  Call WRMPS.ErrView("·提交成功"&Msg&"<br>·1秒钟后自动跳转到"&ChannelName&"首页<meta http-equiv='refresh' content='1;URL=Index.asp'>",1)
    End If

	SitePath = ",<a href="&WR_Setting(3)&ChannelDir&"/>"&ChannelName&"</a>"
	SitePath = WRMPS.GetSitePath(0,SitePath)
	Call WRMPS.FsoBegin()
	TempStr = WRTemp.SiteTemplates(1,0,30,ChannelID)
 	Call WRMPS.FsoEnd()

	Page = WRMPS.CheckStr(Request("Page"),1)
	If Page = "" Then Page = 1
    If Instr(TempStr,"{$CycBegin}") > 0 Then
	  Dim ShowNum
      ShowNum = WRMPS.HCode(2,TempStr,"{\$CycBegin}【","】")
	  MidstContent = WRMPS.HCode(2,TempStr,"{\$CycBegin}【"&ShowNum&"】","{\$CycEnd}")
	  Set ClsPageList = New Cls_PageView  
      ClsPageList.strTableName = "WM_GuestBook"  
      ClsPageList.strPageUrl = ""
      ClsPageList.strFieldsList = "WM_User,WM_Tit,WM_Content,WM_Re,WM_Time,WM_Contact"  
      ClsPageList.strCondiction = "WM_Key=1"
      ClsPageList.strOrderList = "WM_ID Desc"
      ClsPageList.strPrimaryKey = "WM_ID"  
      ClsPageList.intPageSize = ShowNum
      ClsPageList.intPageNow = Page
      ClsPageList.strCookiesName = "RecordCount"  
      ClsPageList.strPageVar = "Page"  
      ClsPageList.intRefresh = 1 
      ClsPageList.objConn = Conn  
      ClsPageList.InitClass  
      arrPage = ClsPageList.arrPage  
      strPageList = ClsPageList.strPageList
      Set ClsPageList = nothing

      If IsArray(arrPage) Then
        For i = 0 to UBound(arrPage, 2)
		   User = WRUser.DispUser(0,arrPage(0,i))
		   Midst = WRMPS.GetReplace(MidstContent,"{$MessageNumber}",i)
		   Midst = WRMPS.GetReplace(Midst,"{$MessageUser}",User)
		   Midst = WRMPS.GetReplace(Midst,"{$MessageContact}",arrPage(5,i))
		   MessageContact = arrPage(2,i)
		   MessageContact = WRMPS.CheckStr(MessageContact,10) 
		   Midst = WRMPS.GetReplace(Midst,"{$MessageContent}",MessageContact)
		   If arrPage(3,i) <> "" Then Midst = WRMPS.GetReplace(Midst,"{$MessageRe}","<div class=GuestRe><span class=GuestReText>回复：</span><br>"&arrPage(3,i)&"</div>") Else Midst = WRMPS.GetReplace(Midst,"{$MessageRe}","")
		   Midst = WRMPS.GetReplace(Midst,"{$MessageTitle}",arrPage(1,i))
		   Midst = WRMPS.GetReplace(Midst,"{$MessageTime}",arrPage(4,i))
	       MidstC = MidstC & Midst
		Next
	  End If
	  TempStr = WRMPS.HCode(1,TempStr,"{\$CycBegin}","{\$CycEnd}") & MidstC & WRMPS.HCode(3,TempStr,"{\$CycBegin}","{\$CycEnd}")
    End If
    TempStr = WRMPS.GetReplace(TempStr,"{$NextPage}",strPageList)
	If Instr(TempStr,"{$IDCode}") > 0 Then
	  TempStr = WRMPS.GetReplace(TempStr,"{$IsIDCode}",WRMPS.CheckCode("GuestBook",1))
	  If WRMPS.CheckCode("GuestBook",1) Then
	      TempStr = WRMPS.GetReplace(TempStr,"{$IDCode}","")
	  Else
		  TempStr = WRMPS.GetReplace(TempStr,"{$IDCode}"," style=""display:none""")
	  End If
    End If
	TempStr = WRTemp.SiteChannel(TempStr)
	TempStr = WRTemp.SiteLabel(TempStr)
	Call ClassEnd()
    Call DBConnEnd()
    Response.write TempStr
%>