📄 selectupfile.asp
字号:
<!--#include file = admin_chk.asp -->
<SCRIPT language=javascript>
function unselectall()
{
if(document.myform.chkAll.checked){
document.myform.chkAll.checked = document.myform.chkAll.checked&0;
}
}
function CheckAll(form)
{
for (var i=0;i<form.elements.length;i++)
{
var e = form.elements[i];
if (e.Name != "chkAll")
e.checked = form.chkAll.checked;
}
}
</script>
<title>从已上传文件选择</title>
<link rel="stylesheet" type="text/css" href="../images/admin/style.css">
<table width="100%" border="0" align=center cellpadding="3" cellspacing="1" bordercolor="#FFFFFF">
<tr>
<th height="25"><strong>从已上传文件选择</strong></th>
</tr>
<TR ALIGN=center>
<TD class=forumRow>
<%
Dim sUploadDir, sCurrDir, sDir,sAction,UrlID,strDirName
UrlID=trim(request("UrlID"))
if UrlID="" then
UrlID=0
else
UrlID=Clng(UrlID)
end if
select case UrlID
case 0 'ID=0 新闻缩图选择
sUploadDir ="../"&config("CjUpFilePath")
strDirName="根目录"
case 1 'ID=1 水印图片选择
sUploadDir = "../"&config("CjUpFilePath")&"gg"
strDirName="广告图目录"
case 2 'ID=2 用户头像图片选择
sUploadDir = "../"&config("CjUpFilePath")&"face"
strDirName="用户头像图片目录"
case 3 'ID=3 首页图片选择
sUploadDir = "../"&config("CjUpFilePath")&"gg"
strDirName="首页图片目录"
end select
Call Content()
Sub Content()
If IsObjInstalled("Scripting.FileSystemObject") = False Then
Response.Write "此功能要求服务器支持文件系统对象（FSO），而你当前的服务器不支持！"
Exit Sub
End If
' 初始化传入参数
Call InitParam()
' 显示文件列表
Call ShowList()
End Sub
' UploadFile目录下的所有文件列表
Sub ShowList()
If sCurrDir = "" Then Exit Sub
Response.Write "<table width=100% border=1 align=center cellpadding=0 cellspacing=0 bordercolordark=FFFFFF bordercolorlight=658BD8>" & _
"<form action='?dir=" & sDir & "&UrlID=" & UrlID & "' method=post name=myform >" & _
"<tr style='FONT-FAMILY: Verdana, Arial, 宋体;BACKGROUND-COLOR:#eeeeee'>" & _
"<td height=25>您现在的位置：上传文件管理目录 >> "
if sDir<>"" then
Response.Write "<font color=#ff6600>"& sDir &"</font>"
else
response.write "<font color=#ff6600>"& strDirName &"</font>"
end if
Response.Write"</td></tr>"
Dim sCurrPage, nCurrPage, nFileNum, nPageNum, nPageSize, TotalSize
sCurrPage = Trim(Request("page"))
nPageSize = 9
If sCurrpage = "" Or Not IsNumeric(sCurrPage) Then
nCurrPage = 1
Else
nCurrPage = CLng(sCurrPage)
End If
Dim oFSO, oUploadFolder, oUploadFiles, oUploadFile, sFileName
Set oFSO = Server.CreateObject("Scripting.FileSystemObject")
On Error Resume Next
Set oUploadFolder = oFSO.GetFolder(Server.MapPath(sCurrDir))
If Err.Number>0 Then
Response.Write "</table>无效的目录！"
Exit Sub
End If
If sDir <> "" Then
Response.Write "<tr align=center >" & _
"<td align=left ><img border=0 src='../edit/sysimage/file/folderback.gif'>" & _
"<a href=""?dir="
If InstrRev(sDir, "/") > 1 Then
Response.Write Left(sDir, InstrRev(sDir, "/") - 1)
End If
Response.Write """>返回上一级目录</a></td></tr>"
End If
Dim strHTML
strHTML= "<tr><td ><table width='100%' cellpadding='2' cellspacing='1' ><tr style='FONT-FAMILY: Verdana, Arial, 宋体;'>"
Dim oSubFolder
For Each oSubFolder In oUploadFolder.SubFolders
strHTML=strHTML & "<td><a href=""?dir="
If sDir <> "" Then
strHTML=strHTML & sDir & "/"
End If
strHTML=strHTML & oSubFolder.Name & """>" & "<img src='../edit/sysimage/file/folder.gif' border='0'align='absmiddle'>" & oSubFolder.Name & ""
strHTML=strHTML & "</a></td>"
FolderCount=FolderCount+1
if FolderCount mod 5=0 then strHTML=strHTML & "</td><tr>"
Next
strHTML=strHTML & "</tr></table></td></tr>"& vbcrlf
response.write strHTML
TotalSize=0
Set oUploadFiles = oUploadFolder.Files
nFileNum = oUploadFiles.Count
nPageNum = Int(nFileNum / nPageSize)
If nFileNum Mod nPageSize > 0 Then
nPageNum = nPageNum+1
End If
If nCurrPage > nPageNum Then
nCurrPage = 1
end If
Dim i,strFileType
i = 0
Response.Write "<tr><td><table width=100% border=0 align=center cellpadding=0 cellspacing=2><tr>"
For Each oUploadFile In oUploadFiles
i = i + 1
If i > (nCurrPage - 1) * nPageSize And i <= nCurrPage * nPageSize Then
sFileName = oUploadFile.Name
Response.Write "<td align=center ><table style=' BORDER-RIGHT: #009ace 1px solid; BORDER-TOP: #009ace 1px solid; BORDER-LEFT: #009ace 1px solid; WIDTH: 100%; BORDER-BOTTOM: #009ace 1px solid; BACKGROUND-COLOR: #ffffff'><tr><td colspan=2 align=center>"
strFileType=lcase(mid(oUploadFile.Name,instrrev(oUploadFile.Name,".")+1))
select case UrlID
case 0
response.write "<a href='#' onClick=""javascript:window.opener.document.FrontPage_Form1.pic.value='" & sCurrDir & sFileName &"';window.close();"">"
case 1
response.write "<a href='#' onClick=""javascript:window.opener.document.form.gif_url.value='" & sCurrDir & sFileName &"';window.close();"">"
case 2
response.write "<a href='#' onClick=""javascript:window.opener.document.FrmAddLink.photo.value='" & sCurrDir & sFileName &"';window.close();"">"
case 3
response.write "<a href='#' onClick=""javascript:window.opener.document.FrontPage_Form2.top_pic_url.value='" & sCurrDir & sFileName &"';window.close();"">"
end select
select case strFileType
case "jpg","gif","bmp","png"
'response.write "<img src='" & sCurrDir & sFileName &"' width='140' height='100' border='0' title='点此图片将返回，点下面的文件名将查看原始文件！'></a>"
response.write "<script language=""javascript""> document.write(""<img border=0 src=" & sCurrDir & sFileName &" border='0' title='点此图片将返回，点下面的文件名将查看原始文件！' onload='if((this.width/this.height)>(7/5)){this.width=140;}else{this.height=100;}'>""); </SCRIPT>"
case "swf"
response.write "<img src='../images/filetype_flash.gif' width='140' height='100' border='0'></a>"
case "wmv","avi","asf","mpg"
response.write "<img src='../images/filetype_media.gif' width='140' height='100' border='0'></a>"
case "rm","ra","ram"
response.write "<img src='../images/filetype_rm.gif' width='140' height='100' border='0'></a>"
case "rar"
response.write "<img src='../images/filetype_rar.gif' width='140' height='100' border='0'></a>"
case "zip"
response.write "<img src='../images/filetype_zip.gif' width='140' height='100' border='0'></a>"
case "exe"
response.write "<img src='../images/filetype_exe.gif' width='140' height='100' border='0'></a>"
case else
response.write "<img src='../images/filetype_other.gif' width='140' height='100' border='0'></a>"
end select
Response.Write "</td></tr>"& _
"<tr style='FONT-FAMILY: Verdana, Arial, 宋体;padding: 4px 8px;'>"& _
"<td align=right width='35%' >文 件 名：</td>"& _
"<td width='65%'><a href=""" & sCurrDir & sFileName & """ target=_blank>" & sFileName & "</td></tr>" & _
"<tr style='FONT-FAMILY: Verdana, Arial, 宋体;padding: 4px 8px;'>"& _
"<td align=right>文件大小：</td>"& _
"<td>" & round(oUploadFile.size/1024) & " K </td></tr>" & _
"<tr style='FONT-FAMILY: Verdana, Arial, 宋体;padding: 4px 8px;'>" & _
"<td align=right>文件类型：</td>"& _
"<td>" & oUploadFile.type & "</td></tr>" & _
"<tr style='FONT-FAMILY: Verdana, Arial, 宋体;padding: 4px 8px;'>"& _
"<td align=right>修改时间：</td>"& _
"<td>" & oUploadFile.DateLastModified & "</td></tr>" & _
"</tr></table></td>"
FileCount=FileCount+1
if FileCount mod 3=0 then response.write "<tr>"
TotalSize=TotalSize+oUploadFile.Size
End If
Next
Set oUploadFolder = Nothing
Set oUploadFiles = Nothing
Response.Write "</tr></table></td></tr>"
If nFileNum <= 0 Then
Response.Write "<tr><td >指定目录下现在还没有文件！</td></tr>"
End If
Response.Write "</table>"
Response.Write "<table width='100%' border=1 align=center cellpadding=0 cellspacing=0 bordercolordark=FFFFFF bordercolorlight=658BD8>"
If nFileNum > 0 Then ' 分页
Response.Write "<tr><td align=center height=30 colspan=2> 共<b>" & nFileNum & "</b>个，本页占用 <b>" & TotalSize\1024 & "</b> K "
If nCurrPage > 1 Then
Response.Write "<a href='?dir=" & sDir & "&UrlID=" & UrlID & "&page=1'>首页</a> <a href='?dir=" & sDir & "&UrlID=" & UrlID & "&page="& nCurrPage - 1 & "'>上一页</a> "
Else
Response.Write "首页 上一页 "
End If
If nCurrPage < i / nPageSize Then
Response.Write "<a href='?dir=" & sDir & "&UrlID=" & UrlID & "&page=" & nCurrPage + 1 & "'>下一页</a> <a href='?dir=" & sDir & "&UrlID=" & UrlID & "&page=" & nPageNum & "'>尾页</a>"
Else
Response.Write "下一页 尾页"
End If
Response.Write " 页次:<b><span class=highlight2>" & nCurrPage & "</span>/" & nPageNum & "</b> <b>" & nPageSize & "</b>个文件/页"
Response.Write " 转到：<select name='page' size='1' onchange='javascript:submit()'>"
for l = 1 to nPageNum
Response.Write "<option value='" & l & "'"
if cint(nCurrPage)=cint(l) then Response.Write " selected "
Response.Write ">第" & l & "页</option>"
next
Response.Write"</select>"
Response.Write "</td></tr>"
End If
Response.Write "</table></form>"
End Sub
' 检测服务器是否支持某一对象
Function IsObjInstalled(strClassString)
On Error Resume Next
IsObjInstalled = False
Err = 0
Dim xTestObj
Set xTestObj = Server.CreateObject(strClassString)
If 0 = Err Then IsObjInstalled = True
Set xTestObj = Nothing
Err = 0
End Function
' ===============================================
' 初始化传入参数
' ===============================================
Function InitParam()
sUploadDir = Replace(sUploadDir, "\", "/")
If Right(sUploadDir, 1) <> "/" Then
sUploadDir = sUploadDir & "/"
End If
sCurrDir = sUploadDir
' 样式下的目录
sDir = Trim(Request("dir"))
If sDir <> "" Then
If CheckValidDir(Server.Mappath(sUploadDir & sDir)) = True Then
sCurrDir = sUploadDir & sDir & "/"
Else
sDir = ""
End If
End If
End Function
' ===============================================
' 检测目录的有效性
' ===============================================
Function CheckValidDir(s_Dir)
Dim oFSO
Set oFSO = Server.CreateObject("Scripting.FileSystemObject")
CheckValidDir = oFSO.FolderExists(s_Dir)
Set oFSO = Nothing
End Function
%>
</td></tr></table>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -