cachedupdates.pas

Oracle Data Access Components Source Code ODAC v.6.70.0.45

unit CachedUpdates;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, QButtons, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, Buttons, OdacVcl,
{$ENDIF}
{$IFDEF FPC}
  LResources,
{$ENDIF}
  Db, {$IFNDEF FPC}MemDS{$ELSE}MemDataSet{$ENDIF},
  DBAccess, Ora, OdacDemoFrame, OdacDemoForm;

type
  TCachedUpdatesFrame = class(TOdacDemoFrame)
    DBGrid: TDBGrid;
    DataSource: TDataSource;
    ToolBar: TPanel;
    OraQuery: TOraQuery;
    OraQueryStatus: TStringField;
    OraQueryDEPTNO: TIntegerField;
    OraQueryDNAME: TStringField;
    OraQueryLOC: TStringField;
    RefreshRecord: TSpeedButton;
    btClose: TSpeedButton;
    btOpen: TSpeedButton;
    DBNavigator: TDBNavigator;
    Panel10: TPanel;
    cbCachedUpdates: TCheckBox;
    cbCustomUpdate: TCheckBox;
    Panel6: TPanel;
    Label1: TLabel;
    cbDeleted: TCheckBox;
    cbInserted: TCheckBox;
    cbModified: TCheckBox;
    cbUnmodified: TCheckBox;
    Panel1: TPanel;
    Label2: TLabel;
    Panel3: TPanel;
    btApply: TSpeedButton;
    btCommit: TSpeedButton;
    btCancel: TSpeedButton;
    btRevertRecord: TSpeedButton;
    Panel4: TPanel;
    Label3: TLabel;
    Panel5: TPanel;
    btStartTrans: TSpeedButton;
    btCommitTrans: TSpeedButton;
    btRollBackTrans: TSpeedButton;
    Panel7: TPanel;
    Panel2: TPanel;
    edUpdateBatchSize: TEdit;
    Label4: TLabel;
    Panel8: TPanel;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure btApplyClick(Sender: TObject);
    procedure btCancelClick(Sender: TObject);
    procedure btStartTransClick(Sender: TObject);
    procedure btCommitTransClick(Sender: TObject);
    procedure btRollbackTransClick(Sender: TObject);
    procedure cbCachedUpdatesClick(Sender: TObject);
    procedure OraQueryUpdateError(DataSet: TDataSet; E: EDatabaseError;
      UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
    procedure OraQueryUpdateRecord(DataSet: TDataSet;
      UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
    procedure cbCustomUpdateClick(Sender: TObject);
    procedure OraQueryCalcFields(DataSet: TDataSet);
    procedure btCommitClick(Sender: TObject);
    procedure cbUnmodifiedClick(Sender: TObject);
    procedure cbModifiedClick(Sender: TObject);
    procedure cbInsertedClick(Sender: TObject);
    procedure cbDeletedClick(Sender: TObject);
    procedure DataSourceDataChange(Sender: TObject; Field: TField);
    procedure DataSourceStateChange(Sender: TObject);
    procedure DBGridDrawDataCell(Sender: TObject; const Rect: TRect;
      Field: TField; State: TGridDrawState);
    procedure btRevertRecordClick(Sender: TObject);
    procedure RefreshRecordClick(Sender: TObject);
    procedure edUpdateBatchSizeExit(Sender: TObject);
{$IFNDEF LINUX}
  published
    udUpdateBatchSize: TUpDown;
{$ENDIF}
  private
    { Private declarations }
    procedure ShowTrans;
    procedure ShowPending;
    procedure ShowUpdateRecordTypes;
  public
    procedure Initialize; override;
    procedure SetDebug(Value: boolean); override;
    destructor Destroy; override;
  end;

implementation

uses
  UpdateAction;

{$IFNDEF FPC}
{$IFDEF CLR}
{$R *.nfm}
{$ENDIF}
{$IFDEF WIN32}
{$R *.dfm}
{$ENDIF}
{$IFDEF LINUX}
{$R *.xfm}
{$ENDIF}
{$ENDIF}

destructor TCachedUpdatesFrame.Destroy;
begin
  inherited;
  FreeAndNil(UpdateActionForm);
end;

procedure TCachedUpdatesFrame.ShowTrans;
begin
  if OraQuery.Session.InTransaction then
    OdacForm.StatusBar.Panels[2].Text := 'In Transaction'
  else
    OdacForm.StatusBar.Panels[2].Text := '';
end;

procedure TCachedUpdatesFrame.ShowPending;
begin
  if OraQuery.UpdatesPending then
    OdacForm.StatusBar.Panels[1].Text := 'Updates Pending'
  else
    OdacForm.StatusBar.Panels[1].Text := '';
end;

procedure TCachedUpdatesFrame.ShowUpdateRecordTypes;
begin
  if OraQuery.CachedUpdates then begin
    cbUnmodified.Checked := rtUnmodified in OraQuery.UpdateRecordTypes;
    cbModified.Checked := rtModified in OraQuery.UpdateRecordTypes;
    cbInserted.Checked := rtInserted in OraQuery.UpdateRecordTypes;
    cbDeleted.Checked := rtDeleted in OraQuery.UpdateRecordTypes;
  end;
end;

procedure TCachedUpdatesFrame.btOpenClick(Sender: TObject);
begin
  OraQuery.Open;
end;

procedure TCachedUpdatesFrame.btCloseClick(Sender: TObject);
begin
  OraQuery.Close;
end;

procedure TCachedUpdatesFrame.btApplyClick(Sender: TObject);
begin
  OraQuery.ApplyUpdates;
  ShowPending;
end;

procedure TCachedUpdatesFrame.btCommitClick(Sender: TObject);
begin
  OraQuery.CommitUpdates;
  ShowPending;
end;

procedure TCachedUpdatesFrame.btCancelClick(Sender: TObject);
begin
  OraQuery.CancelUpdates;
  ShowPending;
end;

procedure TCachedUpdatesFrame.btStartTransClick(Sender: TObject);
begin
  OraQuery.Session.StartTransaction;
  ShowTrans;
end;

procedure TCachedUpdatesFrame.btCommitTransClick(Sender: TObject);
begin
  OraQuery.Session.Commit;
  ShowTrans;
end;

procedure TCachedUpdatesFrame.btRollbackTransClick(Sender: TObject);
begin
  OraQuery.Session.Rollback;
  ShowTrans;
end;

procedure TCachedUpdatesFrame.Initialize;
begin
  inherited;

  OraQuery.Connection := Connection;

  if UpdateActionForm = nil then
    UpdateActionForm := TUpdateActionForm.Create(OdacForm);
  cbCachedUpdates.Checked := OraQuery.CachedUpdates;
  edUpdateBatchSize.Text := IntToStr(OraQuery.Options.UpdateBatchSize);
  ShowUpdateRecordTypes;
end;

procedure TCachedUpdatesFrame.cbCachedUpdatesClick(Sender: TObject);
begin
  try
    OraQuery.CachedUpdates := cbCachedUpdates.Checked;
  except
    cbCachedUpdates.Checked := OraQuery.CachedUpdates;
    raise;
  end;
  ShowUpdateRecordTypes;
end;

procedure TCachedUpdatesFrame.OraQueryUpdateError(DataSet: TDataSet; E: EDatabaseError;
  UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
begin
  UpdateActionForm.rgAction.ItemIndex := Ord(UpdateAction);
  UpdateActionForm.rgKind.ItemIndex := Ord(UpdateKind);
  UpdateActionForm.lbField.Caption := string(DataSet.Fields[0].Value);
  UpdateActionForm.lbMessage.Caption := E.Message;
  UpdateActionForm.ShowModal;
  UpdateAction:= TUpdateAction(UpdateActionForm.rgAction.ItemIndex);
end;

procedure TCachedUpdatesFrame.OraQueryUpdateRecord(DataSet: TDataSet;
  UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
begin
  UpdateActionForm.rgAction.ItemIndex := Ord(UpdateAction);
  UpdateActionForm.rgKind.ItemIndex := Ord(UpdateKind);
  UpdateActionForm.lbField.Caption := string(DataSet.Fields[0].NewValue);
  UpdateActionForm.lbMessage.Caption := '';
  UpdateActionForm.ShowModal;
  UpdateAction := TUpdateAction(UpdateActionForm.rgAction.ItemIndex);
end;

procedure TCachedUpdatesFrame.cbCustomUpdateClick(Sender: TObject);
begin
  if cbCustomUpdate.Checked then
    OraQuery.OnUpdateRecord := OraQueryUpdateRecord
  else
    OraQuery.OnUpdateRecord := nil;
end;

procedure TCachedUpdatesFrame.OraQueryCalcFields(DataSet: TDataSet);
var
  St:string;
begin
  case Ord(TOraDataSet(DataSet).UpdateStatus) of
    0: St := 'Unmodified';
    1: St := 'Modified';
    2: St := 'Inserted';
    3: St := 'Deleted';
  end;
  DataSet.FieldByName('Status').AsString := St;

{  case Ord(TOraDataSet(DataSet).UpdateResult) of
    0: St := 'Fail';
    1: St := 'Abort';
    2: St := 'Skip';
    3: St := 'Applied';
  end;
  DataSet.FieldByName('Result').AsString := St;}
end;

procedure TCachedUpdatesFrame.SetDebug(Value: boolean);
begin
  OraQuery.Debug := Value;
end;

procedure TCachedUpdatesFrame.cbUnmodifiedClick(Sender: TObject);
begin
  if cbUnmodified.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtUnmodified]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtUnmodified];
end;

procedure TCachedUpdatesFrame.cbModifiedClick(Sender: TObject);
begin
  if cbModified.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtModified]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtModified];
