smart.pas

Oracle Data Access Components Source Code ODAC v.6.70.0.45

unit Smart;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, OdacClx, QButtons,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, OdacVcl, Buttons,
{$ENDIF}
{$IFDEF FPC}
  LResources,
{$ENDIF}
  DBAccess, DB, Ora, {$IFNDEF FPC}MemDS{$ELSE}MemDataSet{$ENDIF},
  OraSmart, OdacDemoFrame;

type
  TSmartFrame = class(TOdacDemoFrame)
    DBGrid: TDBGrid;
    DataSource: TDataSource;
    ToolBar: TPanel;
    Memo: TMemo;
    SmartQuery: TSmartQuery;
    Splitter1: TSplitter;
    Panel1: TPanel;
    Panel2: TPanel;
    cbDMLRefresh: TCheckBox;
    cbFullRefresh: TCheckBox;
    cbRefreshBeforeEdit: TCheckBox;
    cbRefreshAfterInsert: TCheckBox;
    cbRefreshAfterUpdate: TCheckBox;
    Panel5: TPanel;
    Panel6: TPanel;
    edFilter: TEdit;
    Label5: TLabel;
    cbFiltered: TCheckBox;
    Panel7: TPanel;
    Label2: TLabel;
    cbCheck: TComboBox;
    Panel8: TPanel;
    Label4: TLabel;
    edKeyFields: TEdit;
    cbFetchAll: TCheckBox;
    StaticText1: TLabel;
    edFetchRows: TEdit;
    Panel3: TPanel;
    cbAutoCommit: TCheckBox;
    cbExpand: TCheckBox;
    btClose: TSpeedButton;
    btOpen: TSpeedButton;
    Panel9: TPanel;
    DBNavigator: TDBNavigator;
    btView: TSpeedButton;
    btRefreshRecord: TSpeedButton;
    Panel4: TPanel;
    Label1: TLabel;
    cbLock: TComboBox;
    btLock: TSpeedButton;
    Panel10: TPanel;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure cbFetchAllClick(Sender: TObject);
    procedure edFetchRowsExit(Sender: TObject);
    procedure cbLockChange(Sender: TObject);
    procedure cbCheckChange(Sender: TObject);
    procedure cbExpandClick(Sender: TObject);
    procedure btViewClick(Sender: TObject);
    procedure cbAutoCommitClick(Sender: TObject);
    procedure edKeyFieldsExit(Sender: TObject);
    procedure cbFullRefreshClick(Sender: TObject);
    procedure btLockClick(Sender: TObject);
    procedure btRefreshRecordClick(Sender: TObject);
    procedure cbDMLRefreshClick(Sender: TObject);
    procedure DataSourceDataChange(Sender: TObject; Field: TField);
    procedure DataSourceStateChange(Sender: TObject);
    procedure edFilterExit(Sender: TObject);
    procedure cbFilteredClick(Sender: TObject);
    procedure cbRefreshBeforeEditClick(Sender: TObject);
    procedure cbRefreshAfterInsertClick(Sender: TObject);
    procedure cbRefreshAfterUpdateClick(Sender: TObject);
  public
    procedure Initialize; override;
    procedure SetDebug(Value: boolean); override;
  end;

implementation

uses
  ODACDemoForm;

{$IFNDEF FPC}
{$IFDEF CLR}
{$R *.nfm}
{$ENDIF}
{$IFDEF WIN32}
{$R *.dfm}
{$ENDIF}
{$IFDEF LINUX}
{$R *.xfm}
{$ENDIF}
{$ENDIF}

procedure TSmartFrame.btOpenClick(Sender: TObject);
begin
  SmartQuery.SQL.Assign(Memo.Lines);
  DBGrid.SetFocus; // OnExit events must be generated for edFetchRows, edKeyFields, edFilter
                   // to set SmartQuery parameters before it will be opened.

  SmartQuery.Open;
  btView.Enabled := True;
end;

procedure TSmartFrame.btCloseClick(Sender: TObject);
begin
  SmartQuery.Close;
  btView.Enabled := False;
end;

procedure TSmartFrame.Initialize;
begin
  inherited;

  SmartQuery.Connection := Connection;

  cbFetchAll.Checked := SmartQuery.FetchAll;
  edFetchRows.Text := IntToStr(SmartQuery.FetchRows);
  cbAutoCommit.Checked := SmartQuery.AutoCommit;

  cbLock.ItemIndex := Integer(SmartQuery.LockMode);
  cbCheck.ItemIndex := Integer(SmartQuery.CheckMode);
  cbRefreshBeforeEdit.Checked := roBeforeEdit in SmartQuery.RefreshOptions;
  cbRefreshAfterInsert.Checked := roAfterInsert in SmartQuery.RefreshOptions;
  cbRefreshAfterUpdate.Checked := roAfterUpdate in SmartQuery.RefreshOptions;
  cbExpand.Checked := SmartQuery.Expand;
  cbFullRefresh.Checked := SmartQuery.FullRefresh;
  cbDMLRefresh.Checked := SmartQuery.DMLRefresh;

  edKeyFields.Text := SmartQuery.KeyFields;

  edFilter.Text := SmartQuery.Filter;
  cbFiltered.Checked := SmartQuery.Filtered;

  Memo.Lines.Text := SmartQuery.SQL.Text;
end;

procedure TSmartFrame.cbFetchAllClick(Sender: TObject);
begin
  SmartQuery.FetchAll := cbFetchAll.Checked;
end;

procedure TSmartFrame.edFetchRowsExit(Sender: TObject);
begin
  try
    SmartQuery.FetchRows := StrToInt(edFetchRows.Text);
  except
    edFetchRows.SetFocus;
    raise;
  end;
end;

procedure TSmartFrame.SetDebug(Value: boolean);
begin
  SmartQuery.Debug := Value;
end;

procedure TSmartFrame.cbLockChange(Sender: TObject);
begin
  SmartQuery.LockMode := TLockMode(cbLock.ItemIndex);
end;

procedure TSmartFrame.cbCheckChange(Sender: TObject);
begin
  SmartQuery.CheckMode := TCheckMode(cbCheck.ItemIndex);
end;

procedure TSmartFrame.cbExpandClick(Sender: TObject);
begin
  try
    SmartQuery.Expand := cbExpand.Checked;
  except
    cbExpand.Checked := SmartQuery.Expand;
    raise;
  end;
end;

procedure TSmartFrame.btViewClick(Sender: TObject);
begin
  SmartQuery.View;
end;

procedure TSmartFrame.cbAutoCommitClick(Sender: TObject);
begin
  SmartQuery.AutoCommit := cbAutoCommit.Checked;
end;

procedure TSmartFrame.edKeyFieldsExit(Sender: TObject);
begin
  try
    SmartQuery.KeyFields := edKeyFields.Text;
  finally
    edKeyFields.Text := SmartQuery.KeyFields;
  end;
end;

procedure TSmartFrame.cbFullRefreshClick(Sender: TObject);
begin
  SmartQuery.FullRefresh := cbFullRefresh.Checked;
end;

procedure TSmartFrame.btLockClick(Sender: TObject);
begin
  SmartQuery.Lock;
end;

procedure TSmartFrame.btRefreshRecordClick(Sender: TObject);
begin
  SmartQuery.RefreshRecord;
end;

procedure TSmartFrame.cbDMLRefreshClick(Sender: TObject);
begin
  SmartQuery.DMLRefresh := cbDMLRefresh.Checked;
end;

procedure TSmartFrame.DataSourceStateChange(Sender: TObject);
begin
  OdacForm.StatusBar.Panels[1].Text := 'RecordCount:' + IntToStr(SmartQuery.RecordCount);
  OdacForm.StatusBar.Panels[2].Text := 'RecordNo:' + IntToStr(SmartQuery.RecNo);
end;

procedure TSmartFrame.DataSourceDataChange(Sender: TObject; Field: TField);
begin
  DataSourceStateChange(nil);
end;

procedure TSmartFrame.edFilterExit(Sender: TObject);
begin
  SmartQuery.Filter := edFilter.Text;
end;

procedure TSmartFrame.cbFilteredClick(Sender: TObject);
begin
  try
    SmartQuery.Filtered := cbFiltered.Checked;
  except
    cbFiltered.Checked := SmartQuery.Filtered;
    raise;
  end;
end;

procedure TSmartFrame.cbRefreshBeforeEditClick(Sender: TObject);
begin
  if cbRefreshBeforeEdit.Checked then
    SmartQuery.RefreshOptions := SmartQuery.RefreshOptions + [roBeforeEdit]
  else
    SmartQuery.RefreshOptions := SmartQuery.RefreshOptions - [roBeforeEdit];
end;

procedure TSmartFrame.cbRefreshAfterInsertClick(Sender: TObject);
begin
  if cbRefreshAfterInsert.Checked then
    SmartQuery.RefreshOptions := SmartQuery.RefreshOptions + [roAfterInsert]
  else
    SmartQuery.RefreshOptions := SmartQuery.RefreshOptions - [roAfterInsert];
end;

procedure TSmartFrame.cbRefreshAfterUpdateClick(Sender: TObject);
begin
  if cbRefreshAfterUpdate.Checked then
    SmartQuery.RefreshOptions := SmartQuery.RefreshOptions + [roAfterUpdate]
  else
    SmartQuery.RefreshOptions := SmartQuery.RefreshOptions - [roAfterUpdate];
end;

initialization
{
SELECT
  E.EmpNo, E.EName, E.DeptNo, E.RowId, D.*
FROM
  Emp E, Dept D
WHERE
  E.DeptNo = D.DeptNo(+)
}

{$IFDEF FPC}
{$I Smart.lrs}
{$ENDIF}

end.