power.asm

CCS3.3自带的TI 5400系列DSP的dsplib文件。文档说明可以在TI公司网站上下载。

;***********************************************************
; Version 2.20.01                                           
;***********************************************************
;*****************************************************************************
;  Function:	 power
;  Description:  vector power
;
;  Copyright Texas instruments Inc, 1998
;-----------------------------------------------------------------------------
; Revision History:
; 0.01	J. Axelrod 6/15/98. Original version.
; 1.0 R. Piedra  8/31/98. Added frct mode on
; 2.00	- Li Yuan, 4/09/02. fixed overflow flag setup at the end of code.
;*****************************************************************************
        .mmregs

; Far-mode adjustment

	.if __far_mode
offset	.set 1			; far mode uses one extra location for ret addr  ll
	.else
offset	.set 0
	.endif

	.asg	(2), ret_addr
					; x in A
	.asg	(3 + offset), arg_z
	.asg	(4 + offset), arg_n
					; register usage
					; ar0: addr. idx
	.asg	ar2, ar_x
	.asg	ar3, ar_z

;*****************************************************************************
	.def	_power
	.text

_power
        PSHM    ST0                                 ; 1 cycle
        PSHM    ST1                                 ; 1 cycle
        RSBX    OVA                                 ; 1 cycle
        RSBX    OVB                                 ; 1 cycle

; Preserve registers
;-------------------
	ssbx	sxm			; sign extension on		(1)
	ssbx	frct			; frct bit ON			(1)

; Get arguments
;--------------

	ld	*sp(arg_n),b		; b = n 			(1)
	sub	#1,b			;				(2)
	stl	b, *sp(arg_n)		; n -1				(1)

	stlm	a, ar_x 		; pointer to x			(1)
	mvdk	*sp(arg_z),*(ar_z)	; pointer to z			(2)


; Compute (n) elements
; --------------------
_start:
	ld	#0,a			; a = 0 			(1)
	rpt	*sp(arg_n)		;				(1)
	squra	*ar_x+,a		; x*x				(1)

; Return
;--------
_end:
	dst	a, *ar_z		;				(2)

	ld	#0,a			;				(1)
	xc	1, AOV			; return overflow flag		(1)
	ld	#1,a			;				(1)

        POPM    ST1
        POPM    ST0

	.if	__far_mode
	fretd				;				(4)
	.else
	retd				;				(3)
	.endif
	nop
	nop

;end of file. please do not remove. it is left here to ensure that no lines of code are removed by any editor