cls.label.user.asp

网人分类信息5.0商业版。非常优秀的分类信息系统。比较少见。

<%
Class Cls_Label_User
'ul
  Private iRs,ulSQL,ulN,ulTemp,e_Sql
  Private ulExport,ulTDCSS,ulGroup,ulAgent,ulSex,ulRZEmail,ulRZID,ulNum,ulColsNum,ulContent,ulSexSign,ulOrderType
  Private ulOrderBy
  
  Private Sub Class_Initialize()
	 Set iRs = Server.CreateObject("ADODB.Recordset")
  End Sub
  Private Sub Class_Terminate()
     Set iRs = Nothing
  End Sub
  
  Function GetUser(Str)
     Str = Split(Str,",")
	 ulExport = Int(Str(0))
	 ulTDCSS = Str(1)
	 ulGroup = Int(Str(2))
	 ulAgent = Int(Str(3))
	 ulSex = Int(Str(4))
	 ulRZEmail = Int(Str(5))
	 ulRZID = Int(Str(6))
	 ulOrderType = Int(Str(7))
	 ulNum = Int(Str(8))
	 ulColsNum = Int(Str(9))
	 ulContent = WRMPS.GetReplace(Str(10),"§№§",",")
	 
	 ulSQL = "":ulOrderBy = ""
	 If ulAgent > 0 Then ulSQL = ulSQL & " and A.WM_Agent=1"
	 If ulRZID > 0 Then ulSQL = ulSQL & " and A.WM_RZID=1"
	 If ulRZEmail > 0 Then ulSQL = ulSQL & " and A.WM_RZEmail=1"
	 If ulGroup > 0 Then ulSQL = ulSQL & " and A.WM_GroupID="&ulGroup
	 If ulSex < 2 Then ulSQL = ulSQL & " and A.WM_Sex="&ulSex
	 
     Select Case ulOrderType
       Case 1
	     ulOrderBy = " Order By A.WM_ID Desc"
       Case 2
	     ulOrderBy = " Order By A.WM_NowLoginTime Desc,A.WM_ID Desc"
       Case 3
	     ulOrderBy = " Order By A.WM_LoginNum Desc,A.WM_ID Desc"
       Case 4
	     ulOrderBy = " Order By A.WM_Money Desc,A.WM_ID Desc"
       Case 5
	     ulOrderBy = " Order By A.WM_Integral Desc,A.WM_ID Desc"
       Case 6
	     ulOrderBy = " Order By A.WM_CountOut Desc,A.WM_ID Desc"
       Case 7
	     ulOrderBy = " Order By A.WM_Faith Desc,A.WM_ID Desc"
       Case 8
	     ulOrderBy = " Order By A.WM_ClassNum Desc,A.WM_ID Desc"
       Case 9
	     ulOrderBy = " Order By A.WM_ArticleNum Desc,A.WM_ID Desc"
       Case 10
	     ulOrderBy = " Order By A.WM_CompanyNum Desc,A.WM_ID Desc"
       Case 11
	     ulOrderBy = " Order By A.WM_CompanyReNum Desc,A.WM_ID Desc"
     End Select
     Select Case ulExport
	   Case 2
	     GetUser = "<table border=0 cellspacing=0 cellpadding=0><tr>" & vbCrLf
	   Case 3
	     GetUser = "<div"&WRMPS.LabelCss(ulTDCSS)&"><ul>" & vbCrLf
	 End Select
     e_Sql = "Select Top "&ulNum&" A.WM_ID,A.WM_UserName,A.WM_TrueName,A.WM_Sex,A.WM_Email,A.WM_Web,A.WM_Tel,A.WM_QQ,A.WM_AddRess,A.WM_Sign,A.WM_Face,A.WM_RegTime,A.WM_LastLoginTime,A.WM_LoginNum,A.WM_Money,A.WM_Integral,A.WM_CountOut,A.WM_Faith,A.WM_ClassNum,A.WM_ArticleNum,A.WM_CompanyNum,A.WM_CompanyReNum,B.WM_GroupName from WM_Member A Inner Join WM_UserGroup B on A.WM_GroupID = B.WM_ID Where A.WM_Key=1"&ulSQL&ulOrderBy
     iRs.Open e_Sql,Conn,1,1
	 ulN = 0
	 If iRs.Eof Then GetUser = "":iRs.Close:Exit Function
	 Do While Not iRs.Eof
	    ulN = ulN + 1
		ulTemp = ulContent
		ulTemp = WRMPS.GetReplace(ulTemp,"{$ID}",iRs(0))
        ulTemp = WRMPS.GetReplace(ulTemp,"{$No}",ulN)
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Url}",WRMPS.GetSpaceUrl(0,iRs(1)))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$UserName}",iRs(1))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$TrueName}",iRs(2))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Group}",iRs(22))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Sex}",WRMPS.GetReplace(WRMPS.GetReplace(iRs(3),"1","男孩"),"0","女孩"))
		ulSexSign = WRMPS.GetReplace(WRMPS.GetReplace(iRs(3),"1",UrlPath&"Skins/"&WR_Setting(5)&"/boy.gif"),"0",UrlPath&"Skins/"&WR_Setting(5)&"/girl.gif")
		If ulSexSign = "" Then ulSexSign = UrlPath&"Skins/"&WR_Setting(5)&"/renyao.gif"
		ulTemp = WRMPS.GetReplace(ulTemp,"{$SexSign}",ulSexSign)
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Email}",iRs(4))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$WEB}",iRs(5))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Tel}",iRs(6))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$QQ}",iRs(7))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$AddRess}",iRs(8))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$UserSign}",iRs(9))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$UserFace}",WR_Setting(3)&iRs(10))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$RegTime}",iRs(11))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$LoginTime}",iRs(12))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$LoginNum}",iRs(13))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Money}",WRMPS.GetFormatNumber(iRs(14),2))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Integral}",iRs(15))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$CountOut}",iRs(16))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$Faith}",iRs(17))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$ClassNum}",iRs(18))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$ArticleNum}",iRs(19))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$CompanyNum}",iRs(20))
		ulTemp = WRMPS.GetReplace(ulTemp,"{$DPNum}",iRs(21))
	    Select Case ulExport
	      Case 1
	        GetUser = GetUser & ulTemp
	      Case 2
	        GetUser = GetUser & "<td"&WRMPS.LabelCss(ulTDCSS)&">"&ulTemp&"</td>" & vbCrLf
	      Case 3
	        GetUser = GetUser & "<li>"&ulTemp&"</li>" & vbCrLf
	    End Select
	    If ulColsNum > 0 Then
	      If Int(ulN) mod ulColsNum = 0 And ulN <> iRs.RecordCount Then
		    Select Case ulExport
		      Case 1
		        GetUser = GetUser & "<br>" & vbCrLf
		      Case 2
		        GetUser = GetUser & "</tr>" & vbCrLf & "<tr>" & vbCrLf
		      Case 3
		        GetUser = GetUser & "</ul>" & vbCrLf & "<ul>" & vbCrLf
		    End Select
	      End If
	    End If
	 iRs.MoveNext
	 Loop
	 iRs.Close
	 Select Case ulExport
	   Case 2
         GetUser = GetUser & "</tr></table>" & vbCrLf
	   Case 3
         GetUser = GetUser & "</ul></div>" & vbCrLf
	 End Select
	 ulTemp = ""
  End Function
End Class
Set ClsUser = New Cls_Label_User
%>