end;

procedure TCachedUpdatesFrame.cbInsertedClick(Sender: TObject);
begin
  if cbInserted.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtInserted]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtInserted];
end;

procedure TCachedUpdatesFrame.cbDeletedClick(Sender: TObject);
begin
  if cbDeleted.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtDeleted]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtDeleted];
end;

procedure TCachedUpdatesFrame.DataSourceStateChange(Sender: TObject);
begin
  ShowPending;
  OdacForm.StatusBar.Panels[3].Text := 'Record ' + IntToStr(OraQuery.RecNo) + ' of ' + IntToStr(OraQuery.RecordCount) ;
end;

procedure TCachedUpdatesFrame.DataSourceDataChange(Sender: TObject; Field: TField);
begin
  DataSourceStateChange(nil);
end;

procedure TCachedUpdatesFrame.DBGridDrawDataCell(Sender: TObject; const Rect: TRect;
  Field: TField; State: TGridDrawState);
begin
{$IFNDEF FPC}
  if OraQuery.UpdateResult in [uaFail,uaSkip] then
    TDBGrid(Sender).Canvas.Brush.Color := clRed
  else
    if OraQuery.UpdateStatus <> usUnmodified then
      TDBGrid(Sender).Canvas.Brush.Color := clYellow;

  TDBGrid(Sender).DefaultDrawDataCell(Rect, Field, State);
{$ENDIF}
end;

procedure TCachedUpdatesFrame.btRevertRecordClick(Sender: TObject);
begin
  OraQuery.RevertRecord;
  ShowPending;
end;

procedure TCachedUpdatesFrame.RefreshRecordClick(Sender: TObject);
begin
  OraQuery.RefreshRecord;
end;

procedure TCachedUpdatesFrame.edUpdateBatchSizeExit(Sender: TObject);
begin
  try
    OraQuery.Options.UpdateBatchSize := StrToInt(edUpdateBatchSize.Text);
  except
    edUpdateBatchSize.Text := IntToStr(OraQuery.Options.UpdateBatchSize);
    raise;
  end;
end;

initialization
{$IFDEF FPC}
{$I CachedUpdates.lrs}
{$ENDIF}

end.