arrays.pas

Oracle Data Access Components Source Code ODAC v.6.70.0.45

unit Arrays;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, OdacClx, QButtons,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, OdacVcl, Buttons,
{$ENDIF}
  DBAccess, Ora, OraScript, Db, MemDS, OraSmart, OdacDemoForm, OdacDemoFrame,
  DAScript;

type
  TArraysFrame = class(TOdacDemoFrame)
    DataSource: TDataSource;
    Query: TSmartQuery;
    sqInsert: TOraSQL;
    DBGrid: TDBGrid;
    Panel2: TPanel;
    ToolBar1: TPanel;
    btOpen: TSpeedButton;
    btClose: TSpeedButton;
    btUpdateRecord: TSpeedButton;
    btAddRecord: TSpeedButton;
    DBNavigator1: TDBNavigator;
    Panel1: TPanel;
    cbObjectView: TCheckBox;
    cbSparseArrays: TCheckBox;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure cbObjectViewClick(Sender: TObject);
    procedure btAddRecordClick(Sender: TObject);
    procedure btUpdateRecordClick(Sender: TObject);
    procedure cbSparseArraysClick(Sender: TObject);
  private
    OraSession: TOraSession;
  public
    procedure Initialize; override;
    procedure SetDebug(Value: boolean); override;
  end;

implementation
uses
  MemData, OraObjects
{$IFNDEF VER130}
  ,Variants
{$ENDIF}
  ;

{$IFDEF CLR}
{$R *.nfm}
{$ENDIF}
{$IFDEF WIN32}
{$R *.dfm}
{$ENDIF}
{$IFDEF LINUX}
{$R *.xfm}
{$ENDIF}

procedure TArraysFrame.btOpenClick(Sender: TObject);
begin
  Query.Open;
end;

procedure TArraysFrame.btCloseClick(Sender: TObject);
begin
  Query.Close;
end;

procedure TArraysFrame.Initialize;
begin
  inherited;

  Query.Connection := Connection;
  sqInsert.Connection := Connection;
  OraSession := Connection as TOraSession;

  cbObjectView.Checked:= Query.ObjectView;
  cbSparseArrays.Checked:= Query.SparseArrays;
end;

procedure TArraysFrame.cbObjectViewClick(Sender: TObject);
begin
  if not Query.Active then
    Query.ObjectView:= cbObjectView.Checked;
  cbObjectView.Checked:= Query.ObjectView;
end;

procedure TArraysFrame.cbSparseArraysClick(Sender: TObject);
begin
  if not Query.Active then
    Query.SparseArrays:= cbSparseArrays.Checked;
  cbSparseArrays.Checked:= Query.SparseArrays;
end;

procedure TArraysFrame.SetDebug(Value: boolean);
begin
  Query.Debug := Value;
  sqInsert.Debug := Value;
end;

procedure TArraysFrame.btAddRecordClick(Sender: TObject);
begin
  OraSession.Connect;

  sqInsert['Code']:= variant(100);
  sqInsert['Title']:= variant('New record');

// CREATE TYPE TODACArray1 AS VARRAY (5) OF NUMBER;

  with sqInsert.ParamByName('Arr1').AsArray do begin
    OCISvcCtx:= OraSession.OCISvcCtx;
    AllocObject('TODACArray1');
    ItemAsInteger[0]:= 12;
    AttrAsInteger['[1]']:= 10;
    ItemAsInteger[3]:= 133;
  end;

// CREATE TYPE TODACArrType AS OBJECT (
//     Num NUMBER,
//     Str VARCHAR2(10)
// );
//
// CREATE TYPE TODACArray2 AS VARRAY (3) OF TODACArrType;}

  with sqInsert.ParamByName('Arr2').AsArray do begin
    AllocObject(OraSession.OCISvcCtx, 'TODACArray2');
    ItemAsObject[0].AttrAsInteger['Num']:= 34;
    AttrAsInteger['[2].Num']:= 431;
  end;

// CREATE TYPE TODACArray3 AS VARRAY (4) OF CHAR(10);

  with sqInsert.ParamByName('Arr3').AsArray do begin
    OCISvcCtx:= OraSession.OCISvcCtx;
    AllocObject('TODACArray3');
    AttrAsString['[2]']:= 'eeee';
    ItemAsString[0]:= 'FFFFF';
  end;

// CREATE TYPE TODACArrType1 AS OBJECT (
//   Num NUMBER,
//   Str VARCHAR2(10),
//   Arr TODACArray3
// );

  with sqInsert.ParamByName('Obj').AsObject do begin
    AllocObject(OraSession.OCISvcCtx, 'TODACArrType1');
    AttrAsInteger['Num']:= 591;
    AttrAsString['Arr2[2]']:= 'JJJ';
  end;

  sqInsert.Execute;

  if Query.Active then
    Query.Refresh;
end;

procedure TArraysFrame.btUpdateRecordClick(Sender: TObject);
begin
  if Query.EOF then
    Exit;

  Query.Edit;

  with Query.GetArray('Arr1') do begin
    ItemAsInteger[3]:= ItemAsInteger[3] + 1;
    AttrAsInteger['[1]']:= 67;
  end;

  with Query.GetArray('Arr2') do begin
    AttrAsInteger['[0].Num']:= 89;
    ItemAsObject[2].AttrAsString['Str']:= 'VVV';
  end;

  with Query.GetArray('Arr3') do begin
    AttrAsString['[2]']:= 'TTTTTTT';
    ItemAsString[1]:= 'NNNNN';
  end;

  with Query.GetObject('Obj') do begin
    AttrAsInteger['Num']:= 591;
    AttrAsString['Arr2[2]']:= 'JJJ';
  end;

  Query.Post;
end;

end